A Cinderella Story, OS demonstration (CINDER1.BAS)

A Cinderella Story, OS demonstration by Fred Pinho, 15

Description

A Cinderella Story, OS demonstration by Fred Pinho, 15

From the Antic disk of February 1984 (Vol. 2 No. 11).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 1.4 KB

Dialect
Atari BASIC
Lines
31
Variables
F, DL, DLI, I, D, T
BASIC listing (31 lines)
1 REM *** OS DEMO 1 ****
2 REM * BY FRED PINHO  *
3 REM * ANTIC MAGAZINE *
4 REM * FEBUARY, 1984  *
5 REM ******************
10 GRAPHICS 3:F=0:? "NORMAL SCREEN(NO DLI).":? "CAN YOU SEE THE LETTERS?";:REM OR GR.5 OR GR.7
20 COLOR 1:PLOT 9,0:DRAWTO 9,19
30 COLOR 2:PLOT 19,0:DRAWTO 19,19
40 COLOR 3:PLOT 29,0:DRAWTO 29,19
50 POKE 752,1:GOSUB 300
60 SETCOLOR 0,5,6:GOSUB 300
65 SETCOLOR 0,2,8:GOSUB 300
70 SETCOLOR 1,2,6:GOSUB 300
80 SETCOLOR 1,2,4:GOSUB 300
90 SETCOLOR 1,12,10:GOSUB 300
100 SETCOLOR 2,12,4:GOSUB 300
110 SETCOLOR 2,12,10:GOSUB 300
120 SETCOLOR 2,9,4:GOSUB 300
130 IF F=1 THEN POKE 54286,64:GOTO 10
135 REM POKE OF 64(NORMAL VALUE) INTO 54286 DISABLES DLI
140 ? CHR$(125):? "SETTING UP DLI!";:F=1:GOSUB 300
150 DL=PEEK(560)+256*PEEK(561)
160 DLI=DL+24:REM FOR GR.5 USE DL+44,FOR GR.7 USE DL+84
170 POKE DLI,136:REM FOR GR.5 POKE DLI,138 AND FOR GR.7 POKE DLI,141
180 RESTORE 190:FOR I=0 TO 15:READ D:POKE 1536+I,D:NEXT I
190 DATA 72,169,202,141,10,212,141,23,208,169,148,141,24,208,104,64
200 POKE 512,0:POKE 513,6:POKE 54286,192
205 REM LOCATIONS 512 & 513 HOLD ADDRESS OF DLI ROUTINE
207 REM POKE INTO 54286 ENABLES DLI
210 ? " DONE!":? "CAN YOU SEE THE LETTERS?";:GOSUB 300:GOTO 20
300 FOR T=1 TO 500:NEXT T:RETURN