Character Graphics, character redefinition (CHARSET4.BAS)

Character Graphics, character redefinition by Chris Chabris, 60

Description

Character Graphics, character redefinition by Chris Chabris, 60

From the Antic disk of February 1984 (Vol. 2 No. 11).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

BASIC listing · 2.1 KB

Text
996 REM ANTIC MAGAZINE FEBRUARY 1983
997 REM CHARACTER SET EXAMPLE #2
998 REM BY CHRIS CHABRIS
999 REM REQUIRES 16K
1000 REM *** CHARACTER SET EXAMPLE #2
1010 GRAPHICS 0:POKE 752,1:PRINT CHR$(125):SETCOLOR 2,0,0
1020 DIM DRAW$(13),UNDRAW$(13)
1030 GOSUB 1260:REM - MODIFY DISPLAY LIST SUBROUTINE
1040 GOSUB 1310:REM - MODIFY CHARACTER SET SUBROUTINE
1050 REM - DRAW THE SCREEN WITH OUR SHAPES
1060 LET DRAW$="┤↓←┘↓←┘↓←←♥▕├":LET UNDRAW$=" ↓← ↓← ↓←←   "
1070 POSITION 2,22:PRINT "────────────────────────────────────";:REM - LAUNCH PAD
1080 POKE 756,CH/256
1090 POSITION 20,18:? DRAW$
1100 FOR LOOP=9 TO 0 STEP -1
1110 POSITION 20,23:? LOOP;
1120 FOR LOOP2=1 TO 200:NEXT LOOP2
1130 NEXT LOOP
1140 POSITION 15,23:PRINT "BLAST  OFF!";
1150 FOR LOOP=1 TO 300:NEXT LOOP
1160 POSITION 12,23:PRINT "SHE'S LIFTING OFF";
1170 FOR LOOP=17 TO 0 STEP -1
1180 POSITION 20,LOOP+1:? UNDRAW$;
1190 POSITION 20,LOOP:? DRAW$
1200 FOR LOOP2=1 TO 2*LOOP:NEXT LOOP2
1210 NEXT LOOP
1220 POSITION 10,23:PRINT "MISSION ACCOMPLISHED!";
1230 POSITION 20,0:? UNDRAW$
1240 GOTO 1240:REM - USER MUST PRESS BREAK OR SYSTEM RESET TO EXIT
1250 STOP 
1260 REM - MODIFY THE DISPLAY LIST
1270 DL=PEEK(560)+256*PEEK(561)
1280 POKE DL+3,68:REM - ANTIC MODE 4
1290 FOR LOOP=6 TO 27:POKE DL+LOOP,4:NEXT LOOP:REM - CHANGE ALL SCREEN LINES
1300 RETURN 
1310 REM - DOWNLOAD AND MODIFY THE CHARACTER SET
1320 CH=PEEK(106)-8:CH=CH*256
1330 DIM MOVE$(32):RESTORE 1350:FOR LOOP=1 TO 32:READ BYTE:MOVE$(LOOP)=CHR$(BYTE):NEXT LOOP
1340 JUNK=USR(ADR(MOVE$),CH,57344)
1350 DATA 104,104,133,215,104,133
1360 DATA 214,104,133,213,104,133
1370 DATA 212,162,4,160,0,177
1380 DATA 212,145,214,200,208,249
1390 DATA 230,213,230,215,202,208
1400 DATA 240,96
1410 RESTORE 1480
1420 READ NUM:IF NUM=-1 THEN RETURN 
1430 NUM=NUM*8
1440 FOR LOOP=0 TO 7:READ BYTE:POKE CH+NUM+LOOP,BYTE
1450 NEXT LOOP
1460 GOTO 1420
1470 REM - CHARACTER REDEFINITIONS
1480 DATA 64,2,10,42,42,170,170,0,0
1490 DATA 65,128,160,168,168,170,170,0,0
1500 DATA 66,190,255,255,255,255,255,20,85
1510 DATA 67,190,190,190,190,190,190,190,190
1520 DATA 68,0,0,0,20,20,40,170,190
1530 DATA -1