Character Graphics, character redefinition (CHARSET1.BAS)

Character Graphics, character redefinition by Chris Chabris, 60

Description

Character Graphics, character redefinition by Chris Chabris, 60

From the Antic disk of February 1984 (Vol. 2 No. 11).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

BASIC listing · 4.6 KB

Text
996 REM ANTIC MAGAZINE FEBRUARY 1983
997 REM CHARACTER SET EXAMPLE #1
998 REM BY CHRIS CHABRIS
999 REM REQUIRES 16K
1000 REM *** CHARACTER SET EXAMPLE #1
1010 GRAPHICS 2:POKE 752,1:POKE 82,1:POKE 83,38:PRINT CHR$(125):REM - SET UP GRAPHICS MODE
1020 DIM LINE$(20),QU$(38),ANS1$(38),ANS2$(38),AN$(1),EX$(38),TAN$(10)
1030 POSITION 6,2:PRINT #6;"ELECTRIC":POSITION 6,4:? #6;"circuits"
1040 PRINT "     Character Set Sample Program":PRINT "           by Chris Chabris"
1050 GOSUB 1570:REM - REDEFINE CHARACTERS SUBROUTINE
1060 POKE 756,CH/256:REM - ACTIVATE NEW CHARACTER SET
1070 REM - NOW PRINT OUT THE CIRCUIT ON THE SCREEN FROM DATA STATEMENTS
1080 RESTORE 1920
1090 FOR LOOP=0 TO 9
1100 READ P,LINE$
1110 POSITION P,LOOP:PRINT #6;LINE$;
1120 NEXT LOOP
1130 REM - PRINT INITIAL MESSAGE
1140 PRINT CHR$(125)
1150 PRINT "            Press  START":PRINT "    when you are ready to begin."
1160 POKE 53279,0
1170 IF PEEK(53279)<>6 THEN 1170
1180 REM - NOW WE'RE READY TO BEGIN THE QUESTIONS
1190 RESTORE 2020
1200 FOR LOOP=1 TO 5
1210 PRINT CHR$(125);
1220 READ QU$,ANS1$,ANS2$,AN$,EX$,TAN$
1230 PRINT QU$:PRINT ANS1$:PRINT ANS2$
1240 FOR LOOP2=1 TO 50:SOUND 0,100,10,8:NEXT LOOP2:SOUND 0,0,0,0
1250 OPEN #1,4,0,"K:"
1260 POKE 702,64:REM - KEYBOARD TO ALL CAPITALS
1270 GET #1,AN
1280 CLOSE #1
1290 IF AN=ASC(AN$) THEN 1400:REM - CORRECT ANSWER
1300 FOR LOOP2=1 TO 100:SOUND 0,250,10,8:NEXT LOOP2:SOUND 0,0,0,0
1310 PRINT CHR$(125);
1320 PRINT QU$
1330 PRINT "The correct answer is ";TAN$;".":PRINT EX$
1340 PRINT "Press RETURN to go on.";
1350 OPEN #1,4,0,"K:"
1360 GET #1,AN
1370 IF AN<>155 THEN 1360
1380 CLOSE #1
1390 GOTO 1500:REM - NEXT QUESTION
1400 REM - CORRECT ANSWER
1410 FOR LOOP2=1 TO 75:SOUND 0,150,10,8:NEXT LOOP2:SOUND 0,0,0,0
1420 PRINT CHR$(125)
1430 PRINT "           You are correct."
1440 PRINT "        Press RETURN to go on."
1450 OPEN #1,4,0,"K:"
1460 GET #1,AN
1470 IF AN<>155 THEN 1460
1480 CLOSE #1
1490 RIGHT=RIGHT+1
1500 REM - NEXT QUESTION
1510 NEXT LOOP
1520 PRINT CHR$(125)
1530 PRINT "  You have completed this short quiz"
1540 PRINT "     with a score of ";(RIGHT/5)*100;" per cent."
1550 GOTO 1550:REM - USER MUST PRESS BREAK OR SYSTEM RESET TO EXIT
1560 END 
1570 REM ** REDEFINE CHARACTER SET
1580 REM - FIRST, RESERVE MEMORY
1590 CH=PEEK(106)-8:CH=CH*256:REM - STARTING ADDRESS OF NEW CHARACTER SET AREA
1600 REM - NOW RELOCATE THE OLD SET
1610 FOR LOOP=0 TO 1023
1620 BYTE=PEEK(57344+LOOP)
1630 POKE CH+LOOP,BYTE
1640 NEXT LOOP
1650 REM - NOW WE'RE READY TO POKE IN THE NEW CHARACTER DEFINITIONS
1660 RESTORE 1730
1670 READ NUM:IF NUM=-1 THEN RETURN :REM - IF DONE, GO BACK
1680 NUM=NUM*8:REM - OFFSET INTO NEW CHARACTER SET MEMORY
1690 FOR LOOP=0 TO 7:READ BYTE:POKE CH+NUM+LOOP,BYTE
1700 NEXT LOOP
1710 GOTO 1670:REM - READY FOR ANOTHER CHARACTER
1720 REM - CHARACTER REDEFINITIONS
1730 DATA 1,24,24,24,255,255,0,0,0
1740 DATA 2,24,24,24,31,31,0,0,0
1750 DATA 3,24,24,24,248,248,24,24,24
1760 DATA 4,24,12,6,3,3,6,12,24
1770 DATA 5,64,192,64,64,224,0,0,0
1780 DATA 6,0,24,60,36,36,165,231,0
1790 DATA 7,24,24,24,248,248,0,0,0
1800 DATA 10,255,0,60,0,255,0,60,0
1810 DATA 26,0,0,0,255,255,24,24,24
1820 DATA 27,24,24,24,31,31,24,24,24
1830 DATA 28,224,32,96,32,224,0,0,0
1840 DATA 32,224,32,224,128,224,0,0,0
1850 DATA 59,126,129,189,165,189,165,129,126
1860 DATA 60,0,0,0,255,255,0,0,0
1870 DATA 61,24,24,24,24,24,24,24,24
1880 DATA 62,0,0,0,248,248,24,24,24
1890 DATA 63,0,0,0,31,31,24,24,24
1900 DATA -1
1910 REM - DATA FOR SCREEN
1920 DATA 2,3.0A
1930 DATA 1,_\\[\\:\\\:\\\^
1940 DATA 1,]     ]   ]   ]
1950 DATA 1,*     $   $   $
1960 DATA 1,*24V  $R  $R  $R
1970 DATA 1,*     $ % $ @ $ <
1980 DATA 1,]     ]   ]   ]
1990 DATA 1,"\\\\\!\\\!\\\'
2000 DATA 1,R =20& AND R =30&
2010 DATA 2,%          <
2020 REM - QUESTIONS FOLLOW
2030 DATA 1. What does the symbol & represent?
2040 DATA (a) coulombs       (b) webers
2050 DATA (c) ohms           (d) newtons
2060 DATA C,Ohms measure resistance.,ohms
2070 DATA 2. The resistors are connected in ...
2080 DATA (a) series         (b) parallel
2090 DATA (c) sequence       (d) inversion
2100 DATA B,They are each in separate branches.,parallel
2110 DATA 3. What is the equivalent resistance?
2120 DATA (a) 0.13 &         (b) 8.0 &
2130 DATA (c) 58 &           (d) 72 &
2140 DATA B,Eq. Resistance=Voltage/Current (24/3),8.0 &
2150 DATA 4. The power supplied is ...
2160 DATA (a) 220 w          (b) 190 watts
2170 DATA (c) 24 w           (d) 72 w
2180 DATA D,Power in a ciruit=Voltage X Current.,72 w
2190 DATA 5. The current in resistor 1 is ...
2200 DATA (a) 0.83 a         (b) 1.5 a
2210 DATA (c) 3.0 a          (d) 1.2 a
2220 DATA D,Current=Voltage/Resistance (24/20),1.2 a