A Greeting Card For All Seasons, greeting card (CARD.BAS)

A Greeting Card For All Seasons, greeting card by William L. Henson, 26

Description

A Greeting Card For All Seasons, greeting card by William L. Henson, 26

From the Antic disk of February 1984 (Vol. 2 No. 11).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 1.6 KB

Dialect
Atari BASIC
Lines
60
Variables
A$, B$, C$, D$, C, X, RAMTOP, CBASE, CADR, SPACE, DTA, L
BASIC listing (60 lines)
95 REM * ALL OCCASION CARD *
96 REM * BY WILLIAM HENSON *
97 REM *   ANTIC MAGAZINE  *
98 REM *   FEBUARY, 1984   *
99 REM *********************
100 DATA SMILE,0,60,90,126,90,102,60,0,26
110 DATA TREE,0,0,24,60,126,24,24,0,200
120 DATA CAKE,0,0,42,42,42,127,127,127,57
130 DATA LOGO,28,28,28,28,42,73,0,0,250
140 DATA CAR,0,0,56,68,127,127,34,0,70
150 DATA PICKUP,0,0,12,10,127,127,34,0,87
160 DATA VAN,0,0,126,125,127,127,34,0,156
170 DATA SHAMROCK,0,24,24,124,124,16,8,0,212
180 DATA PUMPKIN,4,8,60,90,126,66,60,0,38
190 DATA HEART,0,54,127,127,62,28,8,0,52
200 DIM A$(20)
210 DIM B$(20)
220 DIM C$(20)
230 DIM D$(20)
240 GRAPHICS 0
250 FOR C=100 TO 190 STEP 10
260 RESTORE C
270 READ C$:PRINT C;" ";C$
280 NEXT C
290 PRINT "SELECT BACKGROUND #"
300 INPUT X
310 RESTORE X
320 RAMTOP=PEEK(106)
330 CBASE=RAMTOP-4
340 POKE 106,CBASE
350 GRAPHICS 18
360 CADR=CBASE*256
370 FOR C=0 TO 1023
380 POKE CADR+C,PEEK(57344+C)
390 NEXT C
400 SPACE=CADR+64*8
410 READ C$
420 FOR C=0 TO 7
430 READ DTA:POKE (SPACE+C),DTA
440 NEXT C:READ DTA:POKE 708,DTA
450 D$=" ":D$(20)=D$:D$(2)=D$
460 A$="  happy mother's day   "
470 B$="         from          "
480 C$="  elizabeth and bill   "
490 POKE 756,CBASE+2
500 REM SETCOLOR 0,INT((14*RND(1))),2
510 SETCOLOR 1,INT((14*RND(1))),8
520 FOR X=1 TO 19
530 POSITION 0,3
540 ? #6;A$(X);:? #6;A$(1,X)
550 POSITION 0,4:? #6;D$
560 POSITION 0,6
570 ? #6;B$(X);:? #6;B$(1,X)
580 POSITION 0,7:? #6;D$
590 POSITION 0,9
600 ? #6;C$(X);:? #6;C$(1,X)
610 POSITION 0,10:? #6;D$
620 FOR L=1 TO 55:NEXT L
630 NEXT X
640 GOTO 500