Trivia Question Quiz, test generator (TRIVIA.BAS)

Trivia Question Quiz, test generator by George Stone, 25

Description

Trivia Question Quiz, test generator by George Stone, 25

From the Antic disk of January 1984 (Vol. 2 No. 10).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.2 KB

Dialect
Atari BASIC
Lines
64
Variables
R$, WORD$, SENT$, ANS$, NAME$, X, Y, BL$, SENT, DLY, S, Q
BASIC listing (64 lines)
10 DIM R$(1):DIM WORD$(100):DIM SENT$(100)
20 DIM ANS$(100):DIM NAME$(25)
30 X=0:Y=0
40 GRAPHICS 0:SETCOLOR 2,5,8:SETCOLOR 1,0,0:POKE 752,1
50 POSITION 2,8:? "TYPE THE USER'S NAME PLEASE.":? "THEN PRESS RETURN.":?
60 INPUT NAME$
70 ? CHR$(125)
80 POSITION 2,1:? NAME$
90 POSITION 2,3:? "NUMBER OF QUESTIONS    ";X
100 POSITION 2,5:? "NUMBER CORRECT         ";Y
110 POSITION 2,7:? "PERCENT CORRECT       "
120 POSITION 2,0:? "__________________________"
130 POSITION 2,8:? "__________________________"
140 DIM BL$(40)
150 BL$=" ":BL$(40)=BL$:BL$(2)=BL$
160 REM FOR DLY=1 TO 200:NEXT DLY
170 FOR SENT=1 TO 3
180 POSITION 2,12:? "QUESTION ";SENT
190 PRINT
200 READ SENT$,WORD$
210 ? SENT$
220 ? :? "NOW TYPE THE CORRECT ANSWER."
230 ? :INPUT ANS$
240 IF ANS$=WORD$ THEN 350
250 SOUND 0,29,10,10:FOR DLY=1 TO 10:NEXT DLY
260 SOUND 0,45,10,10:FOR DLY=1 TO 10:NEXT DLY
270 SOUND 0,0,0,0
280 POSITION 2,20:? "THAT IS NOT CORRECT."
290 FOR DLY=1 TO 250:NEXT DLY
300 GOSUB 570
310 POSITION 2,12:? "THE ANSWER TO"
320 ? :? SENT$:?
330 ? "IS":? :? WORD$
340 GOTO 410
350 SOUND 0,35,10,10:FOR DLY=1 TO 10:NEXT DLY
360 SOUND 0,31,10,10:FOR DLY=1 TO 10:NEXT DLY
370 SOUND 0,29,10,10:FOR DLY=1 TO 10:NEXT DLY
380 SOUND 0,0,0,0
390 POSITION 2,20:? "THAT IS CORRECT."
400 Y=Y+1:POSITION 25,5:? Y
410 X=X+1
420 POSITION 25,3:? X
430 S=INT((Y/X)*100)
440 POSITION 25,7:? "   ←←←";S
450 POSITION 2,22:? "PRESS RETURN FOR QUESTION ";SENT+1;
460 INPUT R$
470 GOSUB 570
480 NEXT SENT
490 POSITION 2,12
500 IF S=100 THEN ? "FANTASTIC! YOU DID GREAT!"
510 IF S<100 AND S>89 THEN ? "VERY GOOD! THAT'S A GOOD SCORE!"
520 IF S<90 AND S>79 THEN ? "PRETTY GOOD. YOU DID OK!"
530 IF S<80 AND S>69 THEN ? "THAT'S A FAIR SCORE. STUDY HARDER!"
540 IF S<70 THEN ? "YOU COULD DO BETTER THAN THAT!"
550 ? :? "GOODBY! ";NAME$
560 END
570 FOR Q=12 TO 23
580 POSITION 0,Q
590 ? BL$(1,39);
600 NEXT Q
610 RETURN
1000 DATA 4+2,6
1010 DATA 1+1,2
1020 DATA 3+4,7