Calling All Tapes, cassette program index (TAPEINDX.BAS)

Calling All Tapes, cassette program index by James Luczak, 89

Description

Calling All Tapes, cassette program index by James Luczak, 89

From the Antic disk of January 1984 (Vol. 2 No. 10).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 8.7 KB

Dialect
Atari BASIC
Lines
197
Variables
A$, TP$, BL$, TL$, D$, X$, Y$, B$, C$, CURSOR$, X, NULINE, BEGIN, CENT, K, COUNT, A, B, N, TIME, LIMIT, T, TL, START, TP, TRACE3, TRACE, TRACE1, TRACE4, TRACE2, LINENUM, TRACE6, L1, L2, DELAY, Y
BASIC listing (197 lines)
485 REM ***TAPE INDEX****
486 REM *BY JAMES LUCZAK*
487 REM *ANTIC MAGAZINE *
488 REM * JANUARY, 1984 *
489 REM *****************
490 ? "↰"
500 DIM A$(840),TP$(38),BL$(38),TL$(3)
510 DIM D$(4):D$="DATA":DIM X$(3),Y$(30)
512 DIM B$(40),C$(1),CURSOR$(1)
520 BL$=" ":BL$(38)=BL$:BL$(2)=BL$
521 ? CHR$(125):POKE 84,8:? :POKE 85,4:? "ENTER TAPE NUMBER ";:INPUT X$
522 ? CHR$(125):POKE 84,8:? "DO YOU WANT TO NAME TAPE":POKE 84,10:? "EX.(UTILITIES, BACK-UP) ECT."
523 POKE 84,14:? :POKE 85,12:? "(Y OR N) ";:OPEN #1,4,0,"K:":GET #1,X:CLOSE #1
524 IF X=89 THEN 527
525 IF X=78 THEN 529
526 GOTO 523
527 ? CHR$(125):POKE 84,8:? :? "ENTER TAPE NAME ":? :? :INPUT Y$
528 IF LEN(Y$)>20 THEN 2400
529 POKE 709,4:GOTO 2500
540 ? "↰":POKE 709,10
545 NULINE=1020
560 GRAPHICS 1+16
570 POKE 709,48+8
600 BEGIN=PEEK(560)+PEEK(561)*256+4
610 POKE BEGIN-1,71
620 POKE BEGIN+2,7
630 POKE BEGIN+3,7
640 POKE BEGIN+4,48
650 POKE BEGIN+5,7
660 POKE BEGIN+6,112
670 POKE BEGIN+24,65:POKE BEGIN+25,PEEK(560):POKE BEGIN+26,PEEK(561)
680 POKE 87,2:POSITION 0,0:POKE 708,250
690 FOR X=0 TO 19:? #6;"@";:NEXT X
700 POSITION 6,1:? #6;"TAPE   ";X$
710 FOR X=0 TO 19:? #6;"@";:NEXT X
720 POSITION 0,3:POKE 711,152
730 CENT=INT((20-LEN(Y$))/2)
732 IF CENT=0 THEN ? #6;Y$:GOTO 740
734 FOR X=1 TO CENT:? #6;" ";:NEXT X:? #6;Y$
740 POKE 87,1:? #6;"do you want to view"
750 POSITION 0,6:? #6;"input  V  for view"
760 POSITION 0,10:? #6;"or do you want to "
770 POSITION 0,12:? #6;"update the tape "
780 POSITION 0,14:? #6;"input  U  for update"
790 POSITION 0,18:? #6;"view or update ?"
800 OPEN #1,4,0,"K:":GET #1,X:CLOSE #1
830 IF X=85 THEN 1335
840 IF X=86 THEN 870
850 GOTO 560
870 ? "↰":POKE 709,0:POKE 710,246:POKE 712,246:POKE 752,1
880 FOR X=0 TO 14:READ B$
890 IF B$="DONE" THEN K=1:GOTO 920
900 ? B$
910 NEXT X
920 ? :POKE 85,8:? "   V = VIEW NEXT PAGE"
930 ? :POKE 85,8:? "   U = UPDATE PROGRAM"
940 ? :POKE 85,8:? "   E = END PROGRAM"
942 IF NULINE=1320 THEN ? :? "DATA BUFFER FULL.CAN'T ADD NEW DATA"
945 IF COUNT=4 THEN COUNT=0:? :? "NO DATA TO EDIT YET"
950 OPEN #1,4,0,"K:":GET #1,X:CLOSE #1
960 IF X=86 THEN 1000
970 IF X=69 THEN ? CHR$(125):GRAPHICS 0:END
980 IF X=85 THEN 1335
990 ? CHR$(125):GOTO 920
1000 ? "↰":IF K=1 THEN K=0:RESTORE 1020:GOTO 870
1010 IF K=0 THEN 870
1320 DATA DONE
1335 ? CHR$(125):POSITION 12,0:? "DATA EDIT MODE"
1340 POSITION 3,5:? "(1) = ADD TITLES TO TAPE"
1350 POSITION 3,7:? "(2) = CHANGE OR DELETE TITLES ON TAPE"
1360 POSITION 3,9:? "(3) = EXIT EDIT MODE"
1365 IF NULINE=1320 THEN ? :? :POKE 85,10:? "DATA BUFFER IS FULL"
1367 IF NULINE=1320 THEN ? :? :POKE 85,6:? "NO NEW DATA ENTRIES CAN BE MADE"
1370 OPEN #1,4,0,"K:":GET #1,X:CLOSE #1
1380 IF X=49 THEN 1402
1390 IF X=50 THEN 1410
1395 IF X=51 THEN ? CHR$(125):GOTO 920
1400 GOTO 1370
1402 IF NULINE=1320 THEN 1335
1404 GOTO 1590
1410 ? CHR$(125):POSITION 2,4:? "TO DELETE AN ENTIRE LINE,TYPE SPACES  OVER EVERYTHING EXCEPT THE LINE NUMBER"
1411 ? :POKE 85,13:? "** CHANGES **":?
1412 ? "USE CURSOR CONTROL ARROWS TO POSITION CURSOR.THEN TYPE OVER THE ENTRY TO BE CHANGED"
1420 ? :? "IF NO CHANGES ARE TO BE MADE JUST HIT RETURN AND THE REST OF THE PAGE YOU   ARE WORKING ON WILL APPEAR"
1430 ? :? "DO NOT HIT RETURN UNTIL ALL CHANGES   ARE MADE..REGARDLESS OF LINE NUMBERS.."
1442 ? :? "HIT ANY KEY TO CONTINUE ":OPEN #1,4,0,"K:":GET #1,X:CLOSE #1
1444 POKE 752,0:? CHR$(125):COUNT=0:GOSUB 1502
1450 ? CHR$(125):POSITION 2,2:? " ":LIST A,B:POSITION 4,22:? "HIT <<RETURN>> AFTER ALL CHANGES"
1455 POSITION 4,23:? "ARE MADE"
1460 POSITION 2,1:INPUT CURSOR$
1480 POSITION 0,0:POKE 842,13:POSITION 2,20:? "CONT":POSITION 2,0:STOP
1490 POKE 842,12
1492 ON COUNT GOTO 1508,1514,1520
1500 ? CHR$(125):GOTO 920
1502 IF NULINE<1080 THEN A=1020:B=NULINE
1504 IF NULINE>=1080 THEN A=1020:B=1080:COUNT=1
1505 IF NULINE=1020 THEN COUNT=4:GOTO 920
1506 RETURN
1508 IF NULINE<1160 THEN A=1090:B=NULINE:COUNT=0
1510 IF NULINE>=1160 THEN A=1090:B=1160:COUNT=2
1512 GOTO 1450
1514 IF NULINE<1230 THEN A=1170:B=NULINE:COUNT=0
1516 IF NULINE>=1230 THEN A=1170:B=1230:COUNT=3
1518 GOTO 1450
1520 A=1240:B=NULINE:COUNT=0:GOTO 1450
1590 ? CHR$(125):N=1:POKE 709,10:POKE 752,1:TIME=1:LIMIT=1:IF NULINE=1320 THEN 920
1600 POKE 84,7:POKE 85,33:? "|":POKE 84,4:POKE 85,4:? "ENTER PROGRAM NAME ":POKE 710,50:POKE 712,50
1602 FOR X=7 TO 12:POKE 84,X:POKE 85,33:? "|":NEXT X
1604 POKE 85,4:? "PROGRAM NAME LIMIT";
1606 FOR X=1 TO 11:? "─";:NEXT X:? "┘"
1610 POSITION 4,2:? "ENTER <<DONE>> WHEN FINISHED"
1619 IF T=1 THEN T=0:POKE 710,68:POKE 712,68
1620 POSITION 4,6:INPUT TP$
1630 IF TP$="DONE" THEN 1910
1640 TL=LEN(TP$):TIME=TIME+1
1650 IF TL>28 THEN GOSUB 2200:GOSUB 2260:GOTO 1600
1655 IF ASC(TP$)>=48 AND ASC(TP$)<=57 THEN GOSUB 2200:GOSUB 2282:GOTO 1600
1660 IF TL<28 THEN TP$(TL+1)=BL$
1670 START=(N-1)*28+1
1680 A$(START)=TP$
1690 N=N+1:? CHR$(125):POKE 710,196:POKE 712,196
1700 POSITION 4,4:? "ENTER PROGRAM <<START>> COUNT "
1710 TRAP 1759:POSITION 4,6:INPUT TP:TP$=STR$(TP)
1720 IF TP>999 THEN GOTO 1759
1730 IF TRACE3=1 THEN TRACE3=0:IF TP<=VAL(A$(START,START+27)) THEN 1790
1740 IF TRACE=1 THEN RETURN
1750 GOTO 1820
1759 GOSUB 2200:POKE 710,66:POKE 712,66
1760 ? CHR$(125):POSITION 2,11:? "PROGRAM COUNT MUST BE NO MORE  THEN 3 DIGITS":TRACE1=1
1770 IF TRACE=1 THEN 1880
1780 GOTO 1700
1790 IF TRACE4=1 THEN TRACE4=0:? CHR$(125)
1799 POKE 710,66:POKE 712,66:GOSUB 2200
1800 ? CHR$(125):POSITION 4,10:? :? "PROGRAM END COUNT MUST BE LARGER THEN PROGRAM START COUNT ":TRACE4=1
1810 ? :? " START COUNT =  ";A$(START,START+27):GOTO 1880
1820 TL=LEN(TP$)
1830 IF TL<28 THEN TP$(TL+1)=BL$
1840 START=(N-1)*28+1
1850 A$(START)=TP$
1860 N=N+1:? CHR$(125):POKE 710,210:POKE 712,210
1865 IF TRACE=1 THEN TRACE=0:LIMIT=LIMIT+1:IF LIMIT=8 THEN 2300
1870 IF TRACE2=1 THEN TRACE2=0:GOTO 1600
1880 POSITION 6,4:? "ENTER PROGRAM <<END>> COUNT ":TRACE=1
1890 TRAP 1759:POSITION 6,6:INPUT TP:TP$=STR$(TP)
1900 TRACE2=1:TRACE3=1:GOSUB 1720:GOTO 1820
1910 IF TIME=1 THEN K=1:GOTO 2060
1915 LINENUM=NULINE:POKE 709,2
1920 ? CHR$(125):POSITION 2,2:? " "
1930 FOR X=1 TO N-1
1940 START=(X-1)*28+1
1950 IF ASC(A$(START,START+27))>=48 AND ASC(A$(START,START+27))<=57 THEN GOSUB 2070:GOTO 2000
1960 ? LINENUM;" ";D$;" ";
1970 ? A$(START,START+27);
1980 LINENUM=LINENUM+10
1985 IF LINENUM>=1320 THEN 2015
1990 NULINE=LINENUM
2000 NEXT X
2005 FOR X=2520 TO 2524 STEP 2:? X:NEXT X:? "2005 ? 945:? 1505 :? 2005"
2015 POSITION 2,22:? "545 ";"NULINE = ";LINENUM
2020 POSITION 0,0:? " ":POKE 842,13:POSITION 2,23:? "CONT":POSITION 2,0:STOP
2050 POKE 842,12
2055 IF LIMIT=8 THEN 1590
2060 ? CHR$(125):POKE 709,0:POKE 710,246:POKE 712,246:GOTO 920
2070 TL$=A$(START,START+27)
2080 IF TRACE6=1 THEN TRACE6=0:? TL$;")":GOTO 2100
2090 ? "(";TL$;"-";:TRACE6=1
2100 RETURN
2200 FOR L1=14 TO 2 STEP -0.5
2210 FOR L2=50 TO 75 STEP 20
2220 SOUND 0,75-L2,10,L1
2230 NEXT L2
2240 NEXT L1
2250 RETURN
2260 ? CHR$(125):POSITION 2,10:? "PROGRAM NAME IS ";TL-28;" CHARACTERS TOO LONG":T=1
2270 POKE 710,68:POKE 712,68
2280 RETURN
2282 ? CHR$(125):POSITION 2,10:? "PROGRAM NAME MUST NOT START      WITH A NUMERAL"
2284 POKE 84,15:? "PROGRAM NAME ";TP$:POKE 710,68:POKE 712,68:RETURN
2300 POKE 710,50:POKE 712,50
2302 ? CHR$(125):POKE 84,8:? :POKE 85,14:? "LOADING DATA.":? :? :POKE 85,7:? "WILL CONTINUE IN A MINUITE"
2305 TRACE2=0:TRACE3=0:TRACE=0
2310 FOR DELAY=1 TO 250:NEXT DELAY:GOTO 1915
2400 ? CHR$(125):POKE 84,14:? "NAME IS ";(LEN(Y$)-20);" TOO LONG"
2410 POKE 84,8:? :? "ENTER TAPE NAME ":? :? :INPUT Y$
2420 IF LEN(Y$)>20 THEN 2400
2430 GOTO 529
2500 ? CHR$(125):POSITION 2,2:? " ":FOR Y=521 TO 529:? Y:NEXT Y:FOR Y=2400 TO 2430 STEP 10:? Y:NEXT Y
2502 ? "535 Y$ = ";CHR$(34);Y$;CHR$(34)
2504 ? "530 X$ = ";CHR$(34);X$;CHR$(34)
2506 POSITION 0,0:POKE 842,13:POSITION 2,23:? "CONT":POSITION 2,0:STOP
2508 POKE 842,12
2510 FOR DELAY=1 TO 50:NEXT DELAY
2512 ? CHR$(125):POSITION 2,2:? " ":FOR Y=2500 TO 2514 STEP 2:? Y:NEXT Y:POSITION 0,0:POKE 842,13
2514 POSITION 2,23:? "CONT":POSITION 2,0:STOP
2520 POKE 842,12
2522 POKE 842,12
2524 GOTO 540