Rotating Fonts, printing utility (ROTFONT.BAS)

Rotating Fonts, printing utility by Sol Guber, 48

Description

Rotating Fonts, printing utility by Sol Guber, 48

From the Antic disk of January 1984 (Vol. 2 No. 10).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 1.3 KB

Dialect
Atari BASIC
Lines
29
Variables
C0, C1, C2, C3, C4, C5, C6, C7, C8, C9, C10, C40, C128, C256, C1120, C1125, C39, C350, FONT$, NFONT, OUT$, OUTADR, NECHAR, SCREEN, K, DOT, CHAR, OLDFONT, J, N, U, AB, KK, SP
BASIC listing (29 lines)
1 REM *ROTATING FONTS*
2 REM * BY SOL GUBER *
3 REM *ANTIC MAGAZINE*
4 REM *JANUARY, 1984 *
5 REM ****************
10 C0=0:C1=1:C2=2:C3=3:C4=4:C5=5:C6=6:C7=7:C8=8:C9=9:C10=10:C40=40:C128=128:C256=256
15 C1120=1120:C1125=1125:C39=39:C350=350:C40=40
20 DIM FONT$(1090):NFONT=ADR(FONT$)
30 FONT$(C1)=CHR$(C0):FONT$(1030)=CHR$(C0):FONT$(C2)=FONT$
95 GOSUB 1000
100 DIM OUT$(320)
105 OUT$(1)="♥":OUT$(320)="♥":OUT$(2)=OUT$
110 OUTADR=ADR(OUT$):NECHAR=PEEK(756)*256
120 SCREEN=PEEK(88)+256*PEEK(89)
200 LIST 1000,2000
300 REM
330 K=SCREEN
350 FOR DOT=C0 TO C39:CHAR=PEEK(K+DOT):OUT$(DOT*C8+C1,DOT*C8+C8)=FONT$(CHAR*C8+C1,CHAR*C8+C8):NEXT DOT
450 LPRINT "␛S0320";OUT$;"    "
500 IF K<SCREEN+880 THEN K=K+C40:GOTO C350
999 STOP
1000 OLDFONT=PEEK(756)*256:POKE 559,0:FOR J=C0 TO 1027 STEP C8
1110 N=C1:U=C0
1120 AB=PEEK(OLDFONT+J+U):KK=C7
1125 SP=NFONT+J+KK
1130 IF AB/C2<>INT(AB/C2) THEN POKE SP,PEEK(SP)+N
1140 AB=INT(AB/C2):KK=KK-C1:IF KK>C0 THEN GOTO C1125
1150 N=N*C2:U=U+C1:IF U<C8 THEN GOTO C1120
1180 NEXT J:POKE 559,34:RETURN