Disk Label Printer (DISKLABL.BAS)
Disk Label Printer, by Richard Kushner, 58
Description
Disk Label Printer, by Richard Kushner, 58
From the Antic disk of January 1984 (Vol. 2 No. 10).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 1.2 KB
- Dialect
- Atari BASIC
- Lines
- 30
- Variables
B$,N$,X,N,CTR,RECCTR,INDEX,MARKER,I
BASIC listing (30 lines)
1 REM SUPER DISK LABEL PROGRAM by Richard Kushner
2 REM ANTIC MAGAZINE, JANUARY 1984
10 DIM B$(17),N$(40)
20 ? "↰":? "LOAD PRINTER WITH LABELS.":?
21 ? "TURN ON PRINTER/850 INTERFACE UNIT.":?
22 ? "INSERT DISKETTE INTO DRIVE #1.":?
23 ? "PRESS RETURN WHEN READY.":?
25 INPUT N$
28 TRAP 500
30 OPEN #7,8,0,"P:"
33 PUT #7,27:PUT #7,51:PUT #7,18
37 ? #7;CHR$(15);:? #7;CHR$(27);CHR$(83);
40 CLOSE #2:? "ENTER DISKETTE NAME (RETURN FOR END)":INPUT N$
42 IF N$="" THEN CLOSE #2:CLOSE #7:END
45 X=0:N=0:CTR=0:RECCTR=0:INDEX=13
50 ? #7;" DISK = ";N$
60 RECCTR=RECCTR+4
100 OPEN #2,6,0,"D:*.*"
120 TRAP 310:INPUT #2,B$
130 ? #7;B$;" ";:CTR=CTR+1:RECCTR=RECCTR+1:IF B$(4,5)=" F" THEN 310
135 IF CTR=4 THEN PRINT #7:CTR=0
137 IF RECCTR=40 THEN PRINT #7:PRINT #7:RECCTR=0
140 GOTO 120
310 IF RECCTR=0 THEN GOTO 320
312 MARKER=INT(RECCTR/4)
314 IF CTR<>4 THEN MARKER=MARKER+1
316 FOR I=1 TO INDEX-MARKER:PRINT #7:NEXT I
320 GOTO 40
500 TRAP 40000:IF PEEK(195)=138 THEN 20
510 ? "ERROR #";PEEK(195);" AT LINE ";PEEK(186)+256*PEEK(187):STOP
