Pocket Calendars, calendar generator (CALENDER.BAS)

Pocket Calendars, calendar generator, 31

Description

Pocket Calendars, calendar generator, 31

From the Antic disk of January 1984 (Vol. 2 No. 10).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.2 KB

Dialect
Atari BASIC
Lines
56
Variables
B$, T1B$, DL$, DAY(, M$, P$, BASEYEAR, STARTOFF, LEAPFLAG, CUROFF, ML, YEAR, OFFSET, TEMPOFF, L2, MONTH, DIF, TEMPYEAR, L, L3, L4, LD, L5
BASIC listing (56 lines)
95 REM *****CALENDER*****
96 REM *BY BILL LUKEROTH*
97 REM * ANTIC MAGAZINE *
98 REM * JANUARY, 1984  *
99 REM ******************
100 DIM B$(36),T1B$(36),DL$(36),DAY(42),M$(10),P$(2)
110 B$="|    |    |    |    |    |    |    |"
120 DL$="------------------------------------"
130 BASEYEAR=1950:STARTOFF=0:LEAPFLAG=0:CUROFF=450
140 GRAPHICS 0:GOTO 5000
440 REM ++++++++++ curoff ++++++++++
450 POKE 752,1:RETURN :REM turn cursor off
800 READ M$,ML
810 IF ML=3 AND YEAR/4=INT(YEAR/4) THEN ML=2
830 OFFSET=TEMPOFF
840 IF L2<MONTH THEN TEMPOFF=(OFFSET+3)-ML
845 IF TEMPOFF>=7 THEN TEMPOFF=TEMPOFF-7
850 RETURN
5000 ? "CALENDAR FOR WHAT MONTH(INPUT NUMBER, NOT NAME)";:INPUT MONTH
5010 ? :? "FOR WHAT YEAR";:INPUT YEAR:LEAPFLAG=0
5020 IF YEAR<BASEYEAR THEN ? :GOTO 5010
5030 DIF=YEAR-BASEYEAR:TEMPOFF=STARTOFF:TEMPYEAR=BASEYEAR
5040 FOR L=1 TO DIF
5050 TEMPOFF=TEMPOFF+1:TEMPYEAR=TEMPYEAR+1
5060 IF TEMPYEAR/4=INT(TEMPYEAR/4) THEN TEMPOFF=TEMPOFF+1
5070 IF TEMPOFF>=7 THEN TEMPOFF=TEMPOFF-7
5080 NEXT L
5090 IF YEAR/4=INT(YEAR/4) THEN LEAPFLAG=1
5100 IF LEAPFLAG=1 THEN TEMPOFF=TEMPOFF-1:IF TEMPOFF<0 THEN TEMPOFF=TEMPOFF+7
5110 FOR L2=1 TO MONTH
5120 GOSUB 800
5150 NEXT L2
5160 OFFSET=TEMPOFF
5165 T1B$=B$
5166 ? "DO YOU WANT THIS ON THE:":? "   SCREEN":? "   PRINTER":? :? "(TYPE S OR P)":INPUT P$
5167 IF P$<>"S" AND P$<>"P" THEN ? :GOTO 5166
5168 P$(2,2)=":":OPEN #1,8,0,P$:GOSUB CUROFF
5170 ? #1;"               ";M$:? #1;
5180 ? #1;"   S    M    T    W    T    F    S"
5190 ? #1;DL$
5200 FOR L3=1 TO 42:DAY(L3)=0:NEXT L3
5210 FOR L4=1 TO 42
5220 DAY(L4)=L4-OFFSET:IF DAY(L4)<0 THEN DAY(L4)=0
5230 IF L4-OFFSET>30-ML THEN L4=1:POP :GOTO 5250
5240 NEXT L4
5250 LD=-2
5255 FOR L5=1 TO 42
5260 LD=LD+5:IF LD>33 THEN ? #1;T1B$:? #1;B$:? #1;B$:? #1;B$:? #1;B$:? #1;B$:? #1;B$:? #1;DL$:T1B$=B$:LD=3
5270 IF DAY(L5)=0 THEN 5400
5280 IF DAY(L5)<10 THEN T1B$(LD+1,LD+1)=STR$(DAY(L5)):GOTO 5400
5290 T1B$(LD,LD+1)=STR$(DAY(L5))
5400 NEXT L5
5410 ? #1;T1B$:? #1;B$:? #1;B$:? #1;B$:? #1;B$:? #1;B$:? #1;B$:? #1;DL$
9999 END
10010 DATA JANUARY,0,FEBRUARY,3,MARCH,0,APRIL,1,MAY,0,JUNE,1,JULY,0,AUGUST,0,SEPTEMBER,1,OCTOBER,0,NOVEMBER,1
10020 DATA DECEMBER,0