GTIA Sketchpad, graphics utility (GTIAPAD.BAS)

GTIA Sketchpad, graphics utility by Scott Bertfield, 137

Description

GTIA Sketchpad, graphics utility by Scott Bertfield, 137

From the Antic disk of December 1983 (Vol. 2 No. 9).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 9.5 KB

Dialect
Atari BASIC
Lines
209
Variables
CHOICE$, CHOICE1$, XP, YP, VAL, C, OPT, KEY, NOKEY, N0, JOYSTICK, YP1, LEFT, DOWN, FLAG, DFLAG, Q, COLR, OXP, OYP, OVAL, XD(, YD(, OB, B, OB1, N1, OC, N2, CMAX, CMIN, BMAX, BMIN, BAR(, CXP, CYP, Z, XMAX, YMAX, BX, BY, SCALE, XC, YC, XR, YR, XD, YD, R, X, Y, DIAMETER, FILE$, RTOP, BASE, BTS, HI, LO, DUM, A, X2, MODE, BKGND, SETUP, H, L, C(, SHD, I, J, BUFFER$, GREY$, GRAY(, N, DL, P, PTR
BASIC listing (209 lines)
7 REM ***    GTIA SKETCHPAD       **
9 REM ***    SCOTT BERFIELD       **
10 REM **    ANTIC MAGAZINE       **
20 GRAPHICS 0:POKE 82,1:POKE 752,1
30 GOSUB 1520:GOSUB 1260
40 ? CHR$(125);CHOICE$;CHOICE1$:LOCATE XP,YP,VAL:COLOR C:PLOT XP,YP
50 OPT=PEEK(KEY):IF OPT<>NOKEY THEN POKE KEY,NOKEY:GOSUB 70
60 COLOR ABS(C-8):PLOT XP,YP:COLOR C:PLOT XP,YP:COLOR VAL:PLOT XP,YP:GOTO 50
70 IF OPT=10 THEN GOTO 580
80 IF OPT=N0 THEN GOTO 620
90 IF OPT=58 THEN GOTO 660
100 IF OPT=21 THEN GOTO 840
110 IF OPT=18 THEN GOTO 880
120 IF OPT=56 THEN GOTO 210
130 IF OPT=62 THEN GOTO 1070
140 IF OPT=40 THEN GOTO 1130
150 IF OPT=47 THEN GOTO 1200
160 IF OPT=7 THEN GOTO 490
170 IF OPT=6 THEN GOTO 520
180 IF OPT=35 THEN GOTO 1200
185 IF OPT=57 THEN GOTO 30000:REM FOR PRINTER DUMPING ONLY
190 IF OPT=46 THEN 1250
200 GOTO 50
210 ? CHR$(125);"PLACE CURSOR WITHIN THE OUTLINE AND    PRESS TRIGGER(ESC TO EXIT)."
214 TRAP 40
215 IF PEEK(KEY)=28 THEN POKE KEY,NOKEY:GOTO 40
220 GOSUB JOYSTICK
230 COLOR C
240 YP1=YP:LEFT=270:DOWN=320:FLAG=0:DFLAG=0
250 FOR Q=XP TO 319-XP:LOCATE Q,YP,COLR:IF COLR=C THEN GOTO LEFT
260 PLOT Q,YP:NEXT Q
270 FOR Q=XP-1 TO 1 STEP -1:LOCATE Q,YP,COLR:IF COLR=C THEN 290
280 PLOT Q,YP:NEXT Q
290 IF FLAG=1 THEN GOTO DOWN
300 YP=YP-1:LOCATE XP,YP,COLR:IF COLR=C THEN FLAG=1:GOTO DOWN
310 GOTO 250
320 IF DFLAG=1 THEN 340
330 YP=YP1:DFLAG=1
340 YP=YP+1:LOCATE XP,YP,COLR:IF COLR=C THEN GOTO 210
350 GOTO 250
360 TRAP 40000:GOTO 40
370 IF STRIG(N0)=N0 THEN COLOR C:RETURN
380 IF PEEK(KEY)=6 THEN POKE KEY,NOKEY:GOSUB 520
390 IF PEEK(KEY)=7 THEN POKE KEY,NOKEY:GOSUB 490
400 IF PEEK(KEY)=28 THEN POKE KEY,NOKEY:GOTO 40
410 OXP=XP:OYP=YP:OVAL=VAL
420 XP=XP+XD(STICK(N0)):YP=YP+YD(STICK(N0))
430 IF XP>79 THEN XP=0
440 IF XP<0 THEN XP=79
450 IF YP>149 THEN YP=0
460 IF YP<0 THEN YP=149
470 LOCATE XP,YP,VAL:COLOR OVAL:PLOT OXP,OYP
480 COLOR C:PLOT XP,YP:COLOR ABS(C-8):PLOT XP,YP:COLOR VAL:PLOT XP,YP:GOTO 370
490 OB=B:OB1=OB+N1:OC=C:B=B+N2:C=C+N1:IF C>CMAX THEN C=CMIN
500 IF B>BMAX THEN B=BMIN
510 GOTO 540
520 OB=B:OB1=OB+N1:OC=C:B=B-N2:C=C-N1:IF C<CMIN THEN C=CMAX
530 IF B<BMIN THEN B=BMAX
540 COLOR OC:PLOT BAR(OB),159:DRAWTO BAR(OB1),159
550 IF C<INT(0.5*CMAX)+N1 THEN COLOR CMAX
560 IF C>=INT(0.5*CMAX)+N1 THEN COLOR CMIN
570 PLOT BAR(B),159:DRAWTO BAR(B+N1),159:COLOR C:RETURN
580 ? CHR$(125);"POSITION CURSOR AND PRESS TRIGGER TO   PLOT POINTS(ESC TO EXIT)."
585 IF PEEK(KEY)=28 THEN POKE KEY,NOKEY:GOTO 40
590 GOSUB JOYSTICK
600 PLOT XP,YP
610 GOTO 580
620 ? CHR$(125);"POSITION CURSOR AND PRESS TRIGGER TO   PLOT STARTING POINT(ESC TO EXIT)."
630 GOSUB JOYSTICK:PLOT XP,YP:CXP=XP:CYP=YP
640 ? CHR$(125);"NOW POSITION CURSOR AT ENDPOINT AND    PRESS TRIGGER(ESC TO EXIT)."
650 GOSUB JOYSTICK:PLOT CXP,CYP:DRAWTO XP,YP
655 IF PEEK(KEY)=28 THEN POKE KEY,NOKEY:GOTO 40
656 GOTO 620
660 ? CHR$(125);"USE JOYSTICK TO DRAW, HOLD TRIGGER FOR A THICK LINE, PRESS ESC TO EXIT TO MENU"
670 Z=PEEK(KEY):IF Z<>NOKEY THEN POKE KEY,NOKEY
680 IF Z=6 THEN GOSUB 520
690 IF Z=7 THEN GOSUB 490
700 IF Z=28 THEN GOTO 40
710 IF STRIG(N0)=N0 THEN 770
720 XP=XP+XD(STICK(N0)):YP=YP+YD(STICK(N0)):IF XP<N0 THEN XP=79
730 IF XP>XMAX THEN XP=N0
740 IF YP<N0 THEN YP=YMAX
750 IF YP>YMAX THEN YP=N0
760 COLOR ABS(C-CMAX):PLOT XP,YP:COLOR C:PLOT XP,YP:GOTO 670
770 IF STRIG(N0) THEN 670
780 XP=XP+XD(STICK(N0)):YP=YP+YD(STICK(N0)):IF XP>78 THEN XP=N1
790 IF XP<N1 THEN XP=N1
800 IF YP<N1 THEN XP=78
810 IF YP>148 THEN YP=N1
820 PLOT XP-N1,YP-N1:DRAWTO XP+N1,YP-N1:PLOT XP+N1,YP:DRAWTO XP-N1,YP:PLOT XP-N1,YP+N1:DRAWTO XP+N1,YP+N1
830 GOTO 770
840 ? CHR$(125);"POSITION CURSOR TO LOWER RIGHT CORNER  OF BOX AND PRESS TRIGGER."
850 GOSUB JOYSTICK:PLOT XP,YP:BX=XP:BY=YP:? CHR$(125);"NOW POSITION TO UPPER LEFT AND PRESS   TRIGGER TO PLOT";
870 GOSUB JOYSTICK:PLOT XP,YP:DRAWTO BX,YP:DRAWTO BX,BY:DRAWTO XP,BY:DRAWTO XP,YP:GOTO 40
880 TRAP 880:? CHR$(125);"ENTER ROUNDNESS(1=3 TO 1 ELLIPSE, .275=ROUND)";:INPUT SCALE
890 ? "NOW PLACE THE CURSOR AT THE CENTER OF  THE CIRCLE AND PRESS THE TRIGGER.":GOSUB JOYSTICK:XC=XP:YC=YP
900 ? CHR$(125);"NOW POSITION THE CURSOR TO A POINT ON  THE CIRCUMFERANCE OF THE CIRCLE AND    PRESS THE TRIGGER."
910 GOSUB JOYSTICK:XR=XP:YR=YP:IF XC>XR THEN XD=XC-XR
920 IF XC>XR THEN XD=XC-XR:GOTO 940
930 XD=XR-XC
940 IF YC>YR THEN YD=YC-YR:GOTO 960
950 YD=YR-YC
960 IF XC=XR THEN R=YD:GOTO 990
970 IF YC=YR THEN R=XD:GOTO 990
980 R=SQR((XD*XD)+(YD*YD))
990 X=0:Y=R:DIAMETER=3-2*R
1000 IF X<=Y THEN GOSUB 1040:IF DIAMETER<0 THEN DIAMETER=DIAMETER+4*X+6:X=X+1:GOTO 1000
1010 IF X>Y THEN TRAP 40000:GOTO 40
1020 DIAMETER=DIAMETER+4*(X-Y)+10
1030 Y=Y-1:X=X+1:GOTO 1000
1040 TRAP 1060:PLOT XC+(X*SCALE),YC+Y:PLOT XC+(Y*SCALE),YC+X:PLOT XC+(Y*SCALE),YC-X:PLOT XC+(X*SCALE),YC-Y
1050 PLOT XC-(X*SCALE),YC-Y:PLOT XC-(Y*SCALE),YC-X:PLOT XC-(Y*SCALE),YC+X:PLOT XC-(X*SCALE),YC+Y
1060 RETURN
1070 TRAP 1070:? CHR$(125);"INPUT FILE NAME (E TO EXIT).":INPUT FILE$:IF FILE$(1,1)="E" THEN TRAP 40000:GOTO 40
1080 OPEN #N1,8,128,FILE$
1090 RTOP=256*PEEK(106):BASE=PEEK(88)+256*PEEK(89):BTS=RTOP-BASE:HI=INT(BTS/256):LO=BTS-(HI*256)
1100 POKE 850,11:POKE 852,PEEK(88):POKE 853,PEEK(89):POKE 856,LO:POKE 857,HI
1110 DUM=USR(ADR("hhh*LVd"),16):CLOSE #N1:REM * AND d inverse
1120 TRAP 40000:GOTO 40
1130 TRAP 1130:? CHR$(125);"LOAD FROM WHICH FILE (E FOR MENU";:INPUT FILE$
1140 IF FILE$(1,1)="E" THEN TRAP 40000:GOTO 40
1150 OPEN #N1,4,128,FILE$
1170 POKE 850,7:POKE 852,PEEK(88):POKE 853,PEEK(89):POKE 856,NOKEY:POKE 857,NOKEY
1180 DUM=USR(ADR("hhh*LVd"),16):CLOSE #N1:REM * AND d inverse
1190 TRAP 40000:GOTO 40
1200 ? CHR$(125);"DO YOU WANT TO SAVE THIS IMAGE FIRST?":OPEN #N2,4,N0,"K:":GET #N2,A
1210 IF CHR$(A)<>"Y" AND CHR$(A)<>"N" THEN CLOSE #N2:GOTO 1200
1220 IF CHR$(A)="Y" THEN GOSUB 1070
1230 IF OPT=47 THEN END
1240 IF OPT=35 THEN RUN
1250 COLOR C:FOR X2=N0 TO 79:PLOT X2,N0:DRAWTO X2,YMAX:NEXT X2:GOTO 40
1260 REM *** MODE SELECTION ***
1270 ? CHR$(125)
1280 ? :? "PLEASE SELECT A GRAPHICS MODE:"
1290 ? :? "1  MODE 9▶16 SHADES OF ONE HUE"
1300 ? :? "2  MODE 10▶9 HUE/SHADE COMBINATIONS"
1310 ? :? "3  MODE 11▶16 HUES OF ONE SHADE":?
1315 ? :? "    DO NOT PRESS RETURN"
1320 OPEN #N2,4,N0,"K:":GET #N2,A
1330 CLOSE #N2:ON A-48 GOTO 1340,1370,1460
1340 MODE=9:? CHR$(125);"GRAPHICS MODE 9 GIVES YOU 16 SHADES OF ANY ONE HUE."
1350 ? :? "WHAT BACKGROUND COLOR WOULD YOU LIKE   TO USE(0-15)";:INPUT BKGND:GRAPHICS 8:POKE 752,1
1360 POKE 623,64:POKE 87,MODE:BMIN=N1:BMAX=31:CMAX=15:SETCOLOR 4,BKGND,N0:GOSUB 1600:B=N1:GOTO SETUP
1370 MODE=10:? CHR$(125);"GRAPHICS MODE 10 GIVES YOU YOUR CHOICE OF ANY 9 HUE/SHADE COMBINATIONS.":?
1380 FOR Q=N0 TO 8
1390 POSITION N2,15:? "COLOR #";Q;" HUE,SHADE(0-15)      ◀◀◀◀◀◀";:INPUT H,L
1400 IF H<N0 OR H>15 OR L<N0 OR L>15 THEN 1390
1410 C(Q)=H*16+L:NEXT Q
1420 BMIN=9:BMAX=25:CMAX=8:GRAPHICS 8:POKE 623,128:POKE 87,MODE:FOR Q=704 TO 712:POKE Q,C(Q-704):NEXT Q
1430 POKE 752,1:GOSUB 1600
1450 B=BMIN:GOTO SETUP
1460 MODE=11:? CHR$(125);"GRAPHICS MODE 11 GIVES YOU 16 HUES OF ANY ONE SHADE.":?
1470 ? :? "WHAT SHADE(0-15) WOULD YOU LIKE";:INPUT SHD
1480 GRAPHICS 8:POKE 752,1:POKE 623,192:POKE 87,MODE:GOSUB 1600:SETCOLOR 4,N0,SHD:BMIN=N1:BMAX=31:CMAX=15:B=N1
1490 C=CMIN:COLOR C:FOR I=BAR(BMIN) TO BAR(BMAX) STEP 4:FOR J=0 TO 3:PLOT I+J,150:DRAWTO I+J,159:NEXT J
1500 C=C+N1:COLOR C:NEXT I:C=CMIN
1510 COLOR C:XP=39:YP=79:COLOR ABS(C-CMAX):PLOT BAR(BMIN),159:DRAWTO BAR(BMIN+N1),159:RETURN
1520 POKE 559,0
1530 DIM XD(15),YD(15),BAR(32),C(8),CHOICE$(80),CHOICE1$(40),FILE$(20),BUFFER$(400),GREY$(32),GRAY(3,15)
1540 CMIN=N0:N0=0:N1=1:N2=2:XMAX=79:YMAX=149:SCALE=0.275:SETUP=1490:JOYSTICK=370:KEY=764:NOKEY=255
1550 FOR Q=1 TO 15:READ N:XD(Q)=N:READ N:YD(Q)=N:NEXT Q
1560 DATA 0,0,0,0,0,0,0,0,1,1,1,-1,1,0,0,0,-1,1,-1,-1,-1,0,0,0,0,1,0,-1,0,0
1570 FOR Q=1 TO 32:READ N:BAR(Q)=N:NEXT Q
1580 DATA 8,11,12,15,16,19,20,23,24,27,28,31,32,35,36,39,40,43,44,47,48,51,52,55,56,59,60,63,64,67,68,71
1590 CHOICE$="Point, Line, Doodle, Box, Circle, Fill,Whole screen, Save, Retreive"
1591 CHOICE1$="  Hardcopy,              New, Quit":POKE 559,34:RETURN :REM Use INVERSE to begin each word
1600 DL=PEEK(560)+256*PEEK(561)
1610 POKE 559,0
1620 POKE DL+166,143
1630 POKE 513,6:POKE 512,0
1640 FOR I=1536 TO 1546
1650 READ A:POKE I,A:NEXT I
1660 DATA 72,169,0,141,10,212,141,27,208,104,64
1670 POKE 54286,192
1680 POKE 559,34:RETURN
30000 ? CHR$(125);"Random or Patterned?(esc to exit)"
30010 OPEN #3,4,0,"K:":GET #3,A:CLOSE #3:IF A=ASC("P") THEN GOTO 30230
30020 IF A=27 THEN GOTO 40
30030 TRAP 30210
30040 OPEN #7,8,0,"P:"
30050 FOR Y=0 TO 15:FOR X=0 TO 3
30060 READ Q:GRAY(X,Y)=Q
30070 NEXT X:NEXT Y
30080 DATA 255,255,255,255,254,253,251,247
30090 DATA 254,222,253,219,222,219,187,183
30100 DATA 222,181,213,183,181,213,244,173
30110 DATA 181,177,213,149,177,149,212,165
30120 DATA 177,145,149,84,145,148,84,161
30130 DATA 145,33,148,68,33,36,68,72
30140 DATA 33,1,36,8,1,4,16,64
30150 DATA 0,4,0,64,0,0,0,0
30160 BUFFER$(1)="␛":BUFFER$(2)="K":BUFFER$(3)=CHR$(128):BUFFER$(4)=CHR$(1)
30170 ? #7:? #7:? #7;CHR$(27);"A";CHR$(8)
30180 FOR X=79 TO 0 STEP -1:P=5:FOR Y=0 TO 191:LOCATE X,Y,A:BUFFER$(P)=CHR$(GRAY(INT(RND(0)*4),A))
30190 BUFFER$(P+1)=CHR$(GRAY(INT(RND(0)*4),A)):P=P+2:NEXT Y
30200 ? #7;"          ";BUFFER$:NEXT X
30210 TRAP 40000:GOTO 40
30220 REM GR. 9 DUMP PROGRAM FOR MX80 BY RON MILLER, SAN DIEGO ACE
30230 TRAP 30330:RESTORE 30250:OPEN #7,8,0,"P:"
30240 FOR I=1 TO 32:READ A:GREY$(I,I)=CHR$(A):NEXT I:REM Set grey scale
30250 DATA 255,255,251,223,251,222,206,183
30260 DATA 219,78,221,70,217,70,248,85
30270 DATA 38,153,36,153,36,145,17,72
30280 DATA 4,65,4,32,0,16,0,0
30290 BUFFER$(1)=CHR$(27):BUFFER$(2)="K":BUFFER$(3)=CHR$(128):BUFFER$(4)=CHR$(1):REM Tell Epson 384 dots coming
30300 PRINT #7:PRINT #7:PRINT #7;CHR$(27);"A";CHR$(8):REM set Epson for 8 dots/line
30310 FOR X=79 TO 0 STEP -1:P=5:FOR Y=0 TO 191:LOCATE X,Y,A:PTR=A+A+1:BUFFER$(P)=GREY$(PTR,PTR+1):P=P+2:NEXT Y
30320 PRINT #7;"          ";BUFFER$:NEXT X
30330 RETURN