Garbage Collector, programming utility (GARBAGE.BAS)

Garbage Collector, programming utility by Harvey Branch, 77

Description

Garbage Collector, programming utility by Harvey Branch, 77

From the Antic disk of December 1983 (Vol. 2 No. 9).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 1.6 KB

Dialect
Atari BASIC
Lines
26
Variables
DELAY, P1$, B(, C(, D(, E(, F(, G(, H(, I(, J(, K(, P2$, X, Y, TIME, A, RA$
BASIC listing (26 lines)
1 REM ***GARBAGE COLLECTOR DEMO***
10 GRAPHICS 0:POKE 752,1:POKE 82,0
20 ? :? "    DEMO OF FAST ARRAY RESETTING"
30 ? :? "  (ELAPSED TIME FOR TEN 10 X 10 ARRAYS)"
40 FOR DELAY=1 TO 1000:NEXT DELAY
50 DIM P1$(1),B(9,9),C(9,9),D(9,9),E(9,9),F(9,9),G(9,9),H(9,9),I(9,9),J(9,9),K(9,9),P2$(1)
60 ? :? :? "NOW RESETTING WITH OLD FOR .. NEXT LOOP"
70 POKE 18,0:POKE 19,0:POKE 20,0:REM SET CLOCK
80 FOR X=0 TO 9:FOR Y=0 TO 9
90 B(X,Y)=0:C(X,Y)=0:D(X,Y)=0:E(X,Y)=0:F(X,Y)=0:G(X,Y)=0:H(X,Y)=0:I(X,Y)=0:J(X,Y)=0:K(X,Y)=0
100 NEXT Y:NEXT X
110 TIME=(PEEK(20)+256*PEEK(19)+256*256*PEEK(18))/60
120 ? :? "    TIME WAS ";TIME;" SEC."
130 ? :? :? "GET READY FOR NEW FAST RESET";
140 A=ADR(P2$)-ADR(P1$)
150 POKE 143,INT(ADR(P1$)/256):POKE 142,ADR(P1$)-256*PEEK(143)
160 POKE 144,PEEK(142):POKE 145,PEEK(143)
170 DIM RA$(A+1)
180 FOR DELAY=1 TO 1000:NEXT DELAY
190 ? "--GO!":POKE 19,0:POKE 20,0
200 RA$(1)=CHR$(0):RA$(A+1)=CHR$(0)
210 RA$(2)=RA$
220 TIME=(PEEK(20)+256*PEEK(19))/60
230 ? :? "       TIME WAS ";TIME;" SEC."
240 ? "       TO RESET ";A+1;" BYTES"
250 POKE 82,2:POKE 752,0