More Interrupting, display list techniques (DLI1.BAS)
More Interrupting, display list techniques by Allan Moose and Marian Lorenz, 54
Description
More Interrupting, display list techniques by Allan Moose and Marian Lorenz, 54
From the Antic disk of December 1983 (Vol. 2 No. 9).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 914 bytes
- Dialect
- Atari BASIC
- Lines
- 25
- Variables
CT,D,DL,C,J,B
BASIC listing (25 lines)
1 REM *** PROGRAM 1 ***
5 REM *** SET UP COLOR TABLE ***
10 FOR CT=0 TO 5
20 READ D:POKE 1568+CT,D
30 NEXT CT
40 DATA 200,90,56,152,88,120
50 POKE 1536+31,31:REM INITIALIZE COUNTERS
60 REM *** PUT SIX INTERRUPTS INTO THE DISPLAY LIST ***
70 GRAPHICS 7:COLOR 1
80 DL=PEEK(560)+PEEK(561)*256
90 FOR C=18 TO 48 STEP 6
100 POKE DL+C,141:NEXT C
110 REM *** CREATE DISPLAY ***
120 POKE 752,1:? "DLI COLOR TABLE EXAMPLE"
130 PLOT 112,49
140 DRAWTO 112,14:DRAWTO 48,14
150 POSITION 48,49
160 POKE 765,1
170 XIO 18,#6,0,0,"S:"
180 REM *** SET UP DLI SERVICE ROUTINE ***
190 FOR J=0 TO 30:READ B:POKE 1536+J,B:NEXT J
200 DATA 72,138,72,238,31,6,174,31,6,189,0,6,141,10,212
210 DATA 141,22,208,224,37,208,5,169,31,141,31,6,104,170,104,64
220 POKE 512,0:POKE 513,6
230 POKE 54286,192
