Automate Your Player/Missiles, graphics tool (AUTOPM.BAS)
Automate Your Player/Missiles, graphics tool by Fred Pinho, 66
Description
Automate Your Player/Missiles, graphics tool by Fred Pinho, 66
From the Antic disk of December 1983 (Vol. 2 No. 9).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 13.0 KB
- Dialect
- Atari BASIC
- Lines
- 189
- Variables
A,XX,NMB$,E,LINE,F,YY,NA$,NMB,L,H,NUMB$,G,NPL,RS,SZ0,SZ1,HZST0,HZST1,LFL0,RTL0,LFL1,RTL1,R,STV0,STV1,LL0,UPL0,LL1,UPL1,C0,C1,CB,PF,PR,PMST,PB,P0$,P1$,X,PP,OFS,REGISTER,P,PMBASE,PL0L,PL1L,PL0H,PL1H,Z,Z$,T,S,RAM,RMTP,PMB,PL0,PL1,HV,LV,QT0(,RTN0(,QT1(,RTN(,RTN1(,Y,CHR$,B,C,D,SPD,PM$,P2$,P3$,LO,HI,PG,Q
BASIC listing (189 lines)
10 GRAPHICS 18:POKE 708,36:POKE 709,196
20 DIM NMB$(10),NA$(7),Z$(1),QT0(4),RTN0(4),QT1(4),RTN1(4)
30 FOR X=4 TO 9:READ Y:COLOR Y:PLOT X,4:NEXT X:FOR X=11 TO 15:READ Y:COLOR Y:PLOT X,4:NEXT X
40 FOR X=4 TO 8:READ Y:COLOR Y:PLOT X,9:NEXT X:FOR X=10 TO 14:READ Y:COLOR Y:PLOT X,9:NEXT X
50 DATA 240,76,97,217,229,82,109,207,246,69,114,240,82,101,211,243,115,212,225,82,116
60 A=PEEK(711):B=PEEK(708):C=PEEK(709):D=PEEK(710):POKE 711,D:POKE 708,A:POKE 709,B:POKE 710,C
70 FOR X=1 TO 20:IF PEEK(53279)=6 THEN POP :GOTO 90
80 NEXT X:GOTO 60
90 POKE 708,40:POKE 709,202:F=0:OPEN #3,4,0,"K:":GRAPHICS 0
100 ? "WELCOME TO PM MOVER!":? "A SERIES OF QUESTIONS":? "WILL BE DISPLAYED."
110 ? "EACH QUESTION WILL REQUIRE":? "A NUMERICAL ANSWER."
120 ? "INDICATE CHOICE BY TYPING DIGITS.":? "TYPE RETURN ONLY AFTER NUMBER":? "IS COMPLETED."
130 ? "YOU CAN ABORT NUMBER AT ANY TIME,":? "PRIOR TO RETURN,BY TYPING A SPACE."
140 ? :? "PRESS START WHEN READY."
150 POKE 53279,8:IF PEEK(53279)=6 THEN ? CHR$(125):GOTO 170
160 GOTO 150
170 GOSUB 1560:? "INDICATE GRAPHICS MODE FOR YOUR":? "PROGRAM! ANY MODE EXCEPT 10.";
175 LINE=170:L=0:H=11:GOSUB 1370:G=NMB:IF NMB=10 THEN GOSUB 1500:GOTO 170
180 GOSUB 1560:? "INDICATE RAM IN YOUR MACHINE.":? "TYPE 1-4":? " (1)16K":? " (2)24K":? " (3)32K"
190 ? " (4)40-48K":? "?";:LINE=180:L=1:H=4:GOSUB 1370:RAM=NMB
200 GOSUB 1560:? "CHOOSE NUMBER OF PLAYERS(1 OR 2)!";:LINE=200:L=1:H=2:GOSUB 1370:NPL=NMB-1
210 GOSUB 1560:? "DO YOU WISH SINGLE(1) OR DOUBLE(2)":? "LINE RESOLUTION?";:LINE=210:GOSUB 1370:RS=NMB
215 GOSUB 1560
220 ? "CHOOSE PLAYER ZERO SIZE(0,1,3)!":? "NORMAL=0":? "?";:LINE=215:L=0:H=3:F=1:NA$="2":GOSUB 1370:SZ0=NMB:F=0
230 IF NPL THEN GOSUB 1560:? "CHOOSE PLAYER ONE SIZE(0,1,3)!";:? "?";:LINE=230:F=1:GOSUB 1370:SZ1=NMB:F=0
240 GOSUB 1560:? "CHOOSE INITIAL HORIZONTAL POSITION":? "RANGE=0-255.";:? "VISIBLE LIMITS=48-200"
250 ? " PLAYER ZERO(0-255)?";:LINE=250:L=0:H=255:GOSUB 1370:HZST0=NMB
260 IF NPL THEN ? " PLAYER ONE(0-255)?";:LINE=260:GOSUB 1370:HZST1=NMB
270 GOSUB 1560:? "CHOOSE LIMITS ON HORIZONTAL":? "POSITIONS(0-255)!":? "IF CHOOSE 0 AND/OR 255,WILL GET"
280 ? "WRAPAROUND!"
290 ? " PLAYER ZERO LEFT MARGIN?";:LINE=290:GOSUB 1370:LFL0=NMB:IF LFL0>HZST0 THEN GOTO 1620
300 ? " PLAYER ZERO RIGHT MARGIN?";:LINE=300:GOSUB 1370:RTL0=NMB:IF RTL0<HZST0 THEN GOTO 1620
310 IF NPL THEN ? " PLAYER ONE LEFT MARGIN?";:LINE=310:GOSUB 1370:LFL1=NMB:IF LFL1>HZST1 THEN GOTO 1620
320 IF NPL THEN ? " PLAYER ONE RIGHT MARGIN?";:LINE=320:GOSUB 1370:RTL1=NMB:IF RTL1<HZST1 THEN GOTO 1620
330 HV=108+(108*(RS=1)):LV=16+(16*(RS=1)):L=2:H=125+128*(RS=1):GOSUB 1560
340 ? "INITIAL VERTICAL POSITION":? "RANGE=2-";H;".";:? "VISIBLE LIMITS=";LV;"-";HV;")"
350 ? " PLAYER ZERO(2-";H;")?";:LINE=350:GOSUB 1370:GOSUB 1570:STV0=NMB
360 IF NPL THEN ? " PLAYER ONE(2-";H;")?";:LINE=360:GOSUB 1370:GOSUB 1570:STV1=NMB
370 GOSUB 1560:? "CHOOSE LIMITS ON VERTICAL":? "POSITIONS(2-";H;")!"
380 ? " PLAYER ZERO LOWER LIMIT?";:LINE=380:GOSUB 1370:GOSUB 1570:LL0=NMB:IF LL0<STV0 THEN GOTO 1620
390 ? " PLAYER ZERO UPPER LIMIT?";:LINE=390:GOSUB 1370:GOSUB 1570:UPL0=NMB:IF UPL0>STV0 THEN GOTO 1620
400 IF NPL THEN ? " PLAYER ONE LOWER LIMIT?";:LINE=400:GOSUB 1370:GOSUB 1570:LL1=NMB:IF LL1<STV1 THEN GOTO 1620
410 IF NPL THEN ? " PLAYER ONE UPPER LIMIT?";:LINE=410:GOSUB 1370:GOSUB 1570:UPL1=NMB
415 IF NPL THEN IF UPL1>STV1 THEN GOTO 1620
420 GOSUB 1560:? "CHOOSE PLAYER COLORS.":? "HUES ARE ROUGHLY":? " 0 BLACK TO WHITE"
430 ? " 1-4 REDS":? " 5 PURPLE":? " 6-10 BLUES":? " 11-13 GREENS":? " 14-15 ORANGES"
440 ? :? " PLAYER ZERO ";:GOSUB 1510:L=0:H=15:LINE=440:GOSUB 1370:C0=NMB*16
450 ? " PLAYER ZERO ";:GOSUB 1520:H=14:NA$="3579▝▔":F=1:LINE=450:GOSUB 1370:F=0:GOSUB 1540
460 C0=C0+NMB
470 IF NPL THEN ? " PLAYER ONE ";:GOSUB 1510:H=15:LINE=470:GOSUB 1370:C1=NMB*16
480 IF NPL THEN ? " PLAYER ONE ";:GOSUB 1520:H=14:F=1:LINE=480:GOSUB 1370:F=0:GOSUB 1540
490 C1=C1+NMB
500 GOSUB 1560:? "CHOOSE BACKGROUND COLOR!":? " ";:GOSUB 1510:H=15:LINE=500:? " ";:GOSUB 1370:CB=NMB*16
505 IF G=11 AND CB<>0 THEN CB=0:GOSUB 1630
510 ? " ";:GOSUB 1520:H=14:F=1:LINE=510:GOSUB 1370:GOSUB 1540:F=0
511 IF G=9 AND NMB<>0 THEN NMB=0:GOSUB 1640
513 CB=CB+NMB
515 GOSUB 1560
520 ? "CHOOSE PLAYFIELD TYPE!":? " NARROW=0":? " REGULAR=1":? " WIDE=2":? "?";:H=2:LINE=515:GOSUB 1370:PF=NMB
530 GOSUB 1560:? :? "PRIORITY CHOICES! NOTE THAT PLAYER 0":? "ALWAYS HAS PRIORITY OVER PLAYER 1!"
540 ? "TYPE DESIRED NUMBER.":? " ALL PLAYERS OVER PLAYFIELDS(0)":? " PLAYERS 0 & 1 OVER PLAYFIELDS(1)"
550 ? " ALL PLAYFIELDS OVER PLAYERS(2)":? " PLAYFIELDS 0 & 1 OVER PLAYERS(3)"
560 ? "?";:H=3:LINE=530:GOSUB 1370:PR=NMB
570 GOSUB 1560:? :? "WHERE DO YOU DESIRE TO STORE PM DATA?":? " ABOVE A LOWERED RAMTOP(TYPE 0)"
580 ? " BENEATH THE DISPLAY LIST(TYPE 1)"
590 ? "?";:H=1:LINE=570:GOSUB 1370:PMST=NMB
600 GOSUB 1560:? "CHOOSE SPEED OF MOVEMENT.":? " HALF SPEED(TYPE 0)":? " NORMAL SPEED(TYPE 1)":? "?";
610 LINE=600:GOSUB 1370:SPD=NMB
611 GOSUB 1560:? "DO YOU WISH TO STORE THE VBI":? "ROUTINE IN A:":? " STRING(TYPE 0)":? " IN PAGE 6(TYPE 1)"
612 ? "?";:L=0:H=1:LINE=611:GOSUB 1370:PG=NMB
615 GOSUB 1560
620 ? :? "INDICATE NUMBER OF BYTES IN PLAYER.":? "BOTH PLAYERS MUST HAVE SAME NUMBER.":? "MAXIMUM BYTES=10!"
630 L=1:H=10:? "?";:LINE=615:GOSUB 1370:PB=NMB
640 DIM P0$(PB),P1$(PB)
650 FOR X=0 TO 4:QT0(X)=0:QT1(X)=0:RTN0(X)=0:RTN1(X)=0:NEXT X:Y=0:Z=0
660 GOSUB 1560:? :? "TYPE IN DATA FOR PLAYER ZERO.":? "START FROM TOP OF PLAYER.":L=0:H=255:TRAP 1600
670 FOR X=1 TO PB
680 ? "?";:LINE=680:GOSUB 1370:IF E THEN X=X-1:NEXT X:GOTO 720
690 IF NMB=34 THEN QT0(Y)=X:P0$(X,X)=" ":Y=Y+1:NEXT X:GOTO 720
700 IF NMB=155 THEN RTN0(Z)=X:P0$(X,X)=" ":Z=Z+1:NEXT X:GOTO 720
710 P0$(X,X)=CHR$(NMB):NEXT X
720 IF NPL THEN GOSUB 1560:? :? "TYPE IN DATA FOR PLAYER ONE":Y=0:Z=0
730 IF NPL THEN FOR X=1 TO PB
740 IF NPL THEN ? :? "?";:LINE=740:GOSUB 1370:IF E THEN X=X-1:NEXT X:GOTO 775
750 IF NPL THEN IF NMB=34 THEN QT1(Y)=X:P1$(X,X)=" ":Y=Y+1:NEXT X:GOTO 775
760 IF NPL THEN IF NMB=155 THEN RTN1(Z)=X:P1$(X,X)=" ":Z=Z+1:NEXT X:GOTO 775
770 IF NPL THEN P1$(X,X)=CHR$(NMB):NEXT X
775 TRAP 40000
780 GRAPHICS 0:? :? :? "LISTING PLAYER MOVEMENT":? "SUBROUTINE TO DISK"
790 OPEN #1,8,0,"D:PM.LST":RMTP=(8+(RAM*8))*4:IF PMST THEN 850
800 IF RS=1 THEN OFS=8+8*(G>5):GOTO 820
810 OFS=4+8*(G=7)+12*(G>7)
820 ? #1;"31000 PM=PEEK(106)-";OFS;":POKE 106,PM:GR.";G;":POKE 54279,PM:PMBASE=256*PM"
830 PMB=(RMTP-OFS)*256:PL0=PMB+512+(512*(RS=1)):GOSUB 1580
840 IF NPL THEN PL1=PMB+640+(640*(RS=1)):GOSUB 1590:GOTO 900
850 IF RS=2 THEN OFS=8*(G<5)+12*(G=5)+16*(G=6)+24*(G=7)+36*(G>7):PMB=(RMTP-OFS)*256
860 IF RS=1 THEN OFS=16*(G<6)+24*(G=6)+32*(G=7)+40*(G>7):PMB=(RMTP-OFS)*256
870 PL0=PMB+512+(512*(RS=1)):GOSUB 1580
880 IF NPL THEN PL1=PMB+640+(640*(RS=1)):GOSUB 1590
890 ? #1;"31000 GR.";G;":PM=PEEK(106)-";OFS;":POKE 54279,PM:PMBASE=256*PM"
900 ? #1;"31010 DIM ZERO$(47):ZERO$=";CHR$(34);"hhh┐Lh┐Nh┐Mh┐Ph┐O%L&Pp▘ ♥┌M◢P♠fNJPv$O◢@▶p┤┌MPw◆";CHR$(34)
910 ? #1;"31020 X=USR(ADR(ZERO$),0,PMBASE,";1024+1024*(RS=1);")"
920 REGISTER=712-(2*(G=0 OR G=8))
930 ? #1;"31030 POKE 53256,";SZ0;":POKE 53248,";HZST0;":POKE 704,";C0;":POKE ";REGISTER;",";CB;
940 IF NPL THEN ? #1;":POKE 53257,";SZ1;":POKE 53249,";HZST1;":POKE 705,";C1
950 IF NPL=0 THEN ? #1;" "
960 ? #1;"31040 DIM P0$(";PB;"):P0$=";CHR$(34);P0$;CHR$(34)
970 IF QT0(0)=0 THEN 995
975 ? #1;"31043 ";
980 FOR X=0 TO 4:Z=QT0(X):IF Z THEN IF X THEN ? #1;":";
985 IF Z THEN ? #1;"P0$(";Z;",";Z;")=CHR$(34)";
990 NEXT X:? #1;" "
995 IF RTN0(0)=0 THEN 1030
1000 ? #1;"31047 ";
1005 FOR X=0 TO 4:Y=RTN0(X):IF Y THEN IF X THEN ? #1;":";
1010 IF Y THEN ? #1;"P0$(";Y;",";Y;")=CHR$(155)";
1020 NEXT X:? #1;" "
1030 IF NPL=0 THEN 1120
1040 ? #1;"31050 DIM P1$(";PB;"):P1$=";CHR$(34);P1$;CHR$(34)
1050 IF QT1(0)=0 THEN 1075
1055 ? #1;"31053 ";
1060 FOR X=0 TO 4:Z=QT1(X):IF Z THEN IF X THEN ? #1;":";
1065 IF Z THEN ? #1;"P1$(";Z;",";Z;")=CHR$(34)";
1070 NEXT X:? #1;" "
1075 IF RTN1(0)=0 THEN 1120
1080 ? #1;"31057 ";
1090 FOR X=0 TO 4:Y=RTN1(X):IF Y THEN IF X THEN ? #1;":";
1100 IF Y THEN ? #1;"P1$(";Y;",";Y;")=CHR$(155)";
1110 NEXT X:? #1;" "
1120 P=512+(512*(RS=1))+STV0
1130 ? #1;"31060 FOR X=";PB-1;" TO 0 STEP-1:POKE PMBASE+";P;"+X,ASC(P0$(X+1,X+1)):NEXT X"
1140 IF NPL=0 THEN 1170
1150 P=640+(640*(RS=1))+STV1
1160 ? #1;"31070 FOR X=";PB-1;" TO 0 STEP-1:POKE PMBASE+";P;"+X,ASC(P1$(X+1,X+1)):NEXT X"
1170 ? #1;"31080 POKE 203,";PB+1;":POKE 204,";PB+1;":POKE 1000,";STV0;":POKE 1002,";PL0L;":POKE 1004,";PL0H;
1180 ? #1;":POKE 1006,";UPL0;":POKE 1008,";LL0;":POKE 1010,";LFL0
1190 IF NPL THEN ? #1;"31090 POKE 1001,";STV1;":POKE 1003,";PL1L;":POKE 1005,";PL1H;
1200 IF NPL THEN ? #1;":POKE 1007,";UPL1;":POKE 1009,";LL1;":POKE 1011,";LFL1
1210 ? #1;"31100 POKE 1012,";HZST0;":POKE 1014,";RTL0
1220 IF NPL THEN ? #1;"31110 POKE 1013,";HZST1;":POKE 1015,";RTL1
1230 ? #1;"31115 DIM PM$(211)"
1240 ? #1;"31120 PM$(1,65)=";CHR$(34);""♥=x▕)├P▕p%=x▕)▕P▕pW=x▕)┤P▕pH=x▕)◢P▕p9h◆▕p▕PULbd=h┘(◢j┴]n┘♣O↓h┘Hj";CHR$(34)
1250 ? #1;"31130 PM$(66,128)=";CHR$(34);"=j┘┐M=l┘┐N1M◢j┌MHHjFK♣s%L┐K┴♣,p\♣1♣8pB♣=0;=h┘(Hj┴]p┘0↓↓h┘FKFKFK";CHR$(34)
1260 ? #1;"31140 PM$(129,196)=";CHR$(34);"jjHFKP♠%L┐K=j┘┐M=l┘┐N1MHj┌M◢◢jFK♣s%L┐K┴♣8<t┘◢j┴]r┘♣/↓t┘↓♥P┴♣&<t┘Hj┴]";
1265 ? #1;CHR$(34):? #1;"31142 PM$(197,211)=";CHR$(34);"v┘p▕0→↓t┘↓♥P┴♣●";CHR$(34)
1270 IF NPL THEN 1290
1280 ? #1;"31145 PM$(41,41)=CHR$(1)"
1290 IF SPD THEN ? #1;"31147 PM$(54,54)=CHR$(136):PM$(65,65)=CHR$(200):PM$(79,79)=CHR$(136):PM$(84,84)=CHR$(200)"
1300 IF SPD THEN ? #1;"31148 PM$(113,113)=CHR$(200):PM$(129,129)=CHR$(198):PM$(130,130)=CHR$(203)"
1310 IF SPD THEN ? #1;"31149 PM$(153,153)=CHR$(200):PM$(158,158)=CHR$(136):PM$(174,174)=CHR$(136):";
1311 IF SPD THEN ? #1;"PM$(194,194)=CHR$(200)"
1315 IF PG THEN ? #1;"31150 FOR X=0 TO 210:POKE 1536+X,ASC(PM$(X+1,X+1)):NEXT X"
1320 ? #1;"31155 DIM SET$(11):SET$=";CHR$(34);"h " )╲ \d◆";CHR$(34);
1321 IF PG=0 THEN ? #1;":AD=ADR(PM$):HI=INT(AD/256):LO=AD-256*HI"
1322 IF PG THEN ? #1;" "
1325 IF PG=0 THEN ? #1;"31160 SET$(3,3)=CHR$(LO):SET$(5,5)=CHR$(HI):X=USR(ADR(SET$))"
1326 IF PG THEN ? #1;"31160 SET$(3,3)=CHR$(0):SET$(5,5)=CHR$(6):X=USR(ADR(SET$))"
1330 P=44+(16*(RS=1))+(1*(PF=0)+2*(PF=1)+3*(PF=2)):? #1;"31190 POKE 559,";P;
1340 P=1*(PR=0)+2*(PR=1)+4*(PR=2)+8*(PR=3):? #1;":POKE 623,PEEK(623)+";P;":POKE 53277,3"
1350 ? #1;"32000 RETURN"
1360 CLOSE #1:CLOSE #3:GOSUB 1560:? "FILE ON DISK IS CALLED 'PM.LST'":? "TO MERGE WITH YOUR PROGRAM,USE ENTER!":END
1370 A=PEEK(16)-128:IF A<0 THEN 1390
1380 POKE 16,A:POKE 53774,A
1390 XX=1:NMB$="":E=0
1400 GET #3,A:? CHR$(A);:Z$=STR$(0)
1410 IF A=155 THEN 1470
1420 IF A=32 THEN ? :? "↰ABORTING NUMBER.CHOOSE AGAIN.":GOSUB 1530:E=1:POP :GOTO LINE
1430 IF A<48 OR A>57 THEN ? :GOSUB 1500:E=1:POP :GOTO LINE
1440 IF F=1 THEN FOR YY=1 TO LEN(NA$):IF A=ASC(NA$(YY,YY)) THEN POP :? :GOSUB 1500:E=1:POP :GOTO LINE
1450 IF F=1 THEN NEXT YY
1460 NMB$(XX,XX)=CHR$(A):XX=XX+1:GOTO 1400
1470 IF LEN(NMB$)=0 THEN GOSUB 1500:POP :E=1:GOTO LINE
1480 NMB=VAL(NMB$):IF NMB<L OR NMB>H THEN GOSUB 1500:POP :E=1:GOTO LINE
1490 ? :RETURN
1500 ? "↰INCORRECT RESPONSE! PLEASE TRY AGAIN!":GOSUB 1530:RETURN
1510 ? "HUE(0-15)?";:RETURN
1520 ? "LUMINANCE":? " (EVEN NUMBER 0-14)?";:RETURN
1530 FOR Q=1 TO 100:NEXT Q:RETURN
1540 IF NMB=1 OR NMB=11 OR NMB=13 THEN GOSUB 1500:E=1:POP :GOTO LINE
1550 RETURN
1560 FOR T=10 TO 6 STEP -1:FOR S=8 TO 0 STEP -1:SOUND 0,15-S,10,T:NEXT S:NEXT T:SOUND 0,0,0,0:RETURN
1570 NMB=(NMB-(127+128*(RS=1)))*-1:RETURN
1580 PL0H=INT(PL0/256):PL0L=PL0-256*PL0H:RETURN
1590 PL1H=INT(PL1/256):PL1L=PL1-256*PL1H:RETURN
1600 ? "↰YOU HAVE EXCEEDED THE NUMBER OF":? "BYTES ALLOWED WITH VALUES":? "OF 155 OR 34!"
1610 ? "PLEASE USE A DIFFERENT VALUE!":TRAP 1600:X=X-1:NEXT X
1620 ? "↰YOUR MOVEMENT LIMITS ARE NOT":? "COMPATIBLE WITH THE INITIAL POSITION!":? "PLEASE CHECK VALUES":GOTO LINE
1630 ? "↰GR.11 NEEDS A BACKGROUND HUE OF ZERO!":? "I'VE SET THAT!":? :RETURN
1640 ? "↰GR.9 NEEDS A BACKGROUND LUMINANCE":? "OF ZERO! I'VE SET THAT!":? :RETURN
