Sound Beyond Sound, sound editor (SNDEDTR3.BAS)
Sound Beyond Sound, sound editor by Chris Chabris, 35
Description
Sound Beyond Sound, sound editor by Chris Chabris, 35
From the Antic disk of November 1983 (Vol. 2 No. 8).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 5.9 KB
- Dialect
- Atari BASIC
- Lines
- 84
- Variables
L,VOICE,V,FREQ(,AUDCTL(,Q,SPRAY$,PMMEM,B,A,SUM,VOL(,DIST(,PMP,L1,L2,DL
BASIC listing (84 lines)
1000 REM *** SOUND EDITOR, rev. 1.0
1010 REM *** By Chris Chabris 1983
1020 REM *** For ANTIC Magazine
1030 REM *** Allows modification of 4
1040 REM *** voices and AUDCTL value.
1050 FOR L=53760 TO 53768:POKE L,0:NEXT L:SOUND 0,0,0,0:VOICE=1
1060 GRAPHICS 0:POKE 710,54:POKE 709,0:POKE 752,1:POKE 82,1:POKE 83,38:? CHR$(125):POKE 54286,64:GOSUB 1630
1070 REM - MAIN PROGRAM LOOP
1080 POKE 53279,0
1090 IF STRIG(0)=0 THEN 1340
1100 IF PEEK(53279)=6 THEN 1390
1110 IF PEEK(53279)=5 THEN 1560
1120 IF PEEK(53279)=3 THEN 1590
1130 IF STICK(0)=15 THEN 1090
1140 IF STICK(0)<>14 THEN 1170
1150 POKE 703+VOICE,0:VOICE=VOICE-1:IF VOICE=0 THEN VOICE=4
1160 POSITION 8,2:? VOICE;:POKE 703+VOICE,12:FOR L=1 TO 100:NEXT L:GOTO 1080
1170 IF STICK(0)<>13 THEN 1200
1180 POKE 703+VOICE,0:VOICE=VOICE+1:IF VOICE=5 THEN VOICE=1
1190 POSITION 8,2:? VOICE;:POKE 703+VOICE,12:FOR L=1 TO 100:NEXT L:GOTO 1080
1200 IF STICK(0)<>7 THEN 1270
1210 V=VOICE:IF FREQ(V-1)=255 THEN 1090
1220 FREQ(V-1)=FREQ(V-1)+1:POSITION 19,V*4:? FREQ(V-1);" ";
1230 POKE 53247+V,58+INT(FREQ(V-1)/2)
1240 POKE 53758+V*2,FREQ(V-1):IF AUDCTL(4)=1 AND V<3 THEN POSITION 22,2:? " ←←←←←";FREQ(0)+256*FREQ(1);
1250 IF AUDCTL(3)=0 OR V<3 THEN 1200
1260 POSITION 33,2:? " ←←←←←";FREQ(2)+256*FREQ(3);:GOTO 1200
1270 IF STICK(0)<>11 THEN 1090
1280 V=VOICE:IF FREQ(V-1)=0 THEN 1090
1290 FREQ(V-1)=FREQ(V-1)-1:POSITION 19,V*4:? FREQ(V-1);" ";
1300 POKE 53247+V,58+INT(FREQ(V-1)/2)
1310 POKE 53758+V*2,FREQ(V-1):IF AUDCTL(4)=1 AND V<3 THEN POSITION 22,2:? " ←←←←←";FREQ(0)+256*FREQ(1);
1320 IF AUDCTL(3)=0 OR V<3 THEN 1270
1330 POSITION 33,2:? " ←←←←←";FREQ(2)+256*FREQ(3);:GOTO 1270
1340 V=VOICE:FREQ(V-1)=FREQ(V-1)+25:IF FREQ(V-1)>255 THEN FREQ(V-1)=0
1350 POKE 53247+V,58+INT(FREQ(V-1)/2):POKE 53758+2*V,FREQ(V-1):POSITION 19,4*V:? " ←←←";FREQ(V-1);
1360 IF AUDCTL(4)=1 AND V<3 THEN POSITION 22,2:? " ←←←←←";FREQ(0)+256*FREQ(1);
1370 IF AUDCTL(3)<>1 OR V<3 THEN 1100
1380 POSITION 33,2:? " ←←←←←";FREQ(2)+256*FREQ(3);:GOTO 1100
1390 Q=USR(ADR(SPRAY$),PMMEM+1024+(VOICE-1)*256,256):POSITION 1,3:? " Toggle AUDCTL bits with TRIGGER. "
1400 POKE 53247+VOICE,0:RESTORE 1410:FOR L=0 TO 11:READ B:POKE PMMEM+1024+(VOICE-1)*256+198+L,B:NEXT L
1410 DATA 126,126,66,66,66,66,66,66,66,66,126,126
1420 POKE 53247+VOICE,74:A=7:FOR L=1 TO 50:NEXT L
1430 IF STRIG(0)=0 THEN 1480
1440 IF STICK(0)=11 THEN A=A+1:A=A-(8*(A=8)):POKE 53247+VOICE,74+16*(7-A):FOR L=1 TO 50:NEXT L:GOTO 1430
1450 IF STICK(0)=7 THEN A=A-1:A=A+(8*(A=-1)):POKE 53247+VOICE,74+16*(7-A):FOR L=1 TO 50:NEXT L:GOTO 1430
1460 IF PEEK(53279)=6 THEN 1520
1470 GOTO 1430
1480 POKE 53279,0:AUDCTL(A)=ABS(AUDCTL(A)-1):SUM=0:FOR L=0 TO 7:IF AUDCTL(L)=1 THEN SUM=SUM+INT(2^L+0.5)
1490 NEXT L:POKE 53768,SUM
1500 POSITION 7+4*(7-A),23:? AUDCTL(A);:POSITION 34,20:? " ←←←";SUM;
1510 POKE 53279,0:GOTO 1440
1520 Q=USR(ADR(SPRAY$),PMMEM+1024+256*(VOICE-1)):POKE 53247+VOICE,0
1530 RESTORE 1680:FOR L=0 TO 7:READ B:POKE PMMEM+1024+256*(VOICE-1)+(VOICE-1)*32+72+L,B:NEXT L
1540 POKE 53247+VOICE,58+INT(FREQ(VOICE-1)/2)
1550 POSITION 1,3:? " START-SELECT-OPTION STICK-TRIGGER ":GOTO 1080
1560 VOL(VOICE-1)=VOL(VOICE-1)+1:IF VOL(VOICE-1)=16 THEN VOL(VOICE-1)=0
1570 POSITION 27,VOICE*4:? VOL(VOICE-1);" ";:POKE 53759+VOICE*2,DIST(VOICE-1)*16+VOL(VOICE-1):GOTO 1090
1580 FOR L=1 TO 50:NEXT L:GOTO 1090
1590 DIST(VOICE-1)=DIST(VOICE-1)+2:IF DIST(VOICE-1)=16 THEN DIST(VOICE-1)=0
1600 POSITION 35,VOICE*4:? DIST(VOICE-1);" ";:POKE 53759+VOICE*2,DIST(VOICE-1)*16+VOL(VOICE-1)
1610 FOR L=1 TO 50:NEXT L:GOTO 1090
1620 REM - INITIALIZATION ROUTINE
1630 PMP=PEEK(106)-16:PMMEM=PMP*256
1640 DIM SPRAY$(42):RESTORE 1650:FOR L=1 TO 42:READ B:SPRAY$(L)=CHR$(B):NEXT L:Q=USR(ADR(SPRAY$),PMMEM,2048)
1650 DATA 104,104,133,204,104,133,203,104,133,206,104,133,205,166,206,160,0,169,0,145,203,136
1660 DATA 208,251,230,204,202,48,6,208,244,164,205,208,240,198,204,160,0,145,203,96
1670 FOR L1=0 TO 3:RESTORE 1680:FOR L2=0 TO 7:READ B:POKE PMMEM+1024+L1*256+L1*32+72+L2,B:NEXT L2:NEXT L1
1680 DATA 8,8,8,8,8,62,28,8
1690 RESTORE 1700:FOR L=0 TO 28:READ B:POKE 1536+L,B:NEXT L:POKE 207,0:POKE 512,0:POKE 513,6
1700 DATA 8,72,138,72,141,10,212,166,207,189,32,6,141,24,208,232,224,5,208,2,162,0,134,207,104,170,104,40,64
1710 POKE 1568,86:POKE 1569,118:POKE 1570,166:POKE 1571,198:POKE 1572,246
1720 DL=PEEK(560)+256*PEEK(561):FOR L=8 TO 24 STEP 4:POKE DL+L,130:NEXT L
1730 FOR L=704 TO 707:POKE L,0:NEXT L:POKE 54279,PMP:POKE 53277,3:POKE 623,1:POKE 559,62:POKE 54286,192
1740 POSITION 1,0:? " ********** SOUND EDITOR ********** ":? " ***** By Chris Chabris 1983 ***** "
1750 ? :? " START-SELECT-OPTION STICK-TRIGGER "
1760 FOR L=4 TO 16 STEP 4:POSITION 1,L:? " VOICE #";L/4;": FREQ=0 VOL=6 DIST=10":POSITION 1,L+2
1770 ? " ├┴┴┴┴┴┴┴┼┴┴┴┴┴┴┴┼┴┴┴┴┴┴┴┼┴┴┴┴┴┴┴┤":? " 000 064 128 192 255":NEXT L
1780 POSITION 1,20:? "AUDCTL SETTING: (TOTAL VALUE=0 )":? "BIT | 7 | 6 | 5 | 4 | 3 | 2 | 1 | 0 |"
1790 ? " ├───┼───┼───┼───┼───┼───┼───┼───┤":? "IS | 0 | 0 | 0 | 0 | 0 | 0 | 0 | 0 |";
1800 FOR L=53248 TO 53251:POKE L,58:NEXT L
1810 POSITION 2,2:? "VOICE=1 V1+2=0 V3+4=0 "
1820 DIM FREQ(3),VOL(3),DIST(3),AUDCTL(7):FOR L=0 TO 3:FREQ(L)=0:VOL(L)=6:DIST(L)=10:POKE 53761+2*L,166:NEXT L
1830 FOR L=0 TO 7:AUDCTL(L)=0:NEXT L:POKE 704,12:RETURN
