Sound demo (SNDDEMO.BAS)

Sound demo by Bill Lukeroth, 28

Description

Sound demo by Bill Lukeroth, 28

From the Antic disk of November 1983 (Vol. 2 No. 8).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.4 KB

Dialect
Atari BASIC
Lines
68
Variables
L, X, DIS, W, Y, MD$, MFN$, L30, S$, TRIG$, Q, LOUD, L2, X2, COL
BASIC listing (68 lines)
10 REM +++++++++ SOUND DEMO +++++++++
20 DIM S$(20):S$="PRESS START TO QUIT"
30 DIM TRIG$(20):TRIG$="PRESS JOYSTK BUTTON"
40 OPEN #1,4,0,"K:":COL=5:TRAP 2000
50 SOUND 0,0,0,0:SOUND 1,0,0,0:GRAPHICS 1+16:SETCOLOR 0,COL,2:? #6;"CHOOSE ONE:":? #6:? #6;"A.BLAST-OFF"
60 ? #6;"B.ENGINE R0OM":? #6;"C.SPACE MACHINE GUN":? #6;"D.DIESEL HORN":? #6;"E.LASER GUN"
65 ? #6;"F.BOMBS AWAY!":? #6;"G.RACE CAR":? #6;"H.CANNON":? #6;"I.THINKING COMPUTER":? #6;"J."
68 ? #6;"K.":? #6;"L.END"
70 ? #6:? #6;"ENTER SELECTION(A,B,C,ETC.)";:GET #1,Q:Q=Q-64:COL=Q*2
80 GRAPHICS 1+16:IF Q>2 AND Q<6 OR Q=8 THEN ? #6:? #6;TRIG$:? #6:? #6;S$
85 GOTO Q*100
90 STOP
100 FOR L=60 TO 1 STEP -1
110 SOUND 1,L,0,10
115 FOR L2=1 TO 100:NEXT L2
120 NEXT L
130 GOTO 50
200 SOUND 0,40,4,10
210 ? #6:? #6;S$
220 IF PEEK(53279)<>6 THEN 220
230 GOTO 50
300 LOUD=0:REM machine gun
310 SOUND 0,255,2,LOUD
320 IF STRIG(0)=0 THEN LOUD=14:GOTO 340
330 LOUD=0
340 IF PEEK(53279)=6 THEN 50
350 GOTO 310
400 LOUD=0:REM diesel horn
410 SOUND 0,25,12,LOUD:SOUND 1,27,12,LOUD
420 IF STRIG(0)=0 THEN LOUD=15:GOTO 440
430 LOUD=0
440 IF PEEK(53279)=6 THEN 50
450 GOTO 410
500 DIS=10
510 IF STRIG(0)<>0 THEN 560
520 FOR L=0 TO 75
530 SOUND 0,L,DIS,10
540 NEXT L
550 SOUND 0,0,0,0
560 IF PEEK(53279)<>6 THEN 510
570 GOTO 50
600 FOR X=10 TO 60
630 SOUND 0,X,10,8
640 SOUND 1,X+1,10,8
650 FOR W=1 TO 50:NEXT W
655 NEXT X
659 POSITION 7,10:PRINT #6;"BOOM!"
663 FOR L=10 TO 0 STEP -1
665 SOUND 0,250,1,L
666 SOUND 1,100,8,L
667 SOUND 2,25,3,L
670 FOR Y=1 TO 200:NEXT Y
680 NEXT L
690 GOTO 50
700 ? #6:? #6;S$
710 SOUND 0,40,12,10
720 IF PEEK(53279)<>6 THEN 720
730 GOTO 50
800 DIS=4:GOTO 510
900 FOR L=255 TO 1 STEP -1
920 SOUND 0,L,10,3
930 SOUND 1,INT(RND(0)*255),10,8
950 NEXT L
960 SOUND 1,1,10,8
970 FOR L=1 TO 50:NEXT L
980 GOTO 50
1200 END
2000 TRAP 2000:GOTO 50