Simple Synthesizer (SMPSYNTH.BAS)

Simple Synthesizer by Vern Mastel, 43

Description

Simple Synthesizer by Vern Mastel, 43

From the Antic disk of November 1983 (Vol. 2 No. 8).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 4.0 KB

Dialect
Atari BASIC
Lines
61
Variables
H(, M(, L(, K, L0, L1, L2, KC, LKP, X, D, NKP, NULL, C, FLAG, A, B
BASIC listing (61 lines)
1 REM PROGRAM 4
2 REM THE SIMPLE SYNTHESIZER BY VERN L. MASTEL
4 REM SET UP MATRIXES, OPEN KEYBOARD FOR INPUT
5 DIM H(13),M(13),L(13):OPEN #1,4,0,"K":TRAP 300:GOTO 200
19 REM MULTIVOICE ROUTINE LINES 20-40
20 K=STICK(0):L0=PADDLE(0):L1=PADDLE(1):L2=PADDLE(2):KC=PEEK(764):IF KC<>255 THEN 199
29 REM IF NO KEY IS PRESSED TURN OFF THE SOUND
30 IF K=15 THEN SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,0,0,0:GOTO 20
40 SOUND 0,M(K),10,L0:SOUND 1,L(K),10,L1:SOUND 2,H(K),10,L2:GOTO 20
49 REM PIANO MODE LINES 50 TO 75
50 K=STICK(0)
52 KC=PEEK(764):IF KC<>255 THEN 199
54 REM IF NO KEY IS PRESSED TURN OFF THE SOUND
55 IF K=15 THEN SOUND 0,0,0,0:GOTO 50
58 REM SAVE KEY IN LAST KEY PRESS, START DECAY LOOP
59 REM CHECK DURING LOOP TO SEE IF A KEY IS STILL PRESSED AND IF IT IS THE SAME KEY
60 LKP=K:FOR X=10 TO 0 STEP -1:SOUND 0,M(K),10,X:FOR D=1 TO 30:NEXT D:K=STICK(0):IF K=LKP THEN NEXT X
69 REM READ KEYBOARD AGAIN. IF KEY IS STILL THE SAME AT THE END OF DECAY WAIT FOR A NEW KEY TO BE PRESSED
70 NKP=STICK(0):IF NKP=LKP THEN 70
74 REM START SEQUENCE AGAIN
75 K=NKP:GOTO 55
79 REM CHORD ROUTINE. THIS IS THE SAME AS THE MULTIVOICE ROUTINE EXCEPT THE NOTE VALUES ARE DIFFERENT
80 K=STICK(0):L0=PADDLE(0):L1=PADDLE(1):L2=PADDLE(2):KC=PEEK(764):IF KC<>255 THEN 199
84 REM WATCH OUT FOR TWO KEYS BEING PRESSED AT ONE TIME GIVING A ZERO VALUE
85 IF K=0 THEN 80
89 REM IF NO KEY IS PRESSED TURN OF THE SOUND
90 IF K=15 THEN SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,0,0,0:GOTO 80
100 SOUND 0,L(K),10,L0:SOUND 1,M(K),10,L1:SOUND 2,H(K),10,L2:GOTO 80
198 REM THROW AWAY THE FIRST ATARI KEYPRESS AND SET UP THE SCREEN FOR THE MENU LINES 200 TO 220
199 GET #1,NULL
200 GRAPHICS 17:SETCOLOR 4,5,4:SETCOLOR 2,11,6:? #6:? #6:? #6;" SIMPLE SYNTHESIZER":? #6:? #6
210 ? #6:? #6:? #6;"MULTIPLE VOICES---1":? #6:? #6;"1ST OCTAVE CHORDS-2":? #6:? #6;"2ND OCTAVE CHORDS-3"
215 ? #6:? #6;"PIANO OCTAVE 1----4":? #6;"PIANO OCTAVE 2----5":? #6;"PIANO OCTAVE 3----6"
219 REM MAKE SURE THE INPUT IS VALID AND PROCESS THE CHOICE
220 ? #6:? #6:? #6;" SELECT MODE (1-6)";:GET #1,C:IF C<49 OR C>54 THEN 200:FLAG=0
229 REM TURN OFF THE SCREEN AND LOAD THE CORRECT MATRIX VALUES FOR THE MODE SELECTED
230 POKE 559,0:GOTO 230+10*(C-48)
240 FLAG=0:RESTORE 510:GOTO 500
250 FLAG=1:RESTORE 610:GOTO 600
260 FLAG=1:RESTORE 710:GOTO 700
270 RESTORE 810:GOTO 800
280 RESTORE 910:GOTO 900
290 RESTORE 1010:GOTO 1000
299 REM DO CHORDS IF SELECTED OTHERWISE DO MULTIVOICE
300 ON FLAG=1 GOTO 80:GOTO 20
499 REM ALL OF THE PITCH VALUES ARE STORED AS DATA STATEMENTS AND READ UPON DEMAND
500 FOR X=1 TO 13:READ A,B,C:M(X)=A:L(X)=B:H(X)=C:NEXT X:GOTO 300
510 DATA 121,243,60,114,230,57,108,217,53,102,204,50,96,193,47,91,182,45,85,173,42,81,162,40,76,153,37
520 DATA 72,144,35,68,136,33,64,128,31,60,121,29
600 FOR X=1 TO 13:READ A,B,C:L(X)=A:M(X)=B:H(X)=C:NEXT X:GOTO 300
610 DATA 243,193,162,230,182,153,217,173,144,204,162,136,193,153,128,182,144,121,173,136,114,162,128,108
620 DATA 153,121,102,144,114,96,136,108,91,128,102,85,121,96,81
700 FOR X=1 TO 13:READ A,B,C:L(X)=A:M(X)=B:H(X)=C:NEXT X:GOTO 300
710 DATA 121,96,81,114,91,76,108,85,72,102,81,68,96,76,64,91,72,60
720 DATA 85,68,57,81,64,53,76,60,50,72,57,48,68,53,45,64,50,42,60,47,40
800 FOR X=1 TO 13:READ A:M(X)=A:NEXT X:GOTO 50
810 DATA 243,230,217,204,193,182,173,162,153,144,136,128,121
900 FOR X=1 TO 13:READ A:M(X)=A:NEXT X:GOTO 50
910 DATA 121,114,108,102,96,91,85,81,76,72,68,64,60
1000 FOR X=1 TO 13:READ A:M(X)=A:NEXT X:GOTO 50
1010 DATA 60, 57,53,50,47,45,42,40,37,35,33,31,29