Random Music, music program (RNDMUSIC.BAS)
Random Music, music program by Charles Jackson, 50
Description
Random Music, music program by Charles Jackson, 50
From the Antic disk of November 1983 (Vol. 2 No. 8).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 1.6 KB
- Dialect
- Atari BASIC
- Lines
- 55
- Variables
P(,DICE(,OLDICE(,VALDICE(,I,P,TYPE,PIT,WT,WAIT,J,NUM
BASIC listing (55 lines)
0 REM PROGRAM LISTING ONE
1 REM ANTIC MAGAZINE
5 GRAPHICS 3
10 DIM P(16),DICE(7),OLDICE(7),VALDICE(7)
15 COLOR 1
20 FOR I=1 TO 16:READ P:P(I)=P:NEXT I
25 ? "TYPE OF MUSIC":? "1=WHITE; 2= BROWN; 3=1/F":INPUT TYPE:ON TYPE GOTO 100,200,300
45 REM SOUND AND PLOT
50 SOUND 2,12,10,14
55 SOUND 3,P(PIT),10,10
60 SOUND 2,0,0,0
65 PLOT I-40*INT(I/40),18-PIT
70 FOR WT=1 TO WAIT:NEXT WT
75 IF (I-40*INT(I/40))=39 THEN GRAPHICS 3
80 RETURN
100 REM WHITE MUSIC
105 FOR I=1 TO 128
110 PIT=1+INT(16*RND(1))
120 ? "WHITE MUSIC",PIT
130 WAIT=100
140 GOSUB 50
150 NEXT I
160 GOTO 4000
200 REM BROWN MUSIC
205 FOR I=1 TO 128
210 PIT=PIT-2+INT(5*RND(1))
215 IF PIT<1 OR PIT>16 THEN PIT=10
220 ? "BROWN MUSIC",PIT
230 WAIT=105
240 GOSUB 50
250 NEXT I
260 GOTO 4000
300 REM 1/F MUSIC
305 FOR J=1 TO 7:VALDICE(J)=INT(3*RND(1)):DICE(J)=0:OLDICE(J)=0:NEXT J
310 FOR I=1 TO 128
315 PIT=0:NUM=I
320 FOR J=1 TO 7
325 DICE(J)=NUM-2*(INT(NUM/2)):NUM=INT(NUM/2)
330 IF DICE(J)<>OLDICE(J) THEN VALDICE(J)=INT(3*RND(1))
335 OLDICE(J)=DICE(J)
340 PIT=PIT+1+VALDICE(J)
345 NEXT J
350 ? "1/F MUSIC",PIT
355 IF PIT<1 OR PIT>16 THEN PIT=10
360 WAIT=1
365 GOSUB 50
370 NEXT I
375 GOTO 4000
3000 REM DIATONIC SCALE- C MAJOR
3005 DATA 162,144,128,121,108,96,91,81,72,64,60,53,47,45,40,35
3010 REM PENTONIC SCALE
3015 DATA 243,217,182,162,144,121,108,96,81,72,60,53,60,72,81,91
3020 REM BUGLE NOTES
3025 DATA 239,119,79,59,47,39,33,29,26,23,21,19,16,14,14,13,12
4000 GRAPHICS 0:LIST :REM RETURNS TO GR.0
