Drawtext, speech with S.A.M. (DRAWTEXT.BAS)
Drawtext, speech with S.A.M. by Jerry White, 31
Description
Drawtext, speech with S.A.M. by Jerry White, 31
From the Antic disk of November 1983 (Vol. 2 No. 8).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 4.2 KB
- Dialect
- Atari BASIC
- Lines
- 112
- Variables
DL,SAM$,D6$,LINE$,AL$,KEY$,O,ME,ASM,PX,PY,ERASE,IT,SAMFLAG,KEY,SAM,STINDEX,TALK,LINE,Y,PIXELS,X,SM,JW,CP
BASIC listing (112 lines)
50 REM THIS PROGRAM IS DESIGNED TO BE USED WITH S.A.M. THE SOFTWARE VOICE BYTRONIX SOFTWARE. IT WILL UNDOUBTEDLY
51 REM LOCK-UP YOUR COMPUTER IF RUN WITHOUT S.A.M.
99 REM ANTIC MAGAZINE
100 REM DRAWTEXT 8/3/83
105 REM BY JERRY WHITE
110 REM
115 GOTO 155:REM BYPASS SUBROUTINE
120 REM
125 REM CHARACTER FETCH SUBROUTINE
130 REM FOR GR.4 DISPLAY
135 JW=57344+CP*8-1:REM LOCATE CHARACTER DATA IN ROM
140 FOR ME=SM TO SM+70 STEP 10:JW=JW+1:POKE ME,PEEK(JW):NEXT ME:RETURN
145 REM
150 REM INITIAL SCREEN DISPLAY
155 GRAPHICS 0:POKE 752,1:SAM=8192
160 POSITION 6,3:? "DRAWTEXT DEMO BY JERRY WHITE":POSITION 9,6
165 REM
170 REM FIND OUT IF SAM IS AVAILABLE
175 IF PEEK(SAM)=104 AND PEEK(SAM+1)=76 THEN ? " S.A.M. IS IN RAM":SAMFLAG=1:GOTO 185
180 ? "S.A.M. IS NOT IN RAM":SAMFLAG=0
185 IF NOT SAMFLAG THEN 225
190 REM
195 REM POKE S.A.M.
200 POKE 8550,234:POKE 8551,234:POKE 8552,234
205 POKE 8208,60:POKE 8209,60
210 POKE 8554,14:POKE 8559,13:POKE 8564,10
215 REM
220 REM CONVERT DATA TO STRING
225 POSITION 2,9:? "CREATING D6$ FROM DATA";
230 REM
235 REM DISPLAY A DOT FOR EACH BYTE
240 DIM D6$(184)
245 FOR ME=1 TO 184:READ IT:D6$(ME,ME)=CHR$(IT):? ".";:NEXT ME
250 REM
255 REM MORE HOUSEKEEPING
260 GRAPHICS 6:DL=PEEK(560)+256*PEEK(561):REM FIND DISPLAY LIST
265 DIM SAM$(20),LINE$(20),AL$(130)
270 REM
275 REM DEFINE SAM'S ALPHABET
280 AL$="EYY4 BIYY4SIYY4DIYY4IYY4 EH4F DJIY4EY4CHAY4 "
285 AL$(LEN(AL$)+1)="JEY4 KEY4 EH4L EH4M EH4N OW4 PIY4 KYUW4AA4R "
290 AL$(LEN(AL$)+1)="EH4S TTIY4YUW4 VIY4 WWWWWEH4KSWAY4 ZIY4 "
295 REM
300 REM SETUP MIXED DISPLAY LIST
305 POKE DL+3,75:FOR ME=DL+6 TO DL+13:POKE ME,11:NEXT ME
310 FOR ME=DL+14 TO DL+49:POKE ME,9:NEXT ME
315 FOR ME=DL+50 TO DL+64:POKE ME,11:NEXT ME
320 POKE DL+65,65:POKE DL+66,PEEK(560):POKE DL+67,PEEK(561)
325 REM
330 REM USE IOCB #5 FOR THE KEYBOARD
335 CLOSE #5:OPEN #5,4,0,"K:"
340 REM
345 REM NOW WE'RE READY
350 REM TO DISPLAY OUR TOP LINE
355 LINE$="DRAWTEXT":PX=7:PY=1:GOSUB 640
360 REM
365 SM=PEEK(88)+256*PEEK(89):REM LOCATE SCREEN MEMORY
370 SM=SM+302:REM ADD OFFSET TO CENTER SCREEN
375 REM
380 REM DISPLAY "S.A.M." IN MODE GR.4
385 CP=ASC("S")-32:GOSUB 135
390 CP=ASC(".")-32:SM=SM+1:GOSUB 135
395 CP=ASC("A")-32:SM=SM+1:GOSUB 135
400 CP=ASC(".")-32:SM=SM+1:GOSUB 135
405 CP=ASC("M")-32:SM=SM+1:GOSUB 135
410 CP=ASC(".")-32:SM=SM+1:GOSUB 135
415 REM
420 REM DISPLAY INSTRUCTIONS
425 REM SLIDING UP FROM THE BOTTOM
430 PX=1:LINE$="TYPE A LETTER PLEASE"
435 FOR PY=36 TO 28 STEP -1:GOSUB 640:NEXT PY
440 REM
445 REM ERASE WHAT WE LEFT BEHIND
450 FOR PY=41 TO 34 STEP -1:COLOR 0:PLOT 0,PY:DRAWTO 159,PY:NEXT PY
455 REM
460 REM KEYBOARD INPUT ROUTINE
465 POKE 764,255:PX=10:PY=36
470 IF PEEK(764)=255 THEN 470
475 GET #5,KEY:IF KEY<65 OR KEY>90 THEN KEY=63:REM LETTERS ONLY
480 LINE$=CHR$(KEY):GOSUB 640:REM DISPLAY CHARACTER
485 IF NOT SAMFLAG THEN 465:REM WAIT FOR ANOTHER KEY
490 IF KEY=63 THEN SAM$="UH1PS":GOTO 515:REM DISPLAY ? AND SAY OOOPS
495 REM
500 REM LOOK IT UP IN SAMS DICTIONARY
505 STINDEX=KEY-65:SAM$=AL$(STINDEX*5+1,STINDEX*5+5)
510 IF SAM$="WWWWW" THEN SAM$="DAH4BULYUW6":REM W
515 SAM$(LEN(SAM$)+1)=".":TALK=USR(SAM):REM SAM SPEAKS
520 GOTO 465:REM PLAY IT AGAIN SAM
525 REM
530 REM DATA FOR MODE6 DISPLAY SUBROUTINE
535 DATA 104,104,133,204,104,133,203,104,104,141
540 DATA 0,6,104,104,141,1,6,206,1,6
545 DATA 104,104,141,2,6,206,2,6,173,48
550 DATA 2,133,207,173,49,2,133,208,160,4
555 DATA 177,207,141,4,6,200,177,207,141,5
560 DATA 6,172,2,6,240,17,24,173,4,6
565 DATA 105,20,141,4,6,144,3,238,5,6
570 DATA 136,208,239,24,173,4,6,109,1,6
575 DATA 141,4,6,144,3,238,5,6,169,0
580 DATA 141,3,6,172,3,6,204,0,6,176
585 DATA 82,169,0,133,206,177,203,56,233,32
590 DATA 133,205,24,6,205,38,206,6,205,38
595 DATA 206,6,205,38,206,165,206,9,224,133
600 DATA 206,173,4,6,133,207,173,5,6,133
605 DATA 208,160,0,162,6,177,205,145,207,230
610 DATA 205,208,2,230,206,24,165,207,105,20
615 DATA 133,207,144,2,230,208,202,16,232,238
620 DATA 3,6,238,4,6,208,3,238,5,6
625 DATA 56,176,166,96
630 REM
635 REM DISPLAY MODE 6 TEXT SUBROUTINE
640 ASM=USR(ADR(D6$),ADR(LINE$),LEN(LINE$),PX,PY):RETURN
