Pick a Chord, music program (CHORDS.BAS)

Pick a Chord, music program by Karl Wiegers, 47

Description

Pick a Chord, music program by Karl Wiegers, 47

From the Antic disk of November 1983 (Vol. 2 No. 8).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.7 KB

Dialect
Atari BASIC
Lines
48
Variables
MENU1$, MENU2$, PITCH(, INTS(, N(, I, A, KEY, CHORD
BASIC listing (48 lines)
10 REM ......CHORD PROGRAM......
20 REM ......by Karl E. Wiegers.....
30 REM .....ANTIC MAGAZINE 1983......
40 DIM MENU1$(60),MENU2$(72),PITCH(37),INTS(48),N(4)
50 GRAPHICS 0:SETCOLOR 1,0,0:SETCOLOR 2,12,8:POKE 752,1
60 POSITION 5,2:? "ONE MOMENT, PLEASE...."
70 MENU1$="C    C#/DbD    D#/EbE    F    F#/GbG    G#/AbA    A#/BbB    "
80 MENU2$="major minor dom7  maj7  min7  min7b5dim7  aug   9th   min9  6th   sus4  "
90 FOR I=1 TO 37:READ A:PITCH(I)=A:NEXT I:REM Pitch values for musical notes
100 DATA 243,230,217,204,193,182,173,162,153,144
110 DATA 136,128,121,114,108,102,96,91,85,81
120 DATA 76,72,68,64,60,57,53,50,47,45
130 DATA 42,40,37,35,33,31,29
140 FOR I=1 TO 48:READ A:INTS(I)=A:NEXT I:REM Intervals for different chords
150 DATA 1,8,13,17,1,8,13,16,1,8,11,17,1,8,12,17
160 DATA 1,8,11,16,1,7,11,16,1,7,10,16,1,9,13,17
170 DATA 1,5,11,15,1,4,11,15,1,8,10,17,1,6,8,13
180 FOR I=0 TO 19:READ A:POKE 1536+I,A:NEXT I:REM Display list interrupt
190 DATA 72,138,72,169,14,162,248,141,10,212
200 DATA 141,23,208,142,24,208,104,170,104,64
210 ? CHR$(125):REM Clear the screen
220 POSITION 10,2:? "KEY":POSITION 25,2:? "CHORD"
230 FOR I=1 TO 12:POSITION 8-(I>9),3+I:? I;". ";MENU1$(5*I-4,5*I)
240 POSITION 23-(I>9),3+I:? I;". ";MENU2$(6*I-5,6*I):NEXT I
250 POKE 703,4:REM Set up a text window in this Graphics Mode 0 display
260 POKE (PEEK(560)+256*PEEK(561)+23),130:REM Set DLI on line 18 of display
270 POKE 512,0:POKE 513,6:POKE 54286,192:REM Enable display list interrupt
280 TRAP 300:? "Enter a Key: ";:INPUT KEY
290 IF KEY>0 AND KEY<13 THEN TRAP 40000:GOTO 310
300 ? "↰ENTER A NUMBER FROM 1-12":? :GOTO 280:REM ESC CTRL-2 FOR ↰
310 POSITION 14,18:? #6;MENU1$(5*KEY-4,5*KEY)
320 TRAP 340:? "Enter a Chord: ";:INPUT CHORD
330 IF CHORD>0 AND CHORD<13 THEN TRAP 40000:GOTO 350
340 ? "↰ENTER A NUMBER FROM 1-12":? :GOTO 320:REM ESC CTRL-2 FOR ↰
350 POSITION 20,18:? #6;MENU2$(6*CHORD-5,6*CHORD)
360 FOR I=4 TO 15:POSITION 6,I:? #6;" ":NEXT I
370 FOR I=1 TO 4:A=INTS((CHORD-1)*4+I)+KEY-1:N(I)=PITCH(A):REM Choose notes
380 POSITION 6,3+A-12*(A>12)-12*(A>24):? #6;CHR$(159):REM Draw arrows
390 NEXT I
400 FOR I=0 TO 3:SOUND I,N(I+1),10,3:NEXT I:REM Here is the chord
410 FOR I=1 TO 400:NEXT I:REM Play chord for about 2 seconds
420 FOR I=0 TO 3:SOUND I,0,0,0:NEXT I:REM Turn off sound channels
430 ? :? "PRESS RETURN TO GO ON, ESC TO QUIT"
440 OPEN #1,4,0,"K:"
450 GET #1,A:IF A=27 THEN 480
460 IF A<>155 THEN 450
470 CLOSE #1:? :GOTO 280
480 GRAPHICS 0:END