Microloader, graphics utility (MICROLDR.BAS)

Microloader, graphics utility

Description

Microloader, graphics utility

From the Antic disk of October 1983 (Vol. 2 No. 7).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.2 KB

Dialect
Atari BASIC
Lines
53
Variables
CAPS, LOWC, INVC, INLC, BRDR, ANTIC, DL, I, A, FN$, LDR$, F$, X, J1, J2, J3, J4, SEC, BYT, SECT, BYTE, T
BASIC listing (53 lines)
10 REM MICROLOADER
20 REM A UTILITY FOR
30 REM USING MICROPAINTER FILES
40 REM BY DAVID MILLIGAN,ESQ. 1/15/83
45 REM ANTIC MAGAZINE
50 GRAPHICS 0:POKE 752,1:CAPS=708:LOWC=709:INVC=710:INLC=711:BRDR=712:ANTIC=559
60 TRAP 470
70 POKE INVC,0:POKE LOWC,54:POKE INLC,134:REM SETUP COLOR REGISTERS
80 DL=PEEK(560)+256*PEEK(561):REM SETUP FIRST DIPLAY LIST
90 POKE DL+3,71:POKE DL+6,0
100 FOR I=DL+7 TO DL+25:A=PEEK(I)
110 IF A=2 THEN POKE I,6:NEXT I
120 POSITION 4,0:? "MICROPAINTER":REM TITLE SCREEN
130 POSITION 3,2:? "screen  loader":REM USE INVERSE LOWERCASE
140 POSITION 9,3:? "BY"
150 POSITION 1,4:? "david milligan,esq.":REM USE INVERSE LOWERCASE
160 POSITION 2,6:? "AFTER SCREEN HAS "
170 POSITION 2,7:? "LOADED,PRESS ANY "
180 POSITION 2,8:? "KEY TO LOAD THE "
190 POSITION 2,9:? "NEXT SCREEN."
200 POSITION 4,12:? " ENTER FILENAME:"
210 DIM FN$(20),LDR$(32),F$(15)
220 FOR I=1 TO 32:READ A:LDR$(I)=CHR$(A):NEXT I:REM INSTALL M.L. LOADER
230 POSITION 20,12:INPUT F$
240 FN$="D:":FN$(LEN(FN$)+1)=F$
250 GRAPHICS 10:POKE ANTIC,0:POKE 623,0:REM SETUP MODE "E" D.L.
260 DL=PEEK(560)+256*PEEK(561)
270 POKE DL+3,78
280 FOR I=DL+6 TO DL+200
290 A=PEEK(I):IF A=15 THEN POKE I,14
300 IF A=79 THEN POKE I,78
310 NEXT I
320 POKE ANTIC,34
330 OPEN #3,4,0,FN$:GOSUB 420:REM LOAD SCREEN DATA
340 TRAP 470
350 X=USR(ADR(LDR$))
360 GET #3,J1:GET #3,J2:GET #3,J3:GET #3,J4
370 POKE BRDR,J1:POKE CAPS,J2:POKE LOWC,J3:POKE INVC,J4:REM MAKE SURE COLORS ARE CORRECT
380 POKE 764,255
390 IF PEEK(764)=255 THEN 390
400 POKE 764,255
410 CLR :RUN
420 NOTE #3,SEC,BYT:SECT=SEC+61:BYTE=55:POINT #3,SECT,BYTE:REM GET COLOR DATA
440 GET #3,J1:GET #3,J2:GET #3,J3:GET #3,J4
450 POKE BRDR,J1:POKE CAPS,J2:POKE LOWC,J3:POKE INVC,J4
460 POINT #3,SEC,BYT:RETURN
470 IF PEEK(195)=164 THEN 460:REM IF FILE IS APPENDED,LOAD IT ANYWAY
480 GRAPHICS 0:? "ERROR # ";PEEK(195):FOR T=0 TO 200:NEXT T:RUN
490 DATA 104,162,48,169,7,157,66
500 DATA 3,165,88,157,68,3,165
510 DATA 89,157,69,3,169,0,157
520 DATA 72,3,169,30,157,73,3
530 DATA 32,86,228,96