Pattern Maker graphics program (PATTERNS.BAS)
Pattern Maker graphics program
Description
Pattern Maker graphics program
From the Antic disk of September 1983 (Vol. 2 No. 6).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 7.9 KB
- Dialect
- Atari BASIC
- Lines
- 204
- Variables
FILE$,T$,X$,Y$,E,S,Q,UP,DOWN,RIGHT,LEFT,YES,PLACE,MENU,SKETCHPD,MOVE,CHECK,MIRROR,BLOT,PATTERNS,MAKE,FILE,FETCH,INSTRUCT,EXIT,NAMECHEK,FILERROR,RESPONSE,AGAIN,KEY,X,J,Y,A,FX,B,FY,I,CHOICE,DRW,DESIGN,ROW,IMAGE
BASIC listing (204 lines)
10 REM ******************************
11 REM
12 REM D:PATTERNS
13 REM by Frank Roberts
15 REM
16 REM Generates repeated patterns
17 REM from user created designs
18 REM
19 REM ******************************
20 REM
50 DIM FILE$(30),T$(30),X$(1000),Y$(1000)
55 E=69:S=83:Q=81:UP=45:DOWN=61:RIGHT=42:LEFT=43:YES=89
58 PLACE=105
60 MENU=700:REM PIVOT OF PROGRAM
62 SKETCHPD=400:REM DRAWS SKETCHPAD
64 MOVE=600:REM ACCEPTS USER DRAWING
66 CHECK=650:REM CHECKS VALID DESIGN
68 MIRROR=800:REM MIRROR PARAMETERS
70 BLOT=810:REM INK BLOT
72 PATTERNS=820:REM PATTERN ROWS
74 MAKE=900:REM MAKES DESIGNS
76 FILE=1000:REM STORES DESIGN DISK
78 FETCH=2000:REM GETS DESIGN FM DISK
80 INSTRUCT=3000:REM INSTRUCTIONS
82 EXIT=4000:REM TERMINATES PROGRAM
84 NAMECHEK=200:REM CHECKS VALID FILE
86 FILERROR=2500:REM FILE NOT FOUND
88 RESPONSE=100:REM CONTINUATION KEY
90 AGAIN=0:GOTO MENU
99 REM ***** GET USER INPUT SUB *****
100 CLOSE #3:OPEN #3,4,0,"K:":GET #3,KEY:POKE 764,255
102 IF PEEK(694)<>0 THEN POKE 694,0:KEY=KEY-128
103 RETURN
105 X=ASC(X$(J,J)):Y=ASC(Y$(J,J)):RETURN :REM X,Y COORDINATES
106 A=X+FX:B=Y+FY:RETURN :REM UPPER LEFT
107 A=(24-X)+FX:B=Y+FY:RETURN :REM UPPER RIGHT
108 A=X+FX:B=(24-Y)+FY:RETURN :REM LOWER LEFT
109 A=(24-X)+FX:B=(24-Y)+FY:RETURN :REM LOWER RIGHT
199 REM ***** CHECK LEGAL FILE NAME *
200 GRAPHICS 1:COLOR 1:POKE 752,1:POKE 764,255:FOR I=1 TO 5:? #6:NEXT I
201 ? #6;" ENTER NAME OF FILE":? #6:? #6:? #6
202 ? #6;" PRESS return ONLY":? #6;" TO RETURN TO MENU"
203 ? :INPUT FILE$
204 IF LEN(FILE$)=0 THEN GOTO MENU
206 IF ASC(FILE$(1,1))>64 AND ASC(FILE$(1,1))<91 THEN 220
208 GRAPHICS 1:COLOR 1:POKE 752,1:? #6:? #6
210 ? #6;" FIRST LETTER":? #6;" OF FILE NAME":? #6;" MUST BEGIN WITH":? #6;" A LETTER (A-Z)"
211 ? #6:? #6;" RE-ENTER FILE NAME"
212 ? :? :? "↰":?
214 GOTO 203
220 IF LEN(FILE$)<2 THEN 224
222 IF FILE$(1,2)="D:" THEN 225
223 IF FILE$(1,2)="C:" THEN 225
224 T$="D:":T$(3)=FILE$:FILE$=T$
225 RETURN
399 REM ***** PREPARE SKETCHPAD *****
400 GRAPHICS 5:COLOR 1:POKE 752,1
402 POKE 764,255
404 PLOT 53,33:DRAWTO 53,7:DRAWTO 27,7:POSITION 27,32:POKE 765,3:XIO 18,#6,0,0,"S:"
410 COLOR 1:PLOT 27,33:DRAWTO 53,33
420 COLOR 3
425 IF NOT CHOICE THEN GOTO INSTRUCT
430 IF NOT AGAIN OR (LEN(X$)=0) THEN X$="":Y$="":X=12:Y=12:COLOR 2:PLOT X+28,Y+8:AGAIN=1:GOTO 450
440 COLOR 0
441 FOR J=1 TO LEN(X$)
442 GOSUB PLACE
444 PLOT X+28,Y+8
446 NEXT J
448 COLOR 2:PLOT X+28,Y+8:DRW=0
450 ? "ARROWSdraw Start/Stop drawing":?
460 ? "Erase design Quit drawing"
470 CLOSE #3:OPEN #3,4,0,"K:"
599 REM ***** USER CREATES DESIGN ***
600 GET #3,KEY:REM MOVE ROUTINE
601 IF PEEK(694)<>0 THEN POKE 694,0:GOTO 600:REM DISABLE INVERSE VIDEO KEY
602 IF PEEK(702)=0 THEN POKE 702,64:GOTO 600:REM DISABLE LOWER CAPS KEY
605 IF NOT DRW THEN COLOR 3:PLOT X+28,Y+8
606 IF KEY=Q THEN GOTO CHECK
607 IF KEY=S AND NOT DRW THEN DRW=1:GOTO 619
608 IF DRW AND KEY=S THEN DRW=0:COLOR 1:PLOT X+28,Y+8:X$(LEN(X$))="":Y$(LEN(Y$))=""
610 IF KEY=E THEN AGAIN=0:GOTO SKETCHPD
612 IF KEY=UP THEN Y=Y-1:IF Y<0 THEN Y=24
614 IF KEY=DOWN THEN Y=Y+1:IF Y>24 THEN Y=0
615 IF KEY=LEFT THEN X=X-1:IF X<0 THEN X=24
618 IF KEY=RIGHT THEN X=X+1:IF X>24 THEN X=0
619 IF DRW THEN X$(LEN(X$)+1)=CHR$(X):Y$(LEN(Y$)+1)=CHR$(Y):COLOR 0:PLOT X+28,Y+8:GOTO MOVE
620 COLOR 2:PLOT X+28,Y+8
645 GOTO MOVE
649 REM ***** CHECK VALID DESIGN ****
650 IF LEN(X$)>1 THEN GOTO MENU
655 GRAPHICS 17:COLOR 1:POKE 764,255
660 FOR I=1 TO 5:? #6:NEXT I
665 ? #6;" YOU DO NOT HAVE"
666 ? #6;"LARGE ENOUGH DESIGN"
667 ? #6;" TO MAKE A PATTERN"
668 ? #6:? #6:? #6;" DO YOU WANT MORE":? #6:? #6:? #6;" (Y/N)"
670 GOSUB RESPONSE:IF KEY=89 THEN GOTO SKETCHPD
675 IF KEY<>78 THEN 670
680 AGAIN=0:DRW=0:GOTO MENU
699 REM ***** MAIN MENU ROUTINE *****
700 GRAPHICS 17:COLOR 1:POKE 752,1:POKE 764,255:POP :REM MENU ROUTINE
705 ? #6;" pattern maker"
706 ? #6;" by frank roberts"
707 ? #6:? #6:? #6;" 0 INSTRUCTIONS"
708 ? #6:? #6;" 1 create/edit design"
709 ? #6:? #6;" 2 mirror image"
710 ? #6:? #6;" 3 ink blot"
711 ? #6:? #6;" 4 patterns"
712 ? #6:? #6;" 5 save design"
713 ? #6:? #6;" 6 load design"
714 ? #6:? #6;" 7 stop program"
715 ? #6:? #6:? #6;" YOUR CHOICE ?"
720 GOSUB RESPONSE:POKE 764,255
730 IF KEY<48 OR KEY>55 THEN 720
735 CHOICE=KEY-48
737 POKE 764,255
740 ON CHOICE+1 GOTO SKETCHPD,SKETCHPD,MIRROR,BLOT,PATTERNS,FILE,FETCH,EXIT
799 REM ***** SET UP MODE FACTORS
800 FX=60:FY=20:GRAPHICS 7:GOTO 830
810 FX=60:FY=10:GRAPHICS 7:GOTO 830
820 FX=40:FY=10:GRAPHICS 8
830 DESIGN=0:ROW=0:POKE 752,1
840 IF LEN(X$)<2 THEN GOTO CHECK
850 ? "PRESS ESCAPE KEY TO STOP/START DESIGN"
860 ? :REM COMMAND FOR SCREEN DUMP GOES HERE
890 ? "PRESS ANY OTHER KEY TO RETURN TO MENU"
899 REM ***** DRAW PATTERNS FM DESIGN
900 SETCOLOR 2,0,0
902 FOR IMAGE=1 TO 4
907 IF CHOICE=2 AND IMAGE>2 THEN 965
908 IF IMAGE=3 THEN FY=FY+24
910 FOR J=1 TO LEN(X$)
920 GOSUB PLACE
930 GOSUB PLACE+IMAGE
935 IF PEEK(764)=28 THEN POKE 764,255:GOSUB RESPONSE:IF KEY<>27 THEN GOTO MENU
940 REM
950 PLOT A,B
960 NEXT J
965 NEXT IMAGE
970 IF CHOICE<4 THEN GOSUB RESPONSE:GOTO MENU
975 FX=FX+24:FY=FY-24:DESIGN=DESIGN+1:IF DESIGN<10 THEN GOTO MAKE
977 FX=40:FY=FY+48:DESIGN=0:ROW=ROW+1:IF ROW<3 THEN GOTO MAKE
980 GOSUB RESPONSE
990 GOTO MENU
999 REM ***** STORE DESIGN *****
1000 IF LEN(X$)=0 THEN GOTO MENU
1010 GOSUB NAMECHEK
1020 OPEN #1,8,0,FILE$
1100 PRINT #1;X$
1200 PRINT #1;Y$
1300 CLOSE #1
1310 GRAPHICS 1:COLOR 1:FOR I=1 TO 5:? #6:NEXT I
1320 ? #6;FILE$;" IS FILED":? #6:? #6:? #6;" PRESS ANY KEY "
1330 GOSUB RESPONSE:GOTO MENU
1999 REM ***** FETCH DESIGN *****
2000 GRAPHICS 1:COLOR 1:POKE 752,1:POKE 764,255
2010 X$="":Y$=""
2020 GOSUB NAMECHEK
2030 TRAP FILERROR
2040 OPEN #1,4,0,FILE$
2050 TRAP 2080
2060 INPUT #1,X$
2070 INPUT #1,Y$
2080 CLOSE #1
2090 AGAIN=1:GOTO MENU
2499 REM ***** FILE NOT FOUND ERROR *
2500 GRAPHICS 1:COLOR 1:POKE 752,1:POKE 764,255:REM CHECK FOR NO FILE FOUND
2510 FOR I=1 TO 5:? #6:NEXT I
2520 ? #6;" FILE NOT FOUND"
2530 ? #6:? #6;" DO YOU WANT TO SEE"
2540 ? #6;" DISK DIRECTORY ?"
2550 ? #6:? #6;" (Y/N)"
2560 GOSUB RESPONSE
2570 IF KEY<>YES THEN GOTO MENU
2580 GRAPHICS 0:POKE 752,1:POKE 764,255
2590 CLOSE #1:OPEN #1,6,0,"D:*.*"
2600 TRAP 2700
2610 INPUT #1,X$
2620 ? X$
2630 AGAIN=0:GOTO 2610
2700 CLOSE #1
2710 ? :? "DO YOU WANT TO TRY AGAIN ? (Y/N)"
2720 GOSUB RESPONSE
2730 IF KEY=YES THEN GOTO FETCH
2740 AGAIN=0:GOTO MENU
2999 REM ***** GET INSTRUCTIONS *****
3000 POKE 764,255:POKE 752,1
3001 ? "When you choose option 1 you will":? "see a sketch pad like the one above."
3002 ? "(PRESS ANY KEY FOR MORE INSTRUCTIONS)"
3003 GOSUB RESPONSE:GRAPHICS 0:POKE 752,1
3004 ? "Use the keyboard arrow keys to plot":? "a design on the sketch pad."
3005 ? "All black lines or points drawn on":? "the pad will be stored in memory"
3007 ? "to be transformed into designs.":? :? "Any line or point color other than"
3008 ? "black will not be plotted.":? "You may change the color at any time"
3009 ? "by pressing the 'S' key. "
3010 ? :? "Pressing 'E' will erase your design":? "so that you may start again"
3012 ? :? "When you have the design you want,"
3013 ? "press the 'Q' key and the program":? "will return you to the menu "
3014 ? "--from which you may select other":? "options."
3015 ? :? :? "PRESS ESCAPE KEY TO RETURN TO MENU":? "ANY OTHER KEY REPEATS INSTRUCTIONS"
3018 GOSUB RESPONSE:IF KEY=27 THEN AGAIN=0:GOTO MENU
3020 GRAPHICS 0:POKE 752,1:GOTO INSTRUCT+4
3999 REM ***** TERMINATE PROGRAM ****
4000 GRAPHICS 0:CLR :END
