Object code to string programming tool (OBJ2STR.BAS)
Object code to string programming tool
Description
Object code to string programming tool
From the Antic disk of September 1983 (Vol. 2 No. 6).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.2 KB
- Dialect
- Atari BASIC
- Lines
- 39
- Variables
SLINE,LINC,LO,HI,WD,SA,EA,SIZE,JW,COUNT,ME,CHAR,SPEC(,SPEC,FILE$,FLIN$,FLOUT$,BACKS
BASIC listing (39 lines)
0 REM OBJ2STR 4/7/83 BY JERRY WHITE
100 GOTO 320
110 SLINE=SLINE+LINC:IF SLINE>32767 THEN POP :? :? " LINE NUMBER OVERFLOW.":END
120 RETURN
130 GET #1,LO:GET #1,HI:WD=LO+HI*256:RETURN
140 GOSUB 130:IF WD<>65535 THEN ? :? " NOT BINARY LOAD FORMAT":END
150 GOSUB 130:SA=WD:GOSUB 130:EA=WD:SIZE=EA-SA
160 ? #2;SLINE;" DIM ASM$(";SIZE;")"
170 FOR JW=1 TO SIZE STEP 80:IF JW+80>SIZE THEN COUNT=SIZE-JW:GOTO 190
180 COUNT=79
190 GOSUB 110:? #2;SLINE;" ASM$(";JW;")=";CHR$(34);
200 FOR ME=0 TO COUNT:GET #1,CHAR
210 IF CHAR=34 OR CHAR=155 THEN SPEC(SPEC,0)=ME+JW:SPEC(SPEC,1)=CHAR:SPEC=SPEC+1:CHAR=32
220 PUT #2,CHAR:NEXT ME:PUT #2,34:PUT #2,155:NEXT JW
230 IF SPEC=0 THEN 260
240 FOR JW=0 TO SPEC-1:GOSUB 110
250 ? #2;SLINE;" ASM$(";SPEC(JW,0);",";SPEC(JW,0);")=CHR$(";SPEC(JW,1);")":NEXT JW
260 GOSUB 110:? #2;SLINE;" RETURN"
270 CLOSE #1:CLOSE #2:? CHR$(28);CHR$(156);:? ,"I DID IT!":POKE 752,0
280 ? :? "NEW":? :? :? "ENTER";CHR$(34);FILE$;CHR$(34):? :? :? "LIST"
290 FOR JW=1 TO 9:? CHR$(28);:NEXT JW:END
300 ? :? "UNABLE TO OPEN ";FILE$:GOTO 340
310 ? :? "UNABLE TO OPEN ";FILE$:GOTO 380
320 GRAPHICS 0:DIM FILE$(15),FLIN$(15),FLOUT$(15),SPEC(256,1)
325 POKE 710,144:POKE 709,12:POKE 82,1:POKE 201,11:SPEC=0:LINC=1
330 ? :? " OBJECT CODE TO BASIC STRING ":? ,"by Jerry White"
340 ? :? " DISK DRIVE 1 ASSUMED IF NOT SPECIFIED "
345 ? " INPUT FILENAME ";:INPUT FLIN$:FILE$="D:"
350 IF FLIN$(2,2)=":" OR FLIN$(3,3)=":" THEN FILE$=FLIN$:GOTO 370
360 FILE$(LEN(FILE$)+1)=FLIN$
370 TRAP 300:CLOSE #1:OPEN #1,4,0,FILE$
380 ? :? " OUTPUT FILENAME ";:INPUT FLOUT$:FILE$="D:"
390 IF FLOUT$(2,2)=":" OR FLOUT$(3,3)=":" THEN FILE$=FLOUT$:GOTO 410
400 FILE$(LEN(FILE$)+1)=FLOUT$
410 TRAP 310:CLOSE #2:OPEN #2,8,0,FILE$
420 ? :? " STARTING LINE # 31000";:FOR BACKS=1 TO 6:? CHR$(30);:NEXT BACKS
425 TRAP 420:INPUT SLINE:SLINE=INT(SLINE):IF SLINE<1 OR SLINE>32700 THEN 420
430 POKE 752,1:POKE 82,2:POKE 201,8:? :? ,"I'm working on it!":TRAP 440:POKE 201,10:GOTO 140
440 ? :? "ERROR ";PEEK(195);" AT LINE ";PEEK(186)+256*PEEK(187):END
