Cardfile for Cassettes database program (CARDFILC.BAS)

Cardfile for Cassettes database program

Description

Cardfile for Cassettes database program

From the Antic disk of September 1983 (Vol. 2 No. 6).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 3.2 KB

Dialect
Atari BASIC
Lines
54
Variables
SA$, WS$, A$, CD$, TR$, C$, P, O, N, M, MENU, CAL1, CAL2, CAL3, CAL4, SCN, FILL, CHK, CL, B, C, E, F, A, L, S, FLAG, CF, I, LN, CD, CH
BASIC listing (54 lines)
5 REM VERN L. MASTEL-THE ELECTRO-CARDFILE ** ANTIC MAGAZINE **
10 DIM SA$(450),WS$(15),A$(2),CD$(9000),TR$(90),C$(30):SA$(1)=" ":SA$(450)=" ":SA$(2)=SA$
20 CD$(1)=" ":CD$(9000)=" ":CD$(2)=CD$:? CHR$(125)
40 READ P,O,N,M,MENU,CAL1,CAL2,CAL3,CAL4,SCN,FILL,CHK,CL:GOTO MENU
50 DATA 1,30,10,15,10000,100,110,120,130,140,160,150,170
100 B=(M*(C-P)+P):E=B+14:RETURN
110 F=300*(C-P):RETURN
120 B=(O*(A-P)+P):E=B+29:B=B+F:E=E+F:RETURN
130 B=90*(A-P)+P:E=B+89:RETURN
140 ? CHR$(125):RETURN
150 IF C=50 OR L=50 THEN 159
155 IF C<0 OR L<0 THEN 159
156 IF L>10 OR C>30 THEN 159
157 RETURN
159 POP :L=0:C=0:GOSUB SCN:GOTO MENU
160 FOR S=LEN(C$)+P TO O:C$(LEN(C$)+P)=" ":NEXT S:RETURN
170 C=0:L=0:RETURN
500 GOSUB CAL1:LPRINT SA$(B,E):GOSUB CAL2:FOR L=P TO N:A=L:GOSUB CAL3:LPRINT CD$(B,E):NEXT L:GOSUB SCN:GOTO MENU
1000 GOSUB SCN:? "WHICH CARD DO YOU WISH TO TITLE":GOSUB CL:INPUT C:GOSUB CHK:? "INPUT TITLE OF CARD #";C
1005 TR$="|---------------|":? TR$:INPUT WS$
1010 ON LEN(WS$)=M GOTO 1030:FOR S=LEN(WS$)+P TO M:WS$(LEN(WS$)+P)=" ":NEXT S
1030 GOSUB CAL1:SA$(B,E)=WS$:GOTO MENU
2000 GOSUB SCN:FOR C=P TO M:GOSUB CAL1:? C;" ";SA$(B,E);" ";C+M;" ";SA$(B+225,E+225):NEXT C:ON FLAG GOTO 6020
2010 GOTO MENU
3000 GOSUB SCN:? "WHICH CARD DO YOU WISH TO FILL":GOSUB CL:INPUT C:GOSUB CHK:? "HOW MANY LINES DO YOU NEED":INPUT L
3010 GOSUB CHK:? "NOW ENTER THE DATA":TR$=" |------------------------------|":? TR$
3020 GOSUB CAL2:FOR CF=P TO L:? CF;:INPUT C$:ON LEN(C$)=O GOTO 3040:GOSUB FILL
3040 A=CF:GOSUB CAL3:CD$(B,E)=C$:NEXT CF:FOR CF=L+P TO N:ON L+P>N GOTO MENU
3060 C$="                               ":A=CF:GOSUB CAL3:CD$(B,E)=C$:NEXT CF:GOTO MENU
4000 GOSUB SCN:? "WHICH CARD DO YOU WISH TO CHANGE":GOSUB CL:INPUT C:GOSUB CHK
4005 ? "ENTER THE LINE NUMBER YOU WISH TO CHANGE":INPUT L:GOSUB CHK
4010 GOSUB CAL2:A=L:GOSUB CAL3:? "INPUT NEW LINE# ";L:INPUT C$:ON LEN(C$)=O GOTO 4040:GOSUB FILL
4040 CD$(B,E)=C$:? "DO YOU WISH TO CHANGE ANOTHER LINE Y/N":INPUT A$:ON A$="Y" GOTO 4005:GOTO MENU
5000 GOSUB SCN:? "WHICH CARD DO YOU WISH TO DELETE":GOSUB CL:INPUT C:GOSUB CHK
5010 ? "DELETING CARD #";C:GOSUB CAL1:FOR S=B TO E:SA$(S,S)=" ":NEXT S:B=300*(C-P)+P:E=B+299:FOR S=B TO E
5020 CD$(S,S)=" ":NEXT S:? "DELETION COMPLETE":GOTO MENU
6000 GOSUB SCN:FLAG=0:? "DO YOU NEED TO SEE THE CARD LIST Y/N":INPUT A$:IF A$="Y" THEN FLAG=P:GOTO 2000
6020 ? "WHICH CARD DO YOU WISH TO VIEW":GOSUB CL:INPUT C:GOSUB CAL1:GOSUB SCN:POSITION 13,P:? SA$(B,E)
6030 GOSUB CAL2:FOR L=P TO N:A=L:GOSUB CAL3:? CD$(B,E):NEXT L
6040 POSITION P,18:? "THAT'S ALL OF THE ENTRIES, DO YOU WANT A COPY Y/N":INPUT A$:IF A$="Y" THEN GOTO 500
6050 GOSUB SCN:GOTO MENU
7000 OPEN #3,8,128,"C":FOR A=P TO 5:GOSUB CAL4:TR$=SA$(B,E):PRINT #3;TR$:FOR I=P TO 50:NEXT I:NEXT A
7010 FOR A=P TO 100:GOSUB CAL4:TR$=CD$(B,E):PRINT #3;TR$:FOR I=P TO 50:NEXT I:NEXT A:CLOSE #3
7020 ? "SAVE COMPLETE":GOTO MENU
8000 OPEN #3,4,128,"C":FOR A=P TO 5:GOSUB CAL4:INPUT #3;TR$:SA$(B,E)=TR$:NEXT A
8010 FOR A=P TO 100:GOSUB CAL4:INPUT #3;TR$:CD$(B,E)=TR$:NEXT A
8020 CLOSE #3:? "INPUT COMPLETE":GOTO MENU
9000 GOSUB SCN:? "INPUT SEARCH KEY":INPUT C$:LN=LEN(C$):FOR S=P TO O:C=S:GOSUB CAL2:FOR CD=P TO N
9010 B=(O*(CD-P)+P)+F:E=B+(LN-P):IF CD$(B,E)=C$ THEN ? "------MATCH FOUND IN #";S;"-----":? CD$(B,B+29)
9030 NEXT CD:NEXT S:? "SEARCH COMPLETE":GOTO MENU
10000 TRAP 10000:? "TITLE 1..LIST 2..FILL 3..MODIFY 4":? "DELETE 5..VIEW 6..SAVE DATA 7"
10005 ? "INPUT DATA 8..SEARCH DATA 9"
10010 INPUT CH:IF CH>0 AND CH<10 THEN GOTO CH*1000
10020 GOSUB SCN:GOTO MENU