Color Codes for Resistors quiz (RESISTOR.BAS)
Color Codes for Resistors quiz
Description
Color Codes for Resistors quiz
From the Antic disk of August 1983 (Vol. 2 No. 5).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 4.1 KB
- Dialect
- Atari BASIC
- Lines
- 141
- Variables
BAND(,A$,CC$,I,X,BAND1,BAND2,BAND3,BAND4,COL1,COL2,COL3,COL4,PMBASE,RAMTOP,A,PM,VPOS,KEE,OHMS
BASIC listing (141 lines)
10 REM * RESISTOR VALUE MODEL
20 REM * BY Charles D. Moore
30 REM * use the '1 2 3 4' keys to show
40 REM * different colors for each band
50 DIM BAND(12),A$(37),CC$(108)
60 REM * LOAD BAND COLORS IN TO ARRAY
70 FOR I=0 TO 11:READ X:BAND(I)=X:NEXT I
80 REM SET INITIAL BAND COLORS
90 REM * OPEN THE KEYBOARD FOR INPUT
100 BAND1=0:BAND2=0:BAND3=0:BAND4=10
110 OPEN #1,4,0,"K:"
120 REM DEFINE COLOR REGISTERS
130 COL1=704
140 COL2=705
150 COL3=706
160 COL4=707
170 REM * BUILD STRING WITH COLORS
180 GOSUB 1280
190 REM * DISABLE THE CURSOR
200 POKE 752,1
210 GRAPHICS 5
220 REM * DRAW THE RESISTOR
230 GOSUB 1080
240 PMBASE=54279:RAMTOP=106
250 REM * ESTABLISH P/M AREA
260 A=PEEK(RAMTOP)-16:POKE PMBASE,A:PM=256*A
270 REM * SET P/M TO 2 LINE RESOLUTION
280 POKE 559,46:POKE 53277,3
290 REM * SET P/M FIELD PRIORITY
300 POKE 623,1
310 REM * CLEAR P/M AREA
320 FOR I=PM+512 TO PM+1024:POKE I,0:NEXT I
330 REM SET PLAYER SIZES
340 FOR I=0 TO 3:POKE 53256+I,0:NEXT I
350 GOSUB 1020
360 REM SET UP PLAYERS
370 VPOS=54
380 FOR I=VPOS TO VPOS+15:READ A
390 POKE PM+512+I,A
400 POKE PM+640+I,A
410 POKE PM+768+I,A
420 POKE PM+896+I,A
430 NEXT I
440 REM SET HORIZONTAL POSITIONS
450 POKE 53248,93
460 POKE 53249,103
470 POKE 53250,113
480 POKE 53251,123
490 GOTO 620:REM * SEE NOTE ON COLORS
500 REM MAIN PROGRAM STARTS HERE
510 GOSUB 1020
520 GET #1,KEE
530 REM * RING BUZZER ON WRONG KEY
540 IF KEE<49 OR KEE>52 THEN ? CHR$(253):GOTO 520
550 KEE=KEE-48
560 ON KEE GOTO 580,590,600,610
570 REM * INCREMENT BAND COLOR
580 BAND1=BAND1+1:GOTO 620
590 BAND2=BAND2+1:GOTO 620
600 BAND3=BAND3+1:GOTO 620
610 BAND4=BAND4+1
620 GOSUB 930
630 REM * CLEAR WINDOW
640 ? CHR$(125);:POKE 752,1
650 REM * ASSIGN COLOR NAMES TO WINDOW
660 A$(1)=" ":A$(37)=" ":A$(2)=A$
670 A$(1,9)=CC$(BAND1*9+1,BAND1*9+9)
680 A$(10,18)=CC$(BAND2*9+1,BAND2*9+9)
690 A$(19,27)=CC$(BAND3*9+1,BAND3*9+9)
700 A$(28,36)=CC$(BAND4*9+1,BAND4*9+9)
710 ? A$
720 REM READ BANDS
730 SOUND 0,BAND1+BAND2+BAND3+BAND4,10,14
740 POKE 752,1
750 ? :? "Resistor value is ";
760 OHMS=(BAND1*10)+BAND2
770 IF BAND3>9 THEN 830
780 OHMS=OHMS*(10^BAND3)
790 OHMS=INT(OHMS+0.5)
800 IF OHMS<1000 THEN ? OHMS;" ohms":GOTO 860
810 IF OHMS<1000000 THEN OHMS=OHMS/1000:? OHMS;" K ohms":GOTO 860
820 OHMS=INT(OHMS/1000000):? OHMS;" Meg ohms":GOTO 860
830 IF BAND3=10 THEN OHMS=OHMS*0.1:GOTO 850
840 OHMS=OHMS*0.01
850 ? OHMS;" ohms"
860 ? "Tolerance is";
870 IF BAND4=10 THEN ? " 5%.";:GOTO 900
880 ? " 10%.";
890 SOUND 0,(BAND1+BAND2+BAND3+BAND4)*2,10,14
900 SOUND 0,0,0,0
910 GOTO 510
920 REM TEST FOR BAND MAX
930 IF BAND1>9 THEN BAND1=0
940 IF BAND2>9 THEN BAND2=0
950 IF BAND3>11 THEN BAND3=0
960 IF BAND4>11 THEN BAND4=10
970 IF BAND4<10 THEN BAND4=10
980 REM * DISABLE BREAK KEY
990 POKE 16,112:POKE 53774,112
1000 RETURN
1010 REM SET BAND COLORS
1020 POKE COL1,BAND(BAND1)
1030 POKE COL2,BAND(BAND2)
1040 POKE COL3,BAND(BAND3)
1050 POKE COL4,BAND(BAND4)
1060 RETURN
1070 REM DRAW RESISTOR
1080 SETCOLOR 1,3,2
1090 SETCOLOR 4,9,14
1100 SETCOLOR 2,9,14
1110 SETCOLOR 0,0,12
1120 COLOR 2
1130 FOR I=1 TO 8:READ A
1140 PLOT 20-A,18+I:DRAWTO 60-A,18+I
1150 NEXT I
1160 COLOR 1
1170 FOR I=1 TO 8:READ A
1180 PLOT 17-A,18+I:DRAWTO 17+A,18+I
1190 NEXT I
1200 COLOR 2:PLOT 17,22:PLOT 17,23
1210 COLOR 1:PLOT 0,22:DRAWTO 16,22
1220 PLOT 0,23:DRAWTO 16,23
1230 PLOT 61,22:DRAWTO 79,22
1240 PLOT 61,23:DRAWTO 79,23
1250 RETURN
1260 REM DEFINE COLOR STRING
1270 REM * CLEAR STRING FOR COLOR NAME
1280 CC$(1)=" ":CC$(108)=" ":CC$(2)=CC$
1290 FOR I=0 TO 11
1300 READ A$
1310 CC$(I*9+1,I*9+LEN(A$)+1)=A$
1320 NEXT I
1330 RETURN
1340 DATA 0,64,71,41,254,231,147,117,7,15,31,11
1350 REM * COLORS FOR WINDOW
1360 DATA BLACK,BROWN,RED,ORANGE,YELLOW,GREEN
1370 DATA BLUE,VIOLET,GRAY,WHITE,GOLD,SILVER
1380 DATA 2,1,0,0,0,0,1,2
1390 DATA 0,1,2,2,2,2,1,0
1400 REM * PLAYER DATA
1410 DATA 252,126,126,126,63,63,63,63,63,63,63,63,126,126,126,252
