Micropainter Picture Utility (PICUTIL.BAS)
Micropainter Picture Utility
Description
Micropainter Picture Utility
From the Antic disk of August 1983 (Vol. 2 No. 5).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 9.8 KB
- Dialect
- Atari BASIC
- Lines
- 194
- Variables
Z,C,C2,C3,C4,C5,C6,C20,C40,PIC,ZAP,CONS,B,I,CX(,SDMCTL,CROP,TXT$,TEXTP,SM,VPOS,HT,COLR,J,CHAR,CHARFLAG,CHARPOS,CHARSET,SCLOC,DUMMY,PROG$,IO,ERR,FILE$,OUTFLAG,IOCB,BUF,OUTFILE$,ANOTHER,ANS$,MOVEFLAG,OFFSET,MOVEN$,MOVEP$,HOFF,VCOR$,K,CX,LX,BYTE,ITEM$,EDGE$,LIM,HBORD$,INFILE$,BLANK,VOFF,RSFLAG,SCREEN,DL,COLREG
BASIC listing (194 lines)
19 REM : ****************************
29 REM : * PICUTE by W. W. Hough *
39 REM : * for ANTIC Magazine 8/83 *
49 REM : ****************************
100 Z=0:C=1:C2=C+C:C3=C2+C:C4=C2+C2:C5=C+C4:C6=C+C5:C20=C4*C5:C40=C20+C20:PIC=120:ZAP=110:CONS=53279:GOTO 1110
109 REM : Typo announcement (ZAP)
110 POKE 712,68:SOUND Z,136,12,14:FOR B=C TO 60:NEXT B:SOUND Z,Z,Z,Z:POKE 712,Z:RETURN
119 REM : Display picture (PIC)
120 FOR I=C2 TO C4:POKE 706+I,CX(I):NEXT I:POKE 712,CX(C)
130 POKE 560,14:POKE 561,C6:POKE 87,7:POKE 559,SDMCTL
140 IF CROP<>Z THEN RETURN
149 REM : Character transfer
150 POP :IF TXT$="" THEN 240
160 TEXTP=SM+C40*VPOS:POKE 1760,HT:POKE 1761,COLR
170 FOR J=C TO LEN(TXT$)
180 CHAR=ASC(TXT$(J,J)):IF CHAR=32 THEN NEXT J
190 CHARFLAG=C:IF CHAR>127 THEN CHAR=CHAR-128:CHARFLAG=Z
200 IF CHAR<32 THEN CHAR=CHAR+64:GOTO 220
210 IF CHAR>31 AND CHAR<96 THEN CHAR=CHAR-32
220 CHARPOS=CHARSET+8*CHAR:SCLOC=TEXTP+C2*(J-C):POKE 1762,CHARFLAG:DUMMY=USR(ADR(PROG$),CHARPOS,SCLOC)
230 NEXT J:TXT$=""
239 REM : Select path from picture
240 POKE CONS,7:SOUND Z,121,10,10:FOR I=C TO 100:NEXT I:SOUND Z,Z,Z,Z
250 IF PEEK(CONS)=C3 THEN 1140
260 IF PEEK(CONS)=C6 THEN IO=8:GOTO 460
270 IF PEEK(CONS)=C5 THEN 510
280 GOTO 250
289 REM : I/O Routines and traps
290 POP :GRAPHICS Z:POKE 559,SDMCTL:GOSUB ZAP:POKE 709,12:TRAP 290
300 IF IO=C4 THEN ? :? "No such picture on disk--DIRECTORY:":? :GOSUB 380:? :? "Press OPTION":GOTO 240
310 IF ERR=162 OR PEEK(195)=162 OR PEEK(195)=139 THEN ? :? "NO ROOM ON DISK":? :? :GOTO 350
320 FILE$="D:WWXXYYZZ.PIC":OUTFLAG=C3:GOTO 410
330 ? :? "An error was encountered on output.":? "I wrote your picture in a file"
340 ? "called 'WWXXYYZZ.PIC'.":? :?
350 GOSUB 380:OUTFLAG=Z:ERR=Z:? :? "Press START"
360 IF PEEK(CONS)=C6 THEN GOTO PIC
370 GOTO 360
380 CLOSE #C:OPEN #C,C6,Z,"D:*.*":TRAP 400
390 INPUT #C,TXT$:? TXT$:GOTO 390
400 CLOSE #C:TXT$="":RETURN
410 CLOSE #C:TRAP 290:OPEN #C,IO,Z,FILE$
420 POKE IOCB+C2,IO+C3:POKE IOCB+C5,INT(BUF/256):POKE IOCB+C4,BUF-256*PEEK(IOCB+C5):POKE IOCB+8,C4:POKE IOCB+9,30
430 DUMMY=USR(1536):ERR=PEEK(705):IF ERR=162 THEN 290
440 IF OUTFLAG=C3 THEN 330
450 CLOSE #C:RETURN
460 GRAPHICS Z:? CHR$(125):POKE 709,12:POKE 702,64:TRAP 460
470 FOR I=C TO C4:POKE SM+7679+I,CX(I):NEXT I
480 ? :? "Enter name of the OUTPUT picture file":FILE$="":INPUT FILE$:OUTFILE$="D:":OUTFILE$(C3)=FILE$
490 IF FILE$="" THEN GOSUB ZAP:GOTO 480
500 FILE$=OUTFILE$:BUF=SM:POKE 559,Z:GOSUB 410:GOTO PIC
509 REM : Pick your change
510 ANOTHER=C3:GRAPHICS Z:POKE 709,12:? :? :? "Do you want to:":? :? " Add ";CHR$(212);"ext":? :? " ";
520 ? CHR$(205);"ove Picture":? :? " Add ";
530 ? CHR$(194);"orders (crop)":? :? " Change ";CHR$(195);"olors":? :? :? "Type T, M, B, or C (or RETURN)"
540 INPUT ANS$:IF ANS$="T" THEN GOSUB 1000:GOTO PIC
550 IF ANS$="" THEN GOTO PIC
560 IF ANS$="B" THEN 790
570 IF ANS$="M" THEN GOSUB 600:GOTO PIC
580 IF ANS$="C" THEN GOSUB 660:GOTO PIC
590 GOSUB ZAP:GOTO 540
599 REM : Internal move
600 MOVEFLAG=C3:? CHR$(125):? :GOSUB 1310:MOVEFLAG=Z
610 IF OFFSET<Z THEN DUMMY=USR(ADR(MOVEN$),SM-7680-OFFSET,SM-7680,23060+OFFSET)
620 IF OFFSET>Z THEN DUMMY=USR(ADR(MOVEP$),SM+15360-OFFSET,SM+15360,23040-OFFSET)
629 REM : Vertical correction
630 IF HOFF=Z THEN RETURN
640 IF HOFF<Z THEN HOFF=C40+HOFF
650 DUMMY=USR(ADR(VCOR$),HOFF,SM+INT(OFFSET/C40)*C40):RETURN
659 REM : Change colors
660 ? CHR$(125):? :? "Which of the four colors do you want":? "to change? Enter 1-4 or ";CHR$(193);"LL ";
670 INPUT ANS$:IF ANS$="A" THEN J=C:K=C4:GOTO 700
680 IF ANS$<"1" AND ANS$>"4" THEN GOSUB ZAP:GOTO 670
690 J=VAL(ANS$):K=J
700 FOR I=J TO K:? :? "Enter new color (COLOR ";I;")"
710 TRAP 710:? " Color (0-15) ";:INPUT CX:IF CX<Z OR CX>15 THEN GOSUB ZAP:GOTO 710
720 TRAP 720:? " Luminance (0-14) ";:INPUT LX:IF LX<Z OR LX>14 THEN GOSUB ZAP:GOTO 720
730 CX(I)=16*CX+LX:NEXT I
740 IF J<>K THEN RETURN
750 ? :? "Do you want to change another color ?"
760 INPUT ANS$:IF ANS$="Y" THEN 660
770 IF ANS$="N" THEN RETURN
780 GOSUB ZAP:GOTO 760
789 REM : Crop picture
790 ? CHR$(125):? :? "Enter color of border (1-4 or ";CHR$(205);"IXED)"
800 INPUT ANS$:IF ANS$="M" THEN ? :? "Enter byte for mixed color (1-254)"
810 TRAP 810:IF ANS$="M" THEN INPUT BYTE:IF BYTE<C OR BYTE>254 THEN GOSUB ZAP:GOTO 810
820 IF ANS$="M" THEN 850
830 IF ANS$<"1" OR ANS$>"4" THEN GOSUB ZAP:GOTO 800
840 BYTE=(VAL(ANS$)-1)*85
850 ? :? "Do you want to crop ";CHR$(212);"OP, ";CHR$(194);"OTTOM, ";CHR$(204);"EFT"
860 ? "SIDE, or ";CHR$(210);"IGHT SIDE ";
870 INPUT ANS$:IF ANS$="T" THEN ITEM$="scan lines down":EDGE$="top":LIM=192:GOSUB 920:GOTO 950
880 IF ANS$="B" THEN ITEM$="scan lines up":EDGE$="bottom":LIM=192:GOSUB 920:GOTO 960
890 IF ANS$="L" THEN ITEM$="spaces":EDGE$="left side":LIM=C40:GOSUB 920:GOTO 970
900 IF ANS$="R" THEN ITEM$="spaces":EDGE$="right side":LIM=C40:GOSUB 920:GOTO 980
910 GOSUB ZAP:GOTO 870
920 ? :? "How many ";ITEM$;" from ";EDGE$:? "(0 to ";LIM;") ";
930 TRAP 930:INPUT CROP:IF CROP<Z OR CROP>LIM THEN GOSUB ZAP:GOTO 930
940 GOSUB PIC:RETURN
950 DUMMY=USR(ADR(HBORD$),BYTE,SM,C40*CROP):GOTO 990
960 DUMMY=USR(ADR(HBORD$),BYTE,SM+7680-C40*CROP,C40*CROP):GOTO 990
970 FOR I=SM TO SM+7640 STEP C40:DUMMY=USR(ADR(HBORD$),BYTE,I,CROP):NEXT I:GOTO 990
980 FOR I=SM+C40-CROP TO SM+7680-CROP STEP C40:DUMMY=USR(ADR(HBORD$),BYTE,I,CROP):NEXT I
990 CROP=Z:GOTO 240
999 REM : Input display characters
1000 ? CHR$(125):? :? "ENTER TEXT (maximum of 20 characters, and use initial spaces to offset"
1010 ? "text from left margin):":? :? " <<<20--CHARACTERS>>>"
1020 INPUT TXT$:POKE 694,Z:POKE 702,64:IF TXT$="" THEN RETURN
1030 ? :? "Do you want (1) REGULAR HEIGHT (ala":? "Graphics 1) or (2) DOUBLE HEIGHT":? "(ala Graphics 2) ";
1040 ? "or higher up to 5":? "times regular ?";
1050 TRAP 1050:? " Enter 1 to 5 ";:INPUT HT:IF HT<C OR HT>C5 THEN GOSUB ZAP:GOTO 1050
1060 ? :? "Enter vertical position (from top)":? "where you want top of text (0 to ";192-8*HT;")"
1070 TRAP 1070:INPUT VPOS:IF VPOS<Z OR VPOS>192-8*HT THEN GOSUB ZAP:GOTO 1070
1080 ? :? "What color do you want for your text?"
1090 TRAP 1090:? "Enter 1-4 ";:INPUT COLR:IF COLR<C OR COLR>C4 THEN GOSUB ZAP:GOTO 1090
1100 COLR=COLR-C:RETURN
1109 REM : Initialization
1110 IF PEEK(581)=Z THEN POKE 581,PEEK(106)
1120 DIM TXT$(C20),INFILE$(14),OUTFILE$(14),FILE$(14),ANS$(C),CX(C4),ITEM$(15),EDGE$(10)
1130 CHARSET=224*256:BLANK=C2:POKE 106,PEEK(581)
1140 TXT$="":HOFF=Z:VOFF=Z:HT=Z:OFFSET=Z:COLR=Z:OUTFILE$="":OUTFLAG=Z:ANOTHER=Z
1150 GRAPHICS Z:POKE 709,12:? CHR$(125):? :? " PICUTE by W. W. HOUGH":? :?
1160 ? "A Utility for Creating and Modifying":? "High Resolution MICROPAINTER Screens"
1170 ? :? :? "After your picture is displayed"
1180 ? "and a tone sounds, the program is":? "waiting for your input. Press:"
1190 ? :? " START to save modified picture":? " SELECT to change picture":? " OPTION to start over":?
1200 ? :? "If you would like to see the disk":? "directory now, press SELECT. To go":? "on, press START.";
1210 IF BLANK=C2 THEN ? " To make a blank":? "picture, press OPTION.";
1220 IF PEEK(CONS)=C6 THEN ? CHR$(125):GOTO 1260
1230 IF PEEK(CONS)=C5 THEN ? CHR$(125):GOSUB 380:GOTO 1260
1240 IF PEEK(CONS)=C3 AND BLANK=C2 THEN BLANK=C:GOTO 1390
1250 GOTO 1220
1260 POKE 702,64:? :? :? "Enter name of the INPUT picture file ":FILE$="":INPUT FILE$
1270 INFILE$="D:":INFILE$(C3)=FILE$:IF FILE$="" THEN GOSUB ZAP:GOTO 1260
1279 REM : Input move increments
1280 ? CHR$(125):? :? :? "Do you want to move ";FILE$;" ";:INPUT ANS$:IF ANS$="Y" THEN 1310
1290 IF ANS$="N" THEN 1380
1300 GOSUB ZAP:GOTO 1280
1310 ? :? "Enter horizontal offset (-20 to 20)"
1320 TRAP 1320:INPUT HOFF:IF HOFF<Z-C20 OR HOFF>C20 THEN GOSUB ZAP:GOTO 1320
1330 ? :? "Enter vertical offset (-192 to 192)"
1340 TRAP 1340:INPUT VOFF:IF VOFF<-192 OR VOFF>192 THEN GOSUB ZAP:GOTO 1340
1350 IF HOFF<Z THEN VOFF=VOFF+C
1360 OFFSET=HOFF+C40*VOFF
1369 REM : Exit if not first init.
1370 IF MOVEFLAG=C3 OR ANOTHER=C3 THEN RETURN
1380 IF RSFLAG=C3 THEN 1730
1390 SDMCTL=PEEK(559):IOCB=848
1400 GRAPHICS 24:IF PEEK(704)=Z THEN POKE 704,PEEK(89)-16
1410 SCREEN=PEEK(704):POKE 89,SCREEN:SM=SCREEN*256+PEEK(88):POKE 559,Z
1419 REM : Access to OS I/O
1420 FOR I=Z TO 10:READ B:POKE 1536+I,B:NEXT I:RSFLAG=C3
1430 DATA 104,162,16,32,86,228,152,141,193,2,96
1439 REM : Positive internal moves
1440 DIM MOVEP$(56):FOR I=C TO 56:READ B:MOVEP$(I,I)=CHR$(B):NEXT I
1450 DATA 104,104,133,204,104,133,203,104,133,206,104,133,205,104,133,208,104,133,207,164,207,136,192,255,240
1460 DATA 7,177,203,145,205,24,144,244,166,208,240,18,160,255,198,204,198,206,177,203,145,205,136,192,255
1470 DATA 208,247,202,208,238,96
1479 REM : Negative internal moves
1480 DIM MOVEN$(54):FOR I=C TO 54:READ B:MOVEN$(I,I)=CHR$(B):NEXT I
1490 DATA 104,104,133,204,104,133,203,104,133,206,104,133,205,104,133,208,104,133,207,166,208,240,16,160,0
1500 DATA 177,203,145,205,200,208,249,230,204,230,206,202,208,242,160,255,200,196,207,240,7,177,203,145,205
1510 DATA 24,144,244,96
1519 REM : Horizontal borders
1520 DIM HBORD$(47):FOR I=C TO 47:READ B:HBORD$(I,I)=CHR$(B):NEXT I
1530 DATA 104,104,104,133,203,104,133,205,104,133,204,104,133,207,104,133,206,165,203,166,207,240,12,160,0
1540 DATA 145,204,136,208,251,230,205,202,208,246,164,206,136,192,255,240,4,145,204,208,247,96
1549 REM : Transfer & write character
1550 DIM PROG$(189):FOR I=C TO 189:READ B:PROG$(I,I)=CHR$(B):NEXT I
1560 DATA 104,104,133,205,104,133,204,104,133,207,104,133,206,169,0,141,230,6,160,4,173,226,6,208,14
1570 DATA 24,13,225,6,136,240,4,10,10,144,246,141,231,6,173,224,6,141,233,6,160,4,169,0,153
1580 DATA 233,6,136,208,250,162,0,172,230,6,177,204,141,232,6,160,0,30,234,6,30,234,6,30,236
1590 DATA 6,30,236,6,24,14,232,6,144,11,173,225,6,29,236,6,157,236,6,176,8,169,3,29,234
1600 DATA 6,157,234,6,200,192,4,208,214,232,224,2,208,207,173,226,6,208,50,160,0,173,231,6,57
1610 DATA 234,6,145,206,200,192,2,208,243,24,144,16,206,233,6,208,159,238,230,6,169,8,205,230,6
1620 DATA 208,143,96,165,206,105,40,133,206,144,232,165,207,105,0,133,207,144,224,160,0,177,206,57,234
1630 DATA 6,25,236,6,145,206,200,192,2,208,241,24,144,220
1639 REM : Vertical correction
1640 DIM VCOR$(55):FOR I=C TO 55:READ B:VCOR$(I,I)=CHR$(B):NEXT I
1650 DATA 104,104,104,133,204,104,133,208,133,206,104,133,207,162,193,165,207,24,105,40,133,205,144,2,230
1660 DATA 206,160,0,177,205,145,207,200,196,204,208,247,202,240,14,165,207,24,105,40,133,207,144,222,230
1670 DATA 208,24,144,217,96
1680 DL=PEEK(560)+256*PEEK(561):POKE DL+C3,78:POKE DL+C5,SCREEN:FOR I=DL+C6 TO DL+201
1690 IF PEEK(I)=15 THEN POKE I,14
1700 IF PEEK(I)=79 THEN POKE I,78:POKE I+C2,PEEK(I+C2)-16:I=I+C2
1710 NEXT I:DUMMY=USR(ADR(MOVEN$),DL,1550,200):POKE 1750,14:POKE 1751,C6
1720 DUMMY=USR(ADR(HBORD$),Z,DL,202):POKE 106,SCREEN-33
1729 REM : If blank, get colors
1730 IF BLANK=C THEN BLANK=Z:J=C:K=C4:GRAPHICS Z:POKE 709,12:? :GOSUB 700:GOTO PIC
1739 REM : Get input file,read colors
1740 BLANK=Z:BUF=SM+OFFSET:COLREG=BUF+7680:FILE$=INFILE$:IO=C4:GOSUB 410
1750 FOR I=C TO C4:CX(I)=PEEK(COLREG+I-C):NEXT I
1760 FOR I=Z TO C3:POKE COLREG+I,Z:NEXT I
1770 GOSUB 630:GOTO PIC
