Keystroke Artist graphics program (KEYSTROK.BAS)

Keystroke Artist graphics program

Description

Keystroke Artist graphics program

From the Antic disk of August 1983 (Vol. 2 No. 5).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 13.9 KB

Dialect
Atari BASIC
Lines
258
Variables
IND, C, X, Y, TR, FLG, XDIR(, JOY, YDIR(, Z, CAL$, IRPT$, KEY$, PLACE$, NAME$, MIRROR$, ERASE$, ARRAY(, INX(, INY(, CIO$, MODE$, CAL, DL, VLU, START, TENCNGE, NINECNGE, CTIA, GTIA, RETEN, NINEAGN, I, J, K, D, KEY, MRK, SA, SB, SC, X1, Y1, X2, Y2, CMD, STADR, BYTES, IOCB, NTE, VER, HOR, T, U, VOL, LOC, CURCOL, ERR, ODD, IOCBX, ICCOM, ICSTA, ICBAL, ICBAH, ICBLL, ICBLH
BASIC listing (258 lines)
10 REM CREATE -- 1/27/83
20 GOTO 140
30 IF PEEK(20)>5 THEN 50
40 RETURN
50 IF IND=1 THEN IND=0:COLOR C:PLOT X,Y:GOTO 70
60 IND=1:COLOR 0:PLOT X,Y
70 POKE 20,0:RETURN
80 IF TR THEN COLOR C:IND=0:FLG=1
90 RETURN
100 X=X+XDIR(JOY):Y=Y+YDIR(JOY):IF X<0 OR X>79 THEN X=X+(X<0)-(X>79)
110 IF Y<3 OR Y>138 THEN Y=Y+(Y<3)-(Y>138)
120 IF  NOT TR THEN IF XDIR(JOY) OR YDIR(JOY) THEN LOCATE X,Y,Z
130 RETURN
140 POKE 709,15:TRAP 960
150 CLR :DIM CAL$(22),IRPT$(231),XDIR(15),YDIR(15),KEY$(65),PLACE$(1),NAME$(20),MIRROR$(127),ERASE$(71),ARRAY(4)
160 DIM INX(9),INY(9),CIO$(7),MODE$(11)
170 KEY$="LJ***K**O*PU#I**V*C**BXZ4*36*521**.N*M**R*EY*TWQ9*07$8**FHD**GSA$"
180 GOSUB 4000
190 CAL=ADR(CAL$)
200 MODE$="DRAW MODE":TR=0
210 GRAPHICS 9:POKE 559,0:DL=PEEK(560)+256*PEEK(561):VLU=PEEK(DL+4)+PEEK(DL+5)*256
220 START=ADR(IRPT$):TENCNGE=START+17:NINECNGE=TENCNGE+28:CTIA=NINECNGE+47:GTIA=CTIA+36
230 RETEN=GTIA+47:NINEAGN=RETEN+28
240 ARRAY(1)=VLU+760+80:ARRAY(2)=ARRAY(1)+20:ARRAY(3)=ARRAY(1)+2720:ARRAY(4)=ARRAY(3)+20
250 FOR I=1 TO 9:READ J,K:INX(I)=J:INY(I)=K:NEXT I
260 DATA 0,3,40,3,79,3,0,71,40,71,79,71,0,138,40,138,79,138
270 D=USR(CAL,1769,1770,TENCNGE)
280 D=USR(CAL,1771,1772,NINECNGE)
290 D=USR(CAL,1773,1774,CTIA)
300 D=USR(CAL,1775,1776,GTIA)
310 D=USR(CAL,1777,1778,RETEN)
320 D=USR(CAL,1779,1780,NINEAGN)
330 D=USR(CAL,512,513,TENCNGE):REM INITIALIZE INTERRUPT POINTER
340 D=USR(CAL,DL+106,DL+107,VLU+3760)
350 POKE DL+99,15:POKE DL+100,15:POKE DL+101,15:REM CLEAR OUT OLD LMS
360 POKE DL+3,15+64+128
370 POKE DL+21,15+128
380 POKE DL+23,0:POKE DL+24,0+128
390 FOR I=25 TO 28:POKE DL+I,6:NEXT I
400 POKE DL+29,0+128:POKE DL+30,0
410 POKE DL+31,15+128
420 POKE DL+105,15+64
430 POKE DL+169,15+128
440 POKE DL+171,65:POKE DL+172,PEEK(560):POKE DL+173,PEEK(561):POKE 559,34
450 J=0:FOR I=0 TO 79:J=J+1:IF J>15 THEN J=0
460 COLOR J:PLOT I,0:PLOT I,17:PLOT I,20:PLOT I,157:NEXT I
470 D=USR(ADR(MIRROR$),1,0,68,ARRAY(3),ARRAY(4)):D=USR(ADR(MIRROR$),0,1,68,ARRAY(4),ARRAY(2)+2680)
480 COLOR 1:PLOT 40,20:PLOT 39,20:PLOT 40,157:PLOT 39,157
490 POKE 1764,120:POKE 1765,8:POKE 1766,103:POKE 1768,224
500 D=USR(START)
510 GOSUB 1300
520 C=-1:FOR I=1 TO 16:C=C+1:IF C>8 THEN C=0
530 COLOR C:PLOT 0,I:DRAWTO 4,I:NEXT I
540 C=9:J=-3
550 J=J+8:C=C-1:IF C=-1 THEN 570
560 K=J+7:FOR I=1 TO 16:COLOR C:PLOT J,I:DRAWTO K,I:NEXT I:GOTO 550
570 D=USR(CAL,88,89,VLU+720)
580 POSITION 0,0:POKE 87,1:? #6;"  8 7 6 5 4 3 2 1 B"
590 FOR I=1 TO 15:READ D:XDIR(I)=D:READ D:YDIR(I)=D:NEXT I
600 DATA 0,0,0,0,0,0,0,0,1,1,1,-1,1,0,0,0,-1,1,-1,-1,-1,0,0,0,0,1,0,-1,0,0
610 POSITION 2,2:C=5:X=40:Y=71:GOSUB 970:COLOR 3:PLOT 0,70:PLOT 0,71:PLOT 79,70:PLOT 79,71
620 IND=0
630 GOSUB 30:KEY=PEEK(764):IF KEY<>255 THEN COLOR 0:PLOT X,Y:GOSUB 750:GOSUB 930:GOSUB 970
640 IF MRK THEN MRK=0:LOCATE X,Y,Z
650 JOY=STICK(0)
660 IF STRIG(0)=0 THEN IND=1:COLOR 0:GOSUB 80:GOSUB 700:GOTO 630
670 GOSUB 680:GOTO 630
680 FLG=0:IF JOY<>15 THEN COLOR C
690 IF TR THEN IF XDIR(JOY) OR YDIR(JOY) THEN COLOR Z:FLG=1
700 PLOT X,Y
710 GOSUB 100
720 IF FLG THEN LOCATE X,Y,Z
730 RETURN
740 GOTO 630
750 POKE 87,1:GOSUB 930:IF KEY>63 THEN 920
760 GOSUB 940
770 POKE 764,255:IF TR THEN GOSUB 2440:IF PLACE$<>"┤" THEN 750
780 IF PLACE$="C" THEN SA=29:SB=35:SC=60:GOSUB 1630:GOTO 1060
790 IF PLACE$="S" THEN SA=29:SB=40:SC=60:GOSUB 1630:GOTO 1120
800 IF PLACE$="M" THEN SA=29:SB=47:SC=60:GOSUB 1630:GOTO 1470
810 REM Routine to load main menu will be added here.
820 IF PLACE$="D" THEN SA=40:SB=47:SC=60:GOSUB 1630:GOTO 1550
830 IF PLACE$="I" THEN SA=35:SB=53:SC=60:GOSUB 1630:GOTO 2290
840 IF PLACE$="L" THEN SA=35:SB=40:SC=60:GOSUB 1630:GOSUB 2460:GOTO 1660
850 IF PLACE$="F" THEN SA=29:SB=40:SC=47:GOSUB 1630:GOTO 2210
860 IF PLACE$="N" THEN SA=40:SB=60:SC=81:GOSUB 1630:GOTO 1780
870 IF PLACE$="Z" THEN SA=29:SB=35:SC=45:GOSUB 1630:GOTO 2140
880 IF PLACE$="R" THEN SA=35:SB=45:SC=60:GOSUB 1630:GOTO 1880
890 IF PLACE$="E" THEN SA=35:SB=53:SC=60:GOSUB 1630:GOTO 1960
900 IF PLACE$="┤" THEN PLACE$=" ":RETURN
910 IF PLACE$="T" THEN 2440
920 GOSUB 980:RETURN
930 TRAP 40000:POSITION 2,2:? #6;"                  ":POSITION 2,2:RETURN
940 IF KEY>64 THEN PLACE$="*":RETURN
950 PLACE$=KEY$(KEY+1,KEY+1):RETURN
960 GOTO 140
970 ? #6;MODE$:POKE 87,10:POKE 764,255:POKE 16,64:POKE 53774,64:RETURN
980 ? #6;"INVALID ENTRY":GOSUB 1590:RETURN
990 IF PEEK(764)=255 THEN 990
1000 RETURN
1010 FOR K=1 TO 100:NEXT K:RETURN
1020 COLOR C:PLOT X,Y:IF X1>-1 THEN PLOT X1,Y1
1030 FOR I=1 TO 3:NEXT I:COLOR 0:PLOT X,Y:IF X1>1 THEN PLOT X1,Y1
1040 IF X2>-1 THEN COLOR C:PLOT X1,Y1:DRAWTO X2,Y2
1050 RETURN
1060 GOSUB 930:? #6;"CHANGE COLOR TO:";:POKE 764,255:GOSUB 990:KEY=PEEK(764)
1070 GOSUB 940:GOSUB 1320:IF ASC(PLACE$)<49 OR ASC(PLACE$)>56 THEN GOSUB 1730:GOSUB 930:GOSUB 980:GOTO 1060
1080 GOSUB 1730:C=VAL(PLACE$):RETURN
1090 COLOR C:PLOT X,Y:FOR I=1 TO 8:NEXT I:COLOR 0:PLOT X,Y:RETURN
1100 GOSUB 1090:IF PEEK(764)=255 THEN FOR I=1 TO 6:NEXT I:GOTO 1100
1110 RETURN
1120 POKE 87,10:COLOR C:PLOT X,Y:POKE 87,2:GOSUB 1580:GOSUB 1320
1130 IF PLACE$="D" THEN 1170
1140 IF PLACE$<>"T" THEN GOSUB 1730:GOSUB 930:GOSUB 980:GOTO 1120
1150 GOSUB 1730:GOSUB 930:TRAP 1160:? #6;"SAVING ON TAPE":POKE 764,255:LPRINT
1160 TRAP 1900:NAME$="C:":POKE 54286,64:OPEN #1,8,128,NAME$:GOTO 1190
1170 GOSUB 1730:GOSUB 1370
1180 POKE 54286,64:GOSUB 930:? #6;"SAVING ON DISK":GOSUB 1010:TRAP 1900:OPEN #1,8,0,NAME$
1190 CMD=11:STADR=704:BYTES=9:IOCB=1:GOSUB 2330:STADR=VLU+840:BYTES=5440:GOSUB 2330
1200 CLOSE #1:GOSUB 1890
1210 RETURN
1220 GOSUB 930:? #6;"1ST QUADRANT:";:POKE 764,255:GOSUB 990:KEY=PEEK(764):GOSUB 940:GOSUB 1340:TRAP 1280
1230 I=VAL(PLACE$):IF I>4 OR I<1 THEN GOSUB 1460:GOTO 1220
1240 GOSUB 1730
1250 GOSUB 930:? #6;"2ND QUADRANT:";:POKE 764,255:GOSUB 990:KEY=PEEK(764):GOSUB 940:GOSUB 1340:TRAP 1290
1260 J=VAL(PLACE$):IF J<1 OR J>4 THEN GOSUB 1460:GOTO 1250
1270 GOSUB 1730:RETURN
1280 GOSUB 1460:GOTO 1220
1290 GOSUB 1460:GOTO 1250
1300 POKE 705,68:POKE 706,246:POKE 707,218:POKE 708,182:POKE 709,134:POKE 710,100:POKE 711,14:POKE 712,224
1310 POKE 704,0:RETURN
1320 IF PLACE$="X" THEN GOSUB 1730:GOSUB 930:? #6;"EXIT":GOSUB 1650:POP
1330 RETURN
1340 IF PLACE$="X" THEN GOSUB 1730:GOSUB 930:? #6;"EXIT":GOSUB 1650:POP :POP
1350 RETURN
1360 PLOT PEEK(709)-21,7
1370 NAME$="D:        ":J=2:GOSUB 930:POKE 764,255:? #6;"FILENAME:--------"
1380 POSITION 11,2:FOR I=1 TO 9:REM INPUT LOOP
1390 POKE 764,255:GOSUB 990:KEY=PEEK(764):SOUND 0,10,0,7:GOSUB 940
1400 J=J+1:SOUND 0,0,0,0:IF PLACE$="#" THEN 1450
1410 IF PLACE$="$" OR J>10 THEN 1370
1420 IF PLACE$="*" THEN J=J-1:GOTO 1390
1430 NAME$(J,J)=PLACE$
1440 ? #6;PLACE$;:NEXT I
1450 RETURN
1460 NTE=200:GOSUB 1730:GOSUB 930:? #6;"1-4 ONLY":GOSUB 1590:RETURN
1470 GOSUB 1220
1480 VER=0:HOR=0:IF I<3 AND J>2 THEN VER=1
1490 IF I>2 AND J<3 THEN VER=1
1500 IF (I=2 OR I=4) AND (J=1 OR J=3) THEN HOR=1
1510 IF (I=1 OR I=3) AND (J=2 OR J=4) THEN HOR=1
1520 I=ARRAY(I):J=ARRAY(J):IF VER=1 THEN J=J+2680
1530 D=USR(ADR(MIRROR$),HOR,VER,67,I,J)
1540 RETURN
1550 GOSUB 1220
1560 D=USR(ADR(MIRROR$),0,0,67,ARRAY(I),ARRAY(J))
1570 RETURN
1580 GOSUB 930:POKE 764,255:? #6;"DISK OR TAPE:";:GOSUB 990:KEY=PEEK(764):GOSUB 940:GOSUB 1340:RETURN
1590 GOSUB 1620
1600 FOR T=1 TO 40:SOUND 0,16,10,14:SOUND 0,0,0,0:FOR U=1 TO 1:NEXT U:NEXT T:FOR T=1 TO 20:NEXT T:RETURN
1610 FOR T=14 TO 0 STEP -2:SOUND 0,81,10,T:NEXT T:RETURN
1620 FOR T=14 TO 0 STEP -2:SOUND 0,200,10,T:NEXT T:RETURN
1630 SOUND 0,SA,10,8:GOSUB 1640:SOUND 0,SB,10,8:GOSUB 1640:SOUND 0,SC,10,8:GOSUB 1640:SOUND 0,0,0,0:RETURN
1640 FOR K=1 TO 10:NEXT K:RETURN
1650 FOR U=1 TO 8:SOUND 0,29,10,8:SOUND 1,35,10,8:FOR T=1 TO 5:NEXT T:SOUND 0,0,0,0:SOUND 1,0,0,0:NEXT U:RETURN
1660 GOSUB 1580:IF PLACE$="D" THEN 1700
1670 IF PLACE$<>"T" THEN GOSUB 1730:GOSUB 930:GOSUB 980:GOTO 1660
1680 TRAP 1690:LPRINT
1690 TRAP 40000:GOSUB 930:TRAP 1740:? #6;"LOADING FROM TAPE":POKE 764,255:POKE 54286,64:OPEN #1,4,128,"C:":GOTO 1710
1700 GOSUB 1730:GOSUB 1370:POKE 54286,64:GOSUB 930:TRAP 1740:? #6;"LOADING FROM DISK":GOSUB 1010:OPEN #1,4,0,NAME$
1710 CMD=7:STADR=704:BYTES=9:IOCB=1:GOSUB 2330:STADR=VLU+840:BYTES=5440:GOSUB 2330
1720 MRK=1:CLOSE #1:GOSUB 1890:RETURN
1730 ? #6;PLACE$:GOSUB 1610:GOSUB 1010:RETURN
1740 CLOSE #1:GOSUB 1890:GOSUB 930:? #6;"INPUT ERROR":GOSUB 1010:GOSUB 930:? #6;"TRY AGAIN?";:POKE 764,255
1750 GOSUB 990:KEY=PEEK(764)
1760 GOSUB 940:GOSUB 1730:GOSUB 1320:IF PLACE$="Y" THEN GOSUB 930:GOTO 1660
1770 RETURN
1780 VOL=2:GOSUB 930:? #6;"NEW COLOR FOR:";:POKE 764,255:GOSUB 990:KEY=PEEK(764):GOSUB 940:GOSUB 1320
1790 GOSUB 1730:IF ASC(PLACE$)<48 OR ASC(PLACE$)>56 THEN GOSUB 930:GOSUB 980:GOTO 1780
1800 LOC=VAL(PLACE$)+704:CURCOL=PEEK(LOC):GOSUB 930:? #6;"CHANGE COLOR"
1810 I=PEEK(764):J=STICK(0):IF I=14 OR I=142 OR J=14 THEN CURCOL=CURCOL+2:POKE 764,255:SOUND 0,10,0,7
1820 IF I=15 OR I=143 OR J=13 THEN CURCOL=CURCOL-2:POKE 764,255:SOUND 0,10,0,7
1830 IF I=12 OR STRIG(0)=0 THEN 1870
1840 IF CURCOL>255 THEN CURCOL=0
1850 IF CURCOL<0 THEN CURCOL=255
1860 SOUND 0,0,0,0:POKE LOC,CURCOL:GOTO 1810
1870 GOSUB 1610:RETURN
1880 GOSUB 930:? #6;"RESTORE COLORS":GOSUB 1010:GOSUB 1300:RETURN
1890 D=USR(CAL,512,513,TENCNGE):D=USR(START):RETURN
1900 TRAP 40000:TRAP 1950
1910 CLOSE #1:GOSUB 1890:GOSUB 930:ERR=PEEK(195):IF ERR=162 THEN ? #6;"DISK FULL":GOTO 1940
1920 IF ERR=167 THEN ? #6;"FILE LOCKED":GOTO 1940
1930 ? #6;"OUTPUT ERROR"
1940 GOSUB 1010:GOSUB 930:GOSUB 1010:RETURN
1950 TRAP 40000:TRAP 1910:LPRINT :GOTO 1910
1960 GOSUB 930:? #6;"ALL OR PARTIAL:";:POKE 764,255:GOSUB 990:KEY=PEEK(764):GOSUB 940:GOSUB 1320
1970 GOSUB 1730:IF PLACE$="P" THEN 2000
1980 IF PLACE$<>"A" THEN GOSUB 930:GOSUB 980:GOTO 1960
1990 D=USR(ADR(ERASE$),40,136,0,VLU+840):GOTO 2100
2000 GOSUB 930:? #6;"SMALL OR LARGE:";:POKE 764,255:POKE 87,10:GOSUB 1100:KEY=PEEK(764):GOSUB 940
2010 POKE 87,1:POSITION 17,2:GOSUB 1730:GOSUB 1320
2020 IF PLACE$="S" THEN HOR=5:VER=10:GOTO 2050
2030 IF PLACE$<>"L" THEN GOSUB 930:GOSUB 980:GOTO 2000
2040 HOR=10:VER=20
2050 I=80-X:J=139-Y:IF J<VER THEN VER=J
2060 ODD=0:IF INT(X/2)<>X/2 THEN ODD=1
2070 IF I/2<HOR THEN HOR=INT(I/2):IF INT(I/2)<>I/2 THEN COLOR 0:POKE 87,10:PLOT 79,Y:DRAWTO 79,Y+VER-1:POKE 87,1
2080 IF X>76 THEN POKE 87,10:COLOR 0:FOR T=X TO 79:PLOT T,Y:DRAWTO T,Y+VER:NEXT T:POKE 87,2:GOTO 2100
2090 D=USR(ADR(ERASE$),HOR,VER,ODD,VLU+840+((Y-3)*40)+INT(X/2))
2100 RETURN
2110 GOSUB 930:? #6;"PRESS Y TO QUIT:";:POKE 764,255:GOSUB 990:KEY=PEEK(764):GOSUB 940:GOSUB 1320:GOSUB 1730
2120 TRAP 2400:IF PLACE$="Y" THEN GRAPHICS 17:POSITION 0,10:PRINT #6;" loading main menu":RUN "D:MENU"
2130 RETURN
2140 GOSUB 930:? #6;"ENTER 1ST POINT":X1=-1:X2=-1:POKE 87,10
2150 JOY=STICK(0):GOSUB 100:GOSUB 1020:IF STRIG(0)=0 THEN X1=X:Y1=Y:GOSUB 1640:GOTO 2170
2160 GOTO 2150
2170 POKE 87,1:GOSUB 930:? #6;"ENTER NEXT POINT":POKE 87,10
2180 JOY=STICK(0):GOSUB 100:GOSUB 1020:IF STRIG(0)=0 THEN X2=X:Y2=Y:GOSUB 1020:POKE 87,1:GOTO 2200
2190 GOTO 2180
2200 GOSUB 1640:RETURN
2210 GOSUB 2140:POKE 87,10:X1=X:Y1=Y:GOSUB 2170
2220 GOSUB 930:? #6;"ENTER LAST POINT":POKE 87,10
2230 JOY=STICK(0):GOSUB 100:COLOR C:PLOT X,Y:PLOT X2,Y2:FOR I=1 TO 3:NEXT I
2240 IF STRIG(0)=0 THEN 2270
2250 COLOR 0:PLOT X,Y:PLOT X2,Y2
2260 GOTO 2230
2270 TRAP 2280:POSITION X,Y:POKE 765,C:XIO 18,#6,0,0,"S:"
2280 PLOT X,Y:DRAWTO X,Y:POKE 87,1:RETURN
2290 GOSUB 930:? #6;"INSTANT POSITION:";:POKE 764,255:GOSUB 990:KEY=PEEK(764):GOSUB 940:GOSUB 1320:GOSUB 1730
2300 IF ASC(PLACE$)<49 OR ASC(PLACE$)>57 THEN GOSUB 930:GOSUB 980:GOTO 2290
2310 IF STRIG(0)<>0 THEN POKE 87,10:COLOR C:PLOT X,Y:POKE 87,2
2320 X=INX(VAL(PLACE$)):Y=INY(VAL(PLACE$)):RETURN
2330 IOCBX=IOCB*16:ICCOM=834+IOCBX:ICSTA=835+IOCBX:ICBAL=836+IOCBX:ICBAH=837+IOCBX
2340 ICBLL=840+IOCBX:ICBLH=841+IOCBX
2350 D=USR(CAL,ICBAL,ICBAH,STADR)
2360 D=USR(CAL,ICBLL,ICBLH,BYTES)
2370 POKE ICCOM,CMD:D=USR(ADR(CIO$),IOCBX)
2380 ERR=PEEK(ICSTA):RETURN
2390 REM WRONG DISK
2400 PRINT "↰↰***Error***"
2410 POKE 764,255:TRAP 40000:PRINT "↓Insert The Window Showcase disk and   press RETURN to load the main menu."
2420 IF PEEK(764)<>12 THEN 2420
2430 GOTO 2120
2440 FOR T=14 TO 0 STEP -1:SOUND 0,29,10,T:SOUND 1,35,10,T:SOUND 2,60,10,T:NEXT T
2450 IF TR THEN MODE$="DRAW MODE":TR=0:GOTO 2470
2460 IF  NOT TR THEN MODE$="TRAVEL MODE":TR=1:IF PLACE$<>"L" THEN POKE 87,10:COLOR C:PLOT X,Y:POKE 87,1
2470 IF PLACE$="T" THEN PLACE$="┤"
2480 RETURN
4000 IRPT$(1,100)="h-▖T)@py▗♥-▂T▔▂T◆H-␛P▔◣T)@▗♥▔␛P-k╱▔♥▕-l╱▔├▕h@H◣H-␛P▔◣T)♥▗@▔␛P"┘=d╱EO%N↓▎PJ♣s-m╱▔♥▕-n╱▔├▕h*h@H-␛P▔◣T)"
4010 IRPT$(101,200)="?▔␛P-h╱EO%N▔└P-o╱▔♥▕-p╱▔├▕h@H◣H-␛P▔◣T)♥▗@▔␛P"┤=D▕EO%N↓▎PJ♣s-q╱▔♥▕-r╱▔├▕h*h@H-␛P▔◣T)@▗♥▔␛P-s╱▔♥▕-t╱▔├"
4020 IRPT$(201,231)="▕h@H-␛P▔◣T)♥▗@▔␛P-i╱▔♥▕-j╱▔├▕h@"
4030 MIRROR$(1,100)="hhh┐Vhh┐Whh┐Xh┐]h┐\h┐_h┐^ ┼)♥┐Y%Vp 1\┤Z┴******)▖┐[◣)p┴e[$Y┌^fY$Z◢♣◆0╲1\┌^◢♣y%Wp♣8%^i(┐^%_i♥┐_┴♣▔┴%^i"
4040 MIRROR$(101,127)="(┐^%_i♥┐_┴%\i(┐\%]i♥┐]FX♣ ◆"
4050 ERASE$="hhh┐Vhh┐Whh┐Xh┐Zh┐Y)♥$V◢&Xp◣H1Y)▖┌Y)♥◢┌Y◢P♠%Xp┤1Y)p┌Y┴%Yi(┐Y%Zi♥┐ZFWPM◆"
4060 CAL$="hh┐Wh┐Vh┐Yh┐X ♥h┌Xh┌V◆"
4070 CIO$="hhh*LVd"
4080 MIRROR$(35,35)=CHR$(34):MIRROR$(126,126)=CHR$(155)
4090 RETURN