Escher Sketcher graphics program (ESCHER.BAS)

Escher Sketcher graphics program

Description

Escher Sketcher graphics program

From the Antic disk of August 1983 (Vol. 2 No. 5).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 5.8 KB

Dialect
Atari BASIC
Lines
130
Variables
CLLR(, D(, BAK, I, J, CSSR, X, Y, CBX, L, ST
BASIC listing (130 lines)
10 REM *** PRE-SELECT ***
15 DIM CLLR(2,3),D(4)
20 GRAPHICS 0:SETCOLOR 2,0,0:? "ISO-SKETCH by BENJAMIN BARTELS"
30 ? :? "COLOR(0-15),LUM(0-14)":? :? "INPUT BACKGOUND COLOR AND LUM."
32 TRAP 35:BAK=0:INPUT I,J:BAK=I*16+J
35 ? "INPUT CURSOR COLOR AND LUM.":TRAP 40:CSSR=15:INPUT I,J:CSSR=I*16+J
40 ? :? "BOX #1":? "INPUT TOP COLOR AND LUM.":TRAP 50:CLLR(1,1)=6:INPUT I,J:CLLR(1,1)=I*16+J
50 ? "INPUT RIGHT COLOR AND LUM.":TRAP 60:CLLR(1,2)=4:INPUT I,J:CLLR(1,2)=I*16+J
60 ? "INPUT LEFT COLOR AND LUM.":TRAP 70:CLLR(1,3)=2:INPUT I,J:CLLR(1,3)=I*16+J
70 ? :? "BOX #2"
80 ? "INPUT TOP COLOR AND LUM.":TRAP 90:CLLR(2,1)=236:INPUT I,J:CLLR(2,1)=I*16+J
90 ? "INPUT RIGHT COLOR AND LUM.":TRAP 95:CLLR(2,2)=134:INPUT I,J:CLLR(2,2)=I*16+J
95 ? "INPUT LEFT COLOR AND LUM.":TRAP 100:CLLR(2,3)=66:INPUT I,J:CLLR(2,3)=I*16+J
100 REM *** START POSITION ***
110 ? "↰START=TOGGLES BETWEEN POSITIONING":? "CURSOR AND DRAWING BOXES"
120 ? "SELECT=TOGGLES BETWEEN BOX #1 AND":? "BOX #2"
130 ? "OPTION=CLEARS SCREEN"
140 ? :? "PRESS START TO BEGIN"
142 IF PEEK(53279)=7 THEN 142
160 X=40:Y=96:GRAPHICS 10:CBX=0
170 POKE 705,CLLR(1,1):POKE 706,CLLR(1,2):POKE 707,CLLR(1,3)
172 POKE 708,CLLR(2,1):POKE 709,CLLR(2,2):POKE 710,CLLR(2,3)
174 POKE 704,BAK:POKE 711,CSSR
200 REM *** POSITION CURSOR ***
205 IF PEEK(53279)<>7 THEN 205
207 D(4)=0:D(3)=0:D(2)=0:D(1)=5:L=0
210 LOCATE X,Y,I
220 COLOR 0:PLOT X,Y:GOSUB 240
225 IF PEEK(53279)=5 THEN GOSUB 280
227 IF PEEK(53279)=3 THEN 160
230 COLOR 7:PLOT X,Y:GOSUB 250:GOTO 220
240 IF PEEK(53279)=6 THEN POP :COLOR I:PLOT X,Y:POKE 764,255:GOTO 1000
245 RETURN
250 ST=STICK(0):IF ST=15 OR ST=10 OR ST=9 OR ST=5 OR ST=6 THEN RETURN
260 J=STRIG(0):IF L=0 THEN COLOR I:PLOT X,Y
262 IF (ST=13 AND J=1) OR ST=7 THEN X=X+1
263 IF (ST=14 AND J=1) OR ST=11 THEN X=X-1
264 IF ST=14 OR ST=7 THEN Y=Y-1
265 IF ST=13 OR ST=11 THEN Y=Y+1
267 X=X+(X=-1)-(X=80):Y=Y+(Y=-1)-(Y=192):POKE 77,0
270 LOCATE X,Y,I:RETURN
280 L=1-L
285 IF PEEK(53279)<>7 THEN 285
290 RETURN
300 REM *** MAIN LOOP ***
310 ST=STICK(0):IF ST=14 OR ST=7 OR ST=13 OR ST=11 THEN 900
320 IF PEEK(53279)=3 THEN 160
330 IF PEEK(53279)=5 THEN 400
335 IF PEEK(53279)=6 THEN 200
340 GOTO 300
400 REM *** CHANGE BOX COLORS ***
410 CBX=1-CBX
420 IF PEEK(53279)<>7 THEN 420
430 GOTO 300
900 REM *** DRAW BOX ***
910 D(4)=D(3):D(3)=D(2):D(2)=D(1)
920 D(1)=1*(ST=14)+2*(ST=7)+3*(ST=13)+4*(ST=11)
922 IF ST=14 AND STRIG(0)=0 THEN D(1)=5
925 IF ST=13 AND STRIG(0)=0 THEN D(1)=6
930 X=X+3*(D(1)=3 OR D(1)=2)-3*(D(1)=1 OR D(1)=4):Y=Y+3*(D(1)=3 OR D(1)=4)-3*(D(1)<3)+10*(D(1)=6)-10*(D(1)=5)
940 IF X<3 THEN X=3
945 IF X>75 THEN X=75
950 IF Y<4 THEN Y=4
955 IF Y>180 THEN Y=180
960 POKE 77,0
1000 REM *** BOX TOP ***
1010 COLOR 1+CBX*3
1020 IF D(1)=6 THEN 2000
1040 IF D(1)=1 AND D(2)=6 THEN GOSUB 1100:GOTO 2000
1050 IF D(1)=2 AND D(2)=6 THEN GOSUB 1500:GOTO 2000
1060 GOSUB 1100:GOSUB 1500:GOTO 2000
1100 REM *** LEFT HALF ***
1110 TRAP 1120:PLOT X,Y:DRAWTO X,Y-4
1120 TRAP 1125:PLOT X-1,Y-1:DRAWTO X-1,Y-3
1125 TRAP 1130:PLOT X-2,Y-2
1130 RETURN
1500 REM *** RIGHT HALF ***
1520 TRAP 1535:PLOT X+1,Y:DRAWTO X+1,Y-4
1535 TRAP 1540:PLOT X+2,Y-1:DRAWTO X+2,Y-3
1540 TRAP 1550:PLOT X+3,Y-2
1550 RETURN
2000 REM *** DRAW LEFT SIDE ***
2010 COLOR 2+CBX*3
2020 IF D(1)=2 THEN 3000
2025 IF D(1)=6 AND D(2)=2 THEN GOSUB 2500:GOSUB 2700:GOTO 3000
2030 IF D(1)>2 THEN GOSUB 2300:GOSUB 2500:GOSUB 2700:GOTO 3000
2040 IF D(2)=2 THEN GOSUB 2300:GOTO 3000
2050 IF D(2)=1 AND D(3)=2 AND D(4)=2 THEN GOSUB 2300:GOSUB 2500:GOTO 3000
2060 GOSUB 2300:GOSUB 2500:GOSUB 2700:GOTO 3000
2300 REM *** TOP WEDGE ***
2305 TRAP 2310:PLOT X,Y+1
2310 TRAP 2320:PLOT X-1,Y+1:PLOT X-1,Y+2
2320 TRAP 2330:PLOT X-1,Y
2330 TRAP 2340:PLOT X-2,Y+1:DRAWTO X-2,Y-1
2340 TRAP 2350:PLOT X-2,Y+2:DRAWTO X-2,Y+3
2350 RETURN
2500 REM *** MID WEDGE ***
2510 TRAP 2520:PLOT X,Y+2:DRAWTO X,Y+7
2520 TRAP 2530:PLOT X-1,Y+3:DRAWTO X-1,Y+8
2530 TRAP 2540:PLOT X-2,Y+4:DRAWTO X-2,Y+8
2540 RETURN
2700 REM *** BOTTOM WEDGE ***
2710 TRAP 2720:PLOT X,Y+8:DRAWTO X,Y+10
2720 TRAP 2730:PLOT X-1,Y+9
2730 RETURN
3000 REM *** DRAW RIGHT SIDE ***
3010 COLOR 3+CBX*3
3020 IF D(1)=1 THEN 4000
3025 IF D(1)=6 AND D(2)=1 THEN GOSUB 3500:GOSUB 3700:GOTO 4000
3030 IF D(1)>2 THEN GOSUB 3300:GOSUB 3500:GOSUB 3700:GOTO 4000
3040 IF D(2)=1 THEN GOSUB 3300:GOTO 4000
3050 IF D(2)=2 AND D(3)=1 AND D(4)=1 THEN GOSUB 3300:GOSUB 3500:GOTO 4000
3060 GOSUB 3300:GOSUB 3500:GOSUB 3700:GOTO 4000
3300 REM *** TOP WEDGE ***
3305 TRAP 3310:PLOT X+1,Y+1
3310 TRAP 3320:PLOT X+2,Y+1:PLOT X+2,Y+2
3320 TRAP 3330:PLOT X+2,Y
3330 TRAP 3340:PLOT X+3,Y+1:DRAWTO X+3,Y-1
3340 TRAP 3350:PLOT X+3,Y+2:DRAWTO X+3,Y+3
3350 RETURN
3500 REM *** MID WEDGE ***
3510 TRAP 3520:PLOT X+1,Y+2:DRAWTO X+1,Y+7
3520 TRAP 3530:PLOT X+2,Y+3:DRAWTO X+2,Y+8
3530 TRAP 3540:PLOT X+3,Y+4:DRAWTO X+3,Y+8
3540 RETURN
3700 REM *** BOTTOM WEDGE ***
3710 TRAP 3720:PLOT X+1,Y+8:DRAWTO X+1,Y+10
3720 TRAP 3730:PLOT X+2,Y+9
3730 RETURN
4000 GOTO 300