Atari Printfont (DSKFNTPR.BAS)
Atari Printfont by Jerry White
Description
Atari Printfont by Jerry White
From the Antic disk of April 1983 (Vol. 2 No. 1).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.1 KB
- Dialect
- Atari BASIC
- Lines
- 33
- Variables
FL$,ME,IT,FONT$,SM,SCREEN,FONT,CNUM,OFFSET,DISK$,AC,J1,CAR$,J2,IF
BASIC listing (33 lines)
10 GOSUB 390:REM PRINTFNT 102082 (C) 1982 Jerry White
30 DIM FL$(32):FOR ME=1 TO 32:READ IT:FL$(ME,ME)=CHR$(IT):NEXT ME:? :? " READING ";FONT$
40 ME=USR(ADR(FL$)):CLOSE #3:POKE 710,0:POKE 756,48
60 ? CHR$(125):POSITION 19-LEN(FONT$)/2,2:? FONT$:SM=PEEK(88)+256*PEEK(89):SCREEN=SM+160
80 FOR ME=0 TO 255:POKE SCREEN+ME*2,ME:NEXT ME
90 POSITION 8,19:? "PRINTING CHARACTER SET":FONT=12288:CNUM=0:OFFSET=FONT+512:GOSUB 160
120 OFFSET=FONT:GOSUB 160:OFFSET=FONT+256:GOSUB 160:OFFSET=FONT+768:GOSUB 160
140 POKE 82,2:CLOSE #2:GRAPHICS 0:? :? "BASIC":? "IS":POKE 752,0:END
160 ? #2;DISK$:? #2
180 FOR ME=1 TO 4:? #2:? #2:FOR AC=0 TO 7:? #2;"ASC ";CNUM+AC,:NEXT AC:CNUM=CNUM+8:? #2:? #2
200 FOR J1=1 TO 8:CAR$=" ":CAR$(80)=" ":CAR$(2)=CAR$
220 FOR J2=1 TO 80 STEP 10:IT=PEEK(OFFSET)
240 IF IT>127 THEN CAR$(J2,J2)="*":IT=IT-128
250 IF IT>63 THEN CAR$(J2+1,J2+1)="*":IT=IT-64
260 IF IT>31 THEN CAR$(J2+2,J2+2)="*":IT=IT-32
270 IF IT>15 THEN CAR$(J2+3,J2+3)="*":IT=IT-16
280 IF IT>7 THEN CAR$(J2+4,J2+4)="*":IT=IT-8
290 IF IT>3 THEN CAR$(J2+5,J2+5)="*":IT=IT-4
300 IF IT>1 THEN CAR$(J2+6,J2+6)="*":IT=IT-2
310 IF IT=1 THEN CAR$(J2+7,J2+7)="*"
320 OFFSET=OFFSET+8:NEXT J2
340 OFFSET=OFFSET-63:? #2;CAR$:NEXT J1
350 OFFSET=OFFSET+56:? #2:NEXT ME
370 FOR ME=1 TO 12:? #2:NEXT ME:RETURN
390 DIM FONT$(12),DISK$(14),CAR$(80):GRAPHICS 0:POKE 710,162:POKE 82,5:POKE 83,38
410 ? :? :? "DISK FONT TO PRINTER UTILITY":? :? "ENTER FONT NAME";:INPUT FONT$:DISK$="D:":DISK$(3)=FONT$
430 POKE 201,10:TRAP 460:CLOSE #2:OPEN #2,8,0,"P:"
450 TRAP 410:CLOSE #3:OPEN #3,4,0,DISK$:POKE 752,1:? :? "SETTING UP FONTLOAD IN FL$":RETURN
460 ? :? "MAKE PRINTER READY":? "THEN PRESS START"
470 IF PEEK(53279)<>6 THEN 470
480 GOTO 430
500 DATA 104,162,48,169,7,157,66,3,169,0,157,68,3,169,48
510 DATA 157,69,3,169,0,157,72,3,169,4,157,73,3,32,86,228,96
