Antic Disassembler (DISASEM1.BAS)
Antic Disassembler by Sheila Spencer, 88
Description
Antic Disassembler by Sheila Spencer, 88
From the Antic disk of April 1983 (Vol. 2 No. 1).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.2 KB
- Dialect
- Atari BASIC
- Lines
- 60
- Variables
I,LST,MEMRY,INST,INT,LMS,VSCRL,HSCRL,PEEL(,EEL(,JMP,OMST,JVB,MODE,RAMTOP,HSCR
BASIC listing (60 lines)
10 REM *** PROG1 ***
20 REM MEMORY AND DISPLAY LIST VARIES WITH GRAPHICS MODE
30 REM DUMP AND DISASSEMBLE DISPLAY LIST
40 REM
100 ? " INPUT GRAPHICS MODE ";:INPUT MODE
110 LST=PEEK(560)+PEEK(561)*256:REM FIND START OF DISPLAY LIST
120 MEMRY=PEEK(LST+4)+PEEK(LST+5)*256:REM FIND START OF DISPLAY MEM.
130 RAMTOP=PEEK(106)*256:REM NUMBER OF PAGES IN MEM DEFINED AT POWER ON
140 REM LIST
150 LPRINT " OS GRAPHICS MODE ";MODE
160 LPRINT " RAM AVAILABLE AT POWER ON ";RAMTOP
170 LPRINT " START OF DISPLAY LIST ";LST
180 LPRINT " START OF DISPLAY MEMORY ";MEMRY
190 REM DUMP DISPLAY LIST WITH DISASSEMBLY OF INSTRUCTIONS
195 LMS=64:INT=128:HSCR=16:VSCRL=32:JVB=65:JMP=1
200 FOR I=LST TO MEMRY-1
205 LPRINT I;" ";PEEK(I);
210 INST=PEEK(I):REM DISPLAY LIST VALUE
215 IF INST>=128 THEN GOSUB 1100:GOTO 400
220 GOSUB 1140
400 NEXT I
410 STOP
1100 INST=INST-INT:REM GET RID OF INTERRUPT BIT
1105 LPRINT " INSTRUCTION INTERRUPT ENABLE "
1140 GOSUB 2000:REM FIND JUMPS AND BLANKS
1150 IF INST=0 THEN RETURN
1160 GOSUB 1400:REM GO FIND LMS
1170 GOSUB 1500:REM GO FIND VSCROL
1180 GOSUB 1600:REM GO FIND HORIZONTAL SCROLL
1190 GOSUB 1700:REM TRANSLATE ANTIC MODE TO OS GRAPHICS MODE
1200 RETURN
1400 IF INST<66 THEN RETURN :REM NO LMS
1405 LPRINT " LOAD MEM SCAN FROM ";PEEK(I+1)+PEEK(I+2)*256
1410 INST=INST-LMS:REM GET RID OF LMS BIT
1420 I=I+2:REM INCREMENT LOOP AROUND ADDRESS BYTES
1430 RETURN
1500 IF INST<34 THEN RETURN :REM NO VSCROL ENABLE
1510 INST=INST-VSCRL:REM GET RID OF VSCROLLL BIT
1520 LPRINT "VERTICAL SCROLL ENABLED"
1530 RETURN
1600 IF INST<18 THEN RETURN :REM NO HSCROLL ENABLE
1610 INST=INST-HSCRL:REM GET RID OF HORIZONTAL SCROLL BIT
1620 LPRINT " HORIZONTAL SCROLL ENABLED "
1630 RETURN
1700 LPRINT " ANTIC DISPLAY MODE ";INST
1750 RETURN
2000 IF INST=0 OR INST=16 OR INST=32 OR INST=48 OR INST=64 OR INST=80 OR INST=96 OR INST=112 THEN GOSUB 2100
2010 IF INST=1 THEN GOSUB 2200
2020 IF INST=65 THEN GOSUB 2300
2030 RETURN
2100 LPRINT " BLANK ";INT(INST/16)+1;" LINES "
2110 INST=0:RETURN
2120 REM
2200 LPRINT " JUMP INSTRUCTION TO ";PEEK(I+1)+-PEEK(I+2)*256
2210 I=I+2:REM INCREMENT AROUND ADDRESS BYTES
2215 INST=INST-JMP:RETURN
2220 REM
2300 LPRINT " JUMP & WAIT FOR VERTICAL BLANK TO ";PEEK(I+1)+PEEK(I+2)*256
2310 I=I+2:REM INCREMENT AROUND ADDRESS BYTES
2315 INST=INST-JVB:RETURN
