TinyText, text editor (TINYTEXT.BAS)

TinyText, text editor by Jim Carr, 61

Description

TinyText, text editor by Jim Carr, 61

From the Antic disk of February 1983 (Vol. 1 No. 6).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 5.8 KB

Dialect
Atari BASIC
Lines
107
Variables
SP$, I, S$, I$, A$, SIZ, T$, A, P, SCR, LL, LM, IND, TAB, PS, FF, S, K, PK, LI, LT, LA, AD, ST, OP, D, LINE, FL, RL, TP, B, C, J, SP, N, BEG
BASIC listing (107 lines)
1 REM **** TINY TEXT ****
2 REM
3 REM Stan Ockers Sept-81
4 REM ACE Newsletter Nov-81
5 REM
6 REM Mod by Jim Carr 01-OCT-82
7 REM
12 DIM SP$(40):FOR I=1 TO 40:SP$(I,I)=" ":NEXT I
14 DIM S$(45),I$(120),A$(128):SIZ=FRE(0)-50:DIM T$(SIZ):FOR I=1 TO 45:READ A:S$(I)=CHR$(A):NEXT I
20 DATA 104,104,133,204,104,133,203,104,133,206,104,133,205,104,104,168,162,0,161,203,145,203,198,203,165
30 DATA 203,201,255,208,2,198,204,165,203,197,205,208,236,165,204,197,206,208,230,96
40 FOR I=1536 TO 1643:READ A:POKE I,A:NEXT I
50 DATA 104,104,133,204,104,133,203,104,133,206,104,133,205,162,0,169,240,32,53,6,169,40,32,91,6
60 DATA 165,207,208,8,169,160,32,91,6,24,144,10,169,40,32,53,6,169,120,32,91,6,169,240,32,53,6,96
70 DATA 133,208,161,203,201,96,176,11,201,32,176,5,24,105,64,208,2,233,32,129,205,230,203,208,2
80 DATA 230,204,230,205,208,2,230,206,198,208,208,221,96,133,208,169,0,129,205,230,205,208,2
90 DATA 230,206,198,208,208,244,96
110 P=241:POKE 207,0:POKE 82,0:OPEN #2,4,0,"E:":T$(1)=".":T$(480)=".":T$(2)=T$
120 SCR=PEEK(88)+256*PEEK(89)+120:LL=35:LM=1:IND=5:TAB=10:PS=66:FF=6:GOTO 500
290 ? "INSERT TEXT OR ...  PRESS SELECT TO EDIT"
300 POSITION 0,0:? SIZ-LEN(T$);" FREE   ":S=STICK(0):IF S=15 THEN 330
305 IF S=14 AND P<LEN(T$)-320 THEN P=P+40
310 IF S=13 AND P>280 THEN P=P-40
315 IF S=11 AND P<LEN(T$)-280 THEN P=P+1
320 IF S=7 AND P>241 THEN P=P-1
330 A=USR(1536,ADR(T$)+P-241,SCR)
335 K=0
340 POKE 53279,8:PK=PEEK(53279):IF PK=5 THEN GOSUB 900
350 IF PK=3 THEN 500
360 IF PEEK(764)<255 THEN 400
365 K=K+1:IF K<10 THEN 340
370 IF STRIG(0)=0 THEN P=LEN(T$)-240:POKE 207,0
380 GOTO 300
400 POSITION 0,10:INPUT #2;I$:PK=PEEK(207):IF PK=0 THEN A$=""
405 LI=LEN(I$):LT=LEN(T$):IF LI=0 THEN 460
407 IF LI+LT>SIZ THEN POSITION 0,1:? "OUT OF SPACE         ":GOTO 300
410 IF PK=1 THEN A$=T$(P,P+39):IF T$(P+39,P+39)=" " THEN I$(LI+1)=" ":LI=LI+1
420 LA=LEN(A$):AD=ADR(T$):IF LI>LA THEN A=USR(ADR(S$),AD+LT-1,AD+P-2,LI-LA)
430 T$(P,P+LI-1)=I$
440 IF LA>LI THEN T$(P+LI)=T$(P+LA)
450 P=P+LI:T$(LT+LI-LA+1)="":POKE 207,0:GOTO 300
460 IF PEEK(207)=1 THEN 470
465 IF P<LEN(T$)-279 THEN T$(P)=T$(P+40)
470 POKE 764,255:GOTO 300
500 TRAP 950:ST=PEEK(560)+PEEK(561)*256+4:POKE ST-1,70:POKE ST+2,7:POKE ST+3,112:POKE ST+4,6:POKE ST+5,6
501 POKE ST+24,65
510 POKE ST+25,PEEK(560):POKE ST+26,PEEK(561)
515 OP=OP+1:IF OP=6 THEN OP=1
520 ? CHR$(125):POSITION 20,0:IF OP=1 THEN ? "LOAD"
522 IF OP=2 THEN ? "EDIT"
534 IF OP=3 THEN ? "PRINT"
536 IF OP=4 THEN ? "SAVE"
538 IF OP=5 THEN ? "DISPLAY"
540 POSITION 0,1:? "PRESS START TO BEGIN"
550 FOR D=1 TO 30:NEXT D
555 POKE 53279,8:IF PEEK(53279)=3 THEN 515
557 IF PEEK(53279)<>6 THEN 555
560 POKE 764,255:POSITION 20,1:? CHR$(125):POSITION 0,1:ON OP GOTO 2000,290,590,1500,590
590 FOR I=1 TO 6:? CHR$(127);CHR$(158);:NEXT I:? :FOR I=1 TO 6:? " ";CHR$(159);"   ";:NEXT I
594 POSITION 0,1:? "SET FORMAT CONTROLS":POSITION 0,6:? "LINE LEFT IN-  TAB  PAGE FORM"
595 ? "SIZE MARG DENT STOP SIZE FEED":? CHR$(127);LL;",";CHR$(127);LM;",";CHR$(127);IND;",";CHR$(127);
596 ? TAB;",";CHR$(127);PS;",";CHR$(127);FF:POSITION 0,8
600 INPUT LL,LM,IND,TAB,PS,FF:P=240:P=240:GOTO 710
610 P=240
670 GOTO 620
710 LINE=0:GRAPHICS 0:POSITION 0,3:FL=0
715 RL=LL:TP=P:B=ASC(T$(TP,TP))
720 RL=LL-IND*(B=9)-TAB*(B=20)
725 IF B=19 AND OP=3 AND LINE<=(PS-FF) THEN LPRINT " ":LINE=LINE+1
726 IF B=19 AND OP=5 THEN ?
727 IF B=16 AND OP=3 THEN FOR I=1 TO PS-LINE:LPRINT " ":NEXT I:LINE=0
728 IF B=16 AND OP=5 THEN ? :? :? :LINE=0
735 C=0:K=0
740 K=K+1:TP=TP+1:IF K=RL+1 THEN 765
745 IF TP>LEN(T$)-241 THEN FL=1:GOTO 810
750 A=ASC(T$(TP,TP)):IF A<32 THEN C=0:GOTO 780
755 IF A=32 THEN C=C+1
760 GOTO 740
765 IF C=0 THEN A$=T$(P+1,TP-1):TP=TP-1:GOTO 810
767 IF T$(TP,TP)=" " THEN A$=T$(P+1,TP-1):GOTO 810
768 IF T$(TP-1,TP-1)=" " THEN C=C-1
770 K=1
775 TP=TP-1:IF T$(TP,TP)<>" " THEN K=K+1:GOTO 775
780 IF TP=P+1 THEN P=TP:GOTO 715
785 A$="":I=P+1
790 A$(LEN(A$)+1)=T$(I,I):IF T$(I,I)<>" " THEN 805
795 IF C>1 THEN A=INT(K/C+RND(0)):IF A>0 THEN FOR J=1 TO A:A$(LEN(A$)+1)=" ":NEXT J:K=K-A
800 C=C-1
802 IF C=1 AND K>0 THEN FOR J=1 TO K:A$(LEN(A$)+1)=" ":NEXT J
805 I=I+1:IF I<TP THEN 790
810 IF FL THEN A$=T$(P+1,TP-1)
815 IF OP=3 THEN LINE=LINE+1:IF LINE>(PS-FF) THEN LINE=1:FOR I=1 TO FF:LPRINT " ":NEXT I
820 SP=LM+(B=9)*IND+(B=20)*TAB+(B=3)*(LL-LEN(A$))/2:IF SP>40 THEN SP=40
830 IF OP=3 THEN LPRINT SP$(1,SP);A$
840 IF OP=5 THEN ? SP$(1,SP);A$
850 IF FL THEN 500
860 P=TP:GOTO 715
900 PK=PEEK(207):IF PK=1 THEN POKE 207,0:GOTO 930
910 IF PK=0 AND P<LEN(T$)-279 THEN POKE 207,1
930 A=USR(1536,ADR(T$)+P-241,SCR):FOR D=1 TO 50:NEXT D:RETURN
950 ? "ERROR ";PEEK(195);" AT ";256*PEEK(187)+PEEK(186):? "PRESS RETURN TO CONTINUE":INPUT I$:GOTO 500
1500 ? " ENTER FILE NAME":INPUT I$:OPEN #3,8,0,I$:N=INT(LEN(T$)/128):? #3;N:IF N=0 THEN ST=0:GOTO 1520
1510 FOR I=1 TO N:ST=128*I:? #3;T$(ST-127,ST):NEXT I
1520 ? #3;T$(ST+1,LEN(T$)):CLOSE #3:GOTO 500
2000 ? " ENTER FILE NAME":INPUT I$:OPEN #3,4,0,I$:INPUT #3,N:IF N=0 THEN BEG=-127:GOTO 2020
2010 GRAPHICS 0:FOR I=1 TO N:BEG=128*I-127:INPUT #3,A$:? A$;:T$(BEG)=A$:NEXT I
2020 INPUT #3,A$:T$(BEG+128)=A$:CLOSE #3:POKE 1536,104:GOTO 500