Tuning Your Atari, music program (TUNE.BAS)

Tuning Your Atari, music program by Linda Schreiber, 48

Description

Tuning Your Atari, music program by Linda Schreiber, 48

From the Antic disk of October 1982 (Vol. 1 No. 4).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 3.4 KB

Dialect
Atari BASIC
Lines
56
Variables
P1$, M$, A, TONE, WAIT, Q, CHBS, X, C, K, ROUTINE, T, TL
BASIC listing (56 lines)
10 REM ******** TUNING YOUR ATARI ********
20 REM BY L.M.SCHREIBER FOR ANTIC AUGUST 1982
40 DIM P1$(20),M$(100)
50 GRAPHICS 18:POKE 711,PEEK(710):POKE 710,100
60 A=PEEK(106)-8:POKE 204,A:POKE 206,224:REM STORE THE BEGINNING OF NEW & OLD CHARACTER SETS
70 P1$="h"┤ ♥1M┌KHPyfNfLJPr◆":TONE=430:WAIT=500:REM MACHINE LANGUAGE SUBROUTINE MOVES THE CHARACTER SET
80 Q=USR(ADR(P1$)):CHBS=A*256:POKE 756,A:REM INSTALL NEW CHARACTER SET
90 FOR X=CHBS+8 TO CHBS+71:READ C:POKE X,C:NEXT X:REM CHANGE THE CHARACTERS FROM ! TO $
100 DATA 0,254,124,254,124,254,124,254,108,0,254,254,124,254,124,254,40,108,0,254,254,254,124,254
110 DATA 186,40,108,0,254,254,254,254,56,108,56,16,254,56,40,108,0,56,108,56,146,124,56,40
120 DATA 0,0,56,108,56,16,254,56,0,0,0,56,108,56,16,124
130 OPEN #2,4,0,"K:":REM OPEN THE KEYBOARD FOR READ
140 POSITION 2,9:? #6;"! ! ! ! ! ! ! !":POSITION 2,8:? #6;"% % % % % % % %":REM THE ! AND % ARE THE NEW CHARACTERS
150 POSITION 2,6:? #6;"c d e f g a b c":REM PLACE THE TONE NAMES
160 POKE 710,100:REM RESTORE THE MENU
170 POSITION 2,0:? #6;"1. PLAY KEYBOARD"
180 POSITION 2,2:? #6;"2. REPEAT MELODY"
190 POSITION 2,4:? #6;"3. PLAY EXAMPLE"
200 K=0:GET #2,C:POKE 710,0:REM GET THE KEY PRESSED-REMOVE THE MENU
210 IF C>127 THEN C=C-128:POKE 694,0:REM INVERSE FLAG IS ON RESET IT TO NORMAL
220 IF C<49 OR C>52 THEN POKE 764,255:GOTO 200:REM NOT A NUMBER FROM 1 TO 4
230 C=C-48:REM GET THEN NUMBER
240 ON C GOTO 250,540,520,560
250 M$="":REM REMOVE CONTENTS OF THE STRING
260 ROUTINE=260:K=K+1:IF K=101 THEN 160:REM ONLY ACCEPT 100 NOTES
280 GET #2,C:IF C=27 THEN 160:REM GET THE KEY PRESSED-RETURN TO MENU ON ESCAPE KEY
290 IF C>127 THEN C=C-128:POKE 694,0:REM INVERSE FLAG IS ON RESET IT TO NORMAL
300 IF C<49 OR C>56 THEN POKE 764,255:GOTO 200:REM NOT A NUMBER FROM 1 TO 8
310 C=C-48:M$(K,K)=STR$(C):REM GET THEN NUMBER-PUT IT IN THE STRING
320 C=C*2:REM OFFSET IT FOR THE PROPER POSITION
330 ON C/2 GOSUB 350,360,370,380,390,400,410,420
340 GOTO ROUTINE
350 T=121:GOTO TONE:REM 'C'
360 T=108:GOTO TONE:REM 'D'
370 T=96:GOTO TONE:REM 'E'
380 T=91:GOTO TONE:REM 'F'
390 T=81:GOTO TONE:REM 'G'
400 T=72:GOTO TONE:REM 'A'
410 T=64:GOTO TONE:REM 'B'
420 T=60:REM 'C'
425 REM LINES 430-450 MAKE THE CHARACTER APPEAR TO PUSH DOWN ON THE BELLOW AND MAKE THE TONE
430 TL=10:POSITION C,8:? #6;CHR$(134):POSITION C,9:? #6;CHR$(130):SOUND 0,T,10,6:GOSUB WAIT
440 POSITION C,8:? #6;CHR$(135):POSITION C,9:? #6;CHR$(131):SOUND 0,T,10,8:GOSUB WAIT
450 POSITION C,8:? #6;CHR$(136):POSITION C,9:? #6;CHR$(132):GOSUB WAIT
460 SOUND 0,T,10,10
470 POSITION C,8:? #6;CHR$(135):POSITION C,9:? #6;CHR$(131):SOUND 0,T,10,8:GOSUB WAIT
475 REM LINES 470-490 RETURN THE CHARACTER AND BELLOW TO THE CORRECT POSITION
480 POSITION C,8:? #6;CHR$(134):POSITION C,9:? #6;CHR$(162):SOUND 0,T,10,6:GOSUB WAIT
490 POSITION C,8:? #6;"%":POSITION C,9:? #6;"!":SOUND 0,0,0,0:RETURN
500 FOR X=1 TO TL:NEXT X:RETURN :REM TIMING LOOP
510 REM PLAY A SAMPLE TUNE
520 M$="11556654433221"
530 REM ROUTINE TO PLAY BACK THE MELODY ENTERED
540 ROUTINE=540:K=K+1:IF K<=LEN(M$) THEN C=VAL(M$(K,K)):GOTO 320:REM KEEP PLAYING UNTIL THE END OF THE STRING
550 GOTO 160
560 END