Banner Maker (BANNER.BAS)
Banner Maker
Description
Banner Maker
From the Antic disk of August 1982 (Vol. 1 No. 3).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 1.5 KB
- Dialect
- Atari BASIC
- Lines
- 40
- Variables
INSTR$,CHNUM,C1,CH$,CH,CHGRP,C32,Y,C0,C7,BYTE,CHBAS,X,BITON,BIT(,ARR(,ROW,LINE$,BLANK$,COL,COLLOW,COLHIGH,SEGHT,BLOCK$,I,WIDTH,PAGE$,C3,C8,C63,PRTYPE$,SIXROW$,TEMP,BLOCK,BLANK
BASIC listing (40 lines)
10 REM Banner maker by Paul E. Hoffman
20 GOSUB 1000
100 PRINT "String for banner";:INPUT INSTR$
110 FOR CHNUM=C1 TO LEN(INSTR$)
120 CH$=INSTR$(CHNUM):CH=ASC(CH$)
130 PRINT CH$;
140 CHGRP=INT(CH/C32)+C1
150 ON CHGRP GOTO 160,170,170,200,160,170,170,200
160 CH=CH+64:GOTO 200
170 CH=CH-C32:GOTO 200
200 FOR Y=C0 TO C7:BYTE=PEEK(256*CHBAS+8*CH+Y)
210 FOR X=C7 TO C0 STEP -1:BITON=C0:IF BYTE>=BIT(X) THEN BITON=C1:BYTE=BYTE-BIT(X)
220 ARR(C7-Y,C7-X)=BITON:NEXT X
230 NEXT Y
500 FOR ROW=C0 TO C7:LINE$=BLANK$:FOR COL=COLLOW TO COLHIGH
510 IF ARR(COL,ROW)=C1 THEN LINE$(SEGHT*COL)=BLOCK$
530 NEXT COL
540 FOR I=C1 TO WIDTH:LPRINT LINE$:NEXT I
550 NEXT ROW
560 IF PAGE$="YES" THEN LPRINT CHR$(140)
600 NEXT CHNUM
999 END
1000 REM *** Subroutine for setup of vars
1010 C0=0:C1=1:C3=3:C7=7:C8=8:C32=32:C63=63
1020 DIM ARR(C7,C7),BIT(C7),INSTR$(C63),CH$(C1),LINE$(80),PRTYPE$(C7),PAGE$(C3),SIXROW$(C3)
1030 CHBAS=PEEK(756)
1040 TEMP=C1:FOR I=C0 TO C7:BIT(I)=TEMP:TEMP=TEMP*2:NEXT I
1050 WIDTH=5:SEGHT=10
1060 PRTYPE$="EPSON"
1070 PAGE$="NO"
1080 SIXROW$="NO"
1100 IF PRTYPE$="EPSON" THEN BLOCK=35:BLANK=C32
1110 IF PRTYPE$="ATARI" THEN BLOCK=160:BLANK=C32
1120 IF PRTYPE$="LETQUAL" THEN BLOCK=35:BLANK=C32
1130 COLLOW=C0:COLHIGH=C7
1140 IF SIXROW$="YES" THEN SEGHT=INT(SEGHT*1.25):COLLOW=C1:COLHIGH=6
1150 DIM BLOCK$(SEGHT),BLANK$(8*SEGHT)
1160 FOR I=C1 TO SEGHT:BLOCK$(I)=CHR$(BLOCK):BLANK$(I)=CHR$(BLANK):NEXT I
1170 FOR I=C1 TO C3:BLANK$(LEN(BLANK$)+1)=BLANK$:NEXT I
1200 RETURN
